-
Notifications
You must be signed in to change notification settings - Fork 0
/
juego.pco
513 lines (450 loc) · 21.4 KB
/
juego.pco
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
*****************************************************************
* juego *
* ----------------------------------------------------------- *
* Tres en raya. *
* *
*****************************************************************
* Log de modificaciones: *
* --------------------------------------------------------------*
* Marca|Fecha |Usuario|Descripcion *
* -----|----------|-------|------------------------------------ *
* |17/10/2018|Alex |Creacion del programa. *
* --------------------------------------------------------------*
*****************************************************************
*****************************************************************
IDENTIFICATION DIVISION.
PROGRAM-ID. JUEGO.
AUTHOR. ALEX.
INSTALLATION. https://github.com/AlexGracia.
DATE-WRITTEN. 17/10/2018.
DATE-COMPILED.
*****************************************************************
* *
* ENVIRONMENT DIVISION *
* *
*****************************************************************
ENVIRONMENT DIVISION.
CONFIGURATION SECTION.
SPECIAL-NAMES.
DECIMAL-POINT IS COMMA.
INPUT-OUTPUT SECTION.
FILE-CONTROL.
*****************************************************************
* *
* DATA DIVISION *
* *
*****************************************************************
DATA DIVISION.
FILE SECTION.
WORKING-STORAGE SECTION.
*****************************************************************
* *
* VARIABLES WORKING *
* ------------------------------------------------------------- *
* *
* · Hora actual. *
* · Número aleatorio. *
* · Tablero. *
* · Mensaje final. *
* · Booleanos. *
* · Literales. *
* *
*****************************************************************
* · Hora actual.
01 WS-TIEMPO-ACTUAL.
05 TIEMPO OCCURS 4 PIC 99 VALUE ZEROS.
* · Número aleatorio.
01 WS-NUM-ALEATORIO PIC 9 VALUE ZEROS.
* · Tablero.
01 WS-TABLERO.
05 WS-ASTERISCOS PIC X(9) VALUE ALL '*'.
05 WS-TAB-INI.
10 WS-FILA OCCURS 3.
15 WS-CELDA OCCURS 9 PIC X.
10 WS-INDICE PIC 9 COMP-3 VALUE ZEROS.
10 WS-CONT-CELDAS PIC 9 COMP.
88 TABLERO-LLENO VALUE 9.
88 TABLERO-HUECO VALUE 0 THRU 8.
10 WS-COORDENADAS.
15 WS-X OCCURS 9 PIC 9 COMP.
15 WS-Y OCCURS 9 PIC 9 COMP.
10 WS-RAYAS.
15 WS-RAYA-USUARIO OCCURS 8 PIC 99 COMP.
15 WS-RAYA-MAQUINA OCCURS 8 PIC 99 COMP.
15 WS-RAYA-TOTAL OCCURS 8 PIC 99 COMP.
* · Mensaje final.
01 WS-MSG-FINAL PIC X(15) VALUE SPACES.
* · Booleanos.
01 WS-FIN-JUEGO PIC 9 COMP.
88 NO-FIN VALUE 0.
88 FIN VALUE 1.
01 WS-CELDA-LLENA PIC 9 COMP.
88 NO-CELDA-LLENA VALUE 0.
88 SI-CELDA-LLENA VALUE 1.
01 WS-TURNO PIC 9 COMP.
88 USUARIO VALUE 0.
88 MAQUINA VALUE 1.
* · Literales.
77 WS-MSG-CELDA-LLENA PIC X(12) VALUE 'Celda llena.'.
77 WS-MSG-PERDEDOR PIC X(15) VALUE 'Has perdido. :O'.
77 WS-MSG-GANADOR PIC X(15) VALUE 'Has ganado. :)'.
77 WS-MSG-SALIR PIC X(15) VALUE 'Has salido. :('.
*> Rayas.
77 WS-1-LLENA PIC 99 COMP VALUE 6.
77 WS-2-LLENA PIC 99 COMP VALUE 15.
77 WS-3-LLENA PIC 99 COMP VALUE 24.
77 WS-4-LLENA PIC 99 COMP VALUE 12.
77 WS-5-LLENA PIC 99 COMP VALUE 15.
77 WS-6-LLENA PIC 99 COMP VALUE 18.
77 WS-7-LLENA PIC 99 COMP VALUE 15.
77 WS-8-LLENA PIC 99 COMP VALUE 15.
*****************************************************************
* *
* PROCEDURE DIVISION. *
* *
*****************************************************************
PROCEDURE DIVISION.
*****************************************************************
* *
* 0000-PROCESO-PRINCIPAL *
* *
*****************************************************************
0000-PROCESO-PRINCIPAL.
PERFORM 1000-INICIO
THRU 1000-INICIO-EXIT.
PERFORM 2000-PROCESO
THRU 2000-PROCESO-EXIT UNTIL FIN OR TABLERO-LLENO.
PERFORM 3000-FIN
THRU 3000-FIN-EXIT.
0000-PROCESO-PRINCIPAL-EXIT.
STOP RUN.
*****************************************************************
* *
* 1000-INICIO *
* ------------------------------------------------------------- *
* *
* · Inicialización de variables. *
* *
*****************************************************************
1000-INICIO.
* · Inicializar variables.
MOVE ZEROS TO WS-TIEMPO-ACTUAL.
INITIALIZE WS-TAB-INI
WS-FIN-JUEGO
WS-CELDA-LLENA
WS-TURNO.
* Coordenadas (x,y) (fila, columna).
*> X (filas de la tabla).
MOVE 1 TO WS-X(1) WS-X(2) WS-X(3).
MOVE 2 TO WS-X(4) WS-X(5) WS-X(6).
MOVE 3 TO WS-X(7) WS-X(8) WS-X(9).
*> Y (columnas de la tabla).
MOVE 3 TO WS-Y(1) WS-Y(4) WS-Y(7).
MOVE 5 TO WS-Y(2) WS-Y(5) WS-Y(8).
MOVE 7 TO WS-Y(3) WS-Y(6) WS-Y(9).
* Asteriscos laterales.
PERFORM 3 TIMES
ADD 1 TO WS-INDICE
MOVE '*' TO WS-CELDA(WS-INDICE,1)
MOVE '*' TO WS-CELDA(WS-INDICE,9)
END-PERFORM.
* Mensaje final.
MOVE WS-MSG-SALIR TO WS-MSG-FINAL.
* Valores de las rayas llenas.
ADD 6 TO WS-RAYA-TOTAL(1).
ADD 15 TO WS-RAYA-TOTAL(2).
ADD 24 TO WS-RAYA-TOTAL(3).
ADD 12 TO WS-RAYA-TOTAL(4).
ADD 15 TO WS-RAYA-TOTAL(5).
ADD 18 TO WS-RAYA-TOTAL(6).
ADD 15 TO WS-RAYA-TOTAL(7).
ADD 15 TO WS-RAYA-TOTAL(8).
1000-INICIO-EXIT.
EXIT.
*****************************************************************
* *
* 2000-PROCESO *
* ------------------------------------------------------------- *
* *
* · Poner ficha usuario. *
* · Pintar tablero. *
* · Poner ficha máquina. *
* · Pintar tablero. *
* *
*****************************************************************
2000-PROCESO.
* · Poner ficha usuario.
SET SI-CELDA-LLENA TO TRUE.
PERFORM 2100-MOVER-USUARIO
THRU 2100-MOVER-USUARIO-EXIT UNTIL NO-CELDA-LLENA.
* · Pintar tablero.
PERFORM 8000-PINTAR-TABLERO
THRU 8000-PINTAR-TABLERO-EXIT.
IF NO-FIN
* · Poner ficha máquina.
SET SI-CELDA-LLENA TO TRUE
PERFORM 2200-MOVER-MAQUINA
THRU 2200-MOVER-MAQUINA-EXIT UNTIL NO-CELDA-LLENA
DISPLAY '(Máquina)'
* · Pintar tablero.
PERFORM 8000-PINTAR-TABLERO
THRU 8000-PINTAR-TABLERO-EXIT
END-IF.
2000-PROCESO-EXIT.
EXIT.
*****************************************************************
* *
* 2100-MOVER-USUARIO *
* ------------------------------------------------------------- *
* *
* · Preguntar posición. *
* · Comprobar celda y añadir ficha en el tablero. *
* *
*****************************************************************
2100-MOVER-USUARIO.
SET NO-CELDA-LLENA TO TRUE.
* · Preguntar posición.
DISPLAY ' '.
DISPLAY 'Mueve ficha (1-9, 0 salir): '.
ACCEPT WS-INDICE.
* · Comprobar celda y añadir ficha en el tablero.
EVALUATE WS-INDICE
WHEN 1 THRU 9
*> Celda vacía.
IF WS-CELDA(WS-X(WS-INDICE),WS-Y(WS-INDICE)) = SPACE
MOVE 'x' TO WS-CELDA(WS-X(WS-INDICE)
,WS-Y(WS-INDICE))
ADD 1 TO WS-CONT-CELDAS
SET USUARIO TO TRUE
*> Comprobar raya.
PERFORM 8100-COMPROBAR-RAYA
THRU 8100-COMPROBAR-RAYA-EXIT
*> Celda llena.
ELSE
SET SI-CELDA-LLENA TO TRUE
END-IF
WHEN OTHER
SET FIN TO TRUE
END-EVALUATE.
* Aviso de celda llena.
IF SI-CELDA-LLENA
DISPLAY WS-MSG-CELDA-LLENA
END-IF.
2100-MOVER-USUARIO-EXIT.
EXIT.
*****************************************************************
* 2200-MOVER-MAQUINA. *
* ------------------------------------------------------------- *
* *
* Descripción: *
* Generación de un número aleatorio *
* , para que la máquina mueva ficha. *
* *
* Apartados: *
* · Generación de número aleatorio. *
* · Comprobar celda y añadir ficha en el tablero. *
* *
*****************************************************************
2200-MOVER-MAQUINA.
SET NO-CELDA-LLENA TO TRUE.
* · Generación de número aleatorio.
ACCEPT WS-TIEMPO-ACTUAL FROM TIME.
COMPUTE WS-INDICE = TIEMPO(2) + TIEMPO(3)
* TIEMPO(4) - TIEMPO(1).
* · Comprobar celda y añadir ficha en el tablero.
EVALUATE WS-INDICE
WHEN 1 THRU 9
*> Celda vacía.
IF WS-CELDA(WS-X(WS-INDICE),WS-Y(WS-INDICE)) = SPACE
MOVE 'o' TO WS-CELDA(WS-X(WS-INDICE)
,WS-Y(WS-INDICE))
ADD 1 TO WS-CONT-CELDAS
SET MAQUINA TO TRUE
*> Comprobar raya.
PERFORM 8100-COMPROBAR-RAYA
THRU 8100-COMPROBAR-RAYA-EXIT
*> Celda llena.
ELSE
SET SI-CELDA-LLENA TO TRUE
END-IF
WHEN 0
ADD 1 TO TIEMPO(4)
SET SI-CELDA-LLENA TO TRUE
END-EVALUATE.
2200-MOVER-MAQUINA-EXIT.
EXIT.
*****************************************************************
* *
* 3000-FIN *
* *
*****************************************************************
3000-FIN.
PERFORM 6000-ESTADISTICAS
THRU 6000-ESTADISTICAS-EXIT.
3000-FIN-EXIT.
EXIT.
*****************************************************************
* 6000-ESTADISTICA (2 pasos). *
*****************************************************************
6000-ESTADISTICAS.
DISPLAY '*************************************************'.
DISPLAY '** Resumen Programa JUEGO *'.
DISPLAY '* --------------------------------------------- *'.
DISPLAY '* ' WS-MSG-FINAL
' *'.
DISPLAY '* *'.
DISPLAY '*************************************************'.
6000-ESTADISTICAS-EXIT.
EXIT.
*****************************************************************
* *
* 8000-PINTAR-TABLERO *
* ------------------------------------------------------------- *
* *
* · Título. *
* · Tablero. *
* *
*****************************************************************
8000-PINTAR-TABLERO.
* · Título.
DISPLAY 'TRES EN RAYA'.
DISPLAY '============'.
* · Tablero.
DISPLAY WS-ASTERISCOS.
DISPLAY WS-FILA(1).
DISPLAY WS-FILA(2).
DISPLAY WS-FILA(3).
DISPLAY WS-ASTERISCOS.
DISPLAY ' '.
8000-PINTAR-TABLERO-EXIT.
EXIT.
*****************************************************************
* *
* 8100-COMPROBAR-RAYA *
* ------------------------------------------------------------- *
* *
* · Sumar valor de la celda al de las rayas posibles. *
* · Comprobar raya. *
* *
*****************************************************************
8100-COMPROBAR-RAYA.
* · Sumar valor de la celda al de las rayas posibles.
EVALUATE WS-INDICE
WHEN 1
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(1)
ADD WS-INDICE TO WS-RAYA-USUARIO(4)
ADD WS-INDICE TO WS-RAYA-USUARIO(7)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(1)
ADD WS-INDICE TO WS-RAYA-MAQUINA(4)
ADD WS-INDICE TO WS-RAYA-MAQUINA(7)
END-IF
WHEN 2
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(1)
ADD WS-INDICE TO WS-RAYA-USUARIO(5)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(1)
ADD WS-INDICE TO WS-RAYA-MAQUINA(5)
END-IF
WHEN 3
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(1)
ADD WS-INDICE TO WS-RAYA-USUARIO(6)
ADD WS-INDICE TO WS-RAYA-USUARIO(8)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(1)
ADD WS-INDICE TO WS-RAYA-MAQUINA(6)
ADD WS-INDICE TO WS-RAYA-MAQUINA(8)
END-IF
WHEN 4
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(2)
ADD WS-INDICE TO WS-RAYA-USUARIO(4)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(2)
ADD WS-INDICE TO WS-RAYA-MAQUINA(4)
END-IF
WHEN 5
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(2)
ADD WS-INDICE TO WS-RAYA-USUARIO(5)
ADD WS-INDICE TO WS-RAYA-USUARIO(7)
ADD WS-INDICE TO WS-RAYA-USUARIO(8)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(2)
ADD WS-INDICE TO WS-RAYA-MAQUINA(5)
ADD WS-INDICE TO WS-RAYA-MAQUINA(7)
ADD WS-INDICE TO WS-RAYA-MAQUINA(8)
END-IF
WHEN 6
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(2)
ADD WS-INDICE TO WS-RAYA-USUARIO(6)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(2)
ADD WS-INDICE TO WS-RAYA-MAQUINA(6)
END-IF
WHEN 7
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(3)
ADD WS-INDICE TO WS-RAYA-USUARIO(4)
ADD WS-INDICE TO WS-RAYA-USUARIO(8)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(3)
ADD WS-INDICE TO WS-RAYA-MAQUINA(4)
ADD WS-INDICE TO WS-RAYA-MAQUINA(8)
END-IF
WHEN 8
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(3)
ADD WS-INDICE TO WS-RAYA-USUARIO(5)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(3)
ADD WS-INDICE TO WS-RAYA-MAQUINA(5)
END-IF
WHEN 9
IF USUARIO
ADD WS-INDICE TO WS-RAYA-USUARIO(3)
ADD WS-INDICE TO WS-RAYA-USUARIO(6)
ADD WS-INDICE TO WS-RAYA-USUARIO(7)
ELSE IF MAQUINA
ADD WS-INDICE TO WS-RAYA-MAQUINA(3)
ADD WS-INDICE TO WS-RAYA-MAQUINA(6)
ADD WS-INDICE TO WS-RAYA-MAQUINA(7)
END-IF
END-EVALUATE.
* · Comprobar raya.
MOVE ZERO TO WS-INDICE
PERFORM 8 TIMES
ADD 1 TO WS-INDICE
*> Gana usuario.
IF WS-RAYA-USUARIO(WS-INDICE) = WS-RAYA-TOTAL(WS-INDICE)
MOVE WS-MSG-GANADOR TO WS-MSG-FINAL
SET FIN TO TRUE
*> Gana máquina.
ELSE IF WS-RAYA-MAQUINA(WS-INDICE)
= WS-RAYA-TOTAL(WS-INDICE)
MOVE WS-MSG-PERDEDOR TO WS-MSG-FINAL
SET FIN TO TRUE
END-IF
END-PERFORM.
8100-COMPROBAR-RAYA-EXIT.
EXIT.
*****************************************************************
* *
* 9999-ABORTAR *
* *
*****************************************************************
9999-ABORTAR.
PERFORM 6000-ESTADISTICAS
THRU 6000-ESTADISTICAS-EXIT.
MOVE 12 TO RETURN-CODE.
9999-ABORTAR-EXIT.
STOP RUN.
*****************************************************************
* *
* F I N *
* *
***********