PlanUs-BE/build.gradle at develop · 26Grad-FinAI/PlanUs-BE · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.5.15'
	id 'io.spring.dependency-management' version '1.1.7'
	id 'com.diffplug.spotless' version '7.0.4'
}

group = 'com.planus'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-actuator'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.security:spring-security-test'
	testImplementation 'org.testcontainers:postgresql'
	testImplementation 'org.testcontainers:junit-jupiter'
	testCompileOnly 'org.projectlombok:lombok'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	testAnnotationProcessor 'org.projectlombok:lombok'

	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.4'
	implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'

	runtimeOnly 'org.postgresql:postgresql'
	implementation 'org.flywaydb:flyway-core'
	implementation 'org.flywaydb:flyway-database-postgresql'
	implementation 'net.javacrumbs.shedlock:shedlock-spring:6.9.1'
	implementation 'net.javacrumbs.shedlock:shedlock-provider-jdbc-template:6.9.1'
}

dependencyManagement {
	imports {
		mavenBom "org.testcontainers:testcontainers-bom:1.21.1"
	}
}

tasks.named('test') {
	useJUnitPlatform {
		excludeTags 'benchmark', 'llm'
	}
	testLogging {
		showStandardStreams = project.hasProperty('showTestOutput')
	}
	jvmArgs '-XX:+EnableDynamicAgentLoading', '-Xshare:off'
}

tasks.named('bootJar') {
	archiveFileName = 'app.jar'
}

tasks.named('jar') {
	enabled = false
}

// 실제 LLM API를 호출하는 테스트 — ANTHROPIC_API_KEY 환경변수 필요
// 실행: ./gradlew testLlm
tasks.register('testLlm', Test) {
	useJUnitPlatform {
		includeTags 'llm'
	}
	testLogging {
		showStandardStreams = true
	}
}

spotless {
	java {
		palantirJavaFormat()
		target 'src/**/*.java'
	}
}