CMakeLists.txt

cmake_minimum_required(VERSION 3.16)
project(omni_teleop_keyboard)

if(CMAKE_CXX_COMPILER_ID MATCHES "(GNU|Clang)")
  add_compile_options(-Wall -Wextra -Wpedantic)
endif()

# Find dependencies
set(THIS_PACKAGE_INCLUDE_DEPENDS
  ament_cmake
  ament_index_cpp
  geometry_msgs
  rclcpp
  sdl2_vendor
)
foreach(Dependency IN ITEMS ${THIS_PACKAGE_INCLUDE_DEPENDS})
  find_package(${Dependency} REQUIRED)
endforeach()
find_package(sdl2_custom REQUIRED)
set(SDL2_STATIC_LIB ON)
find_package(SDL2 REQUIRED)
find_package(SDL2_ttf REQUIRED)
find_package(SDL2_image REQUIRED)

add_executable(${PROJECT_NAME} src/${PROJECT_NAME}.cpp src/clayman.cpp)
target_compile_features(${PROJECT_NAME} PUBLIC cxx_std_20)
target_include_directories(${PROJECT_NAME}
  PUBLIC $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
  $<INSTALL_INTERFACE:include/${PROJECT_NAME}>
)
target_link_libraries(${PROJECT_NAME} PRIVATE
  SDL2::SDL2main
  SDL2::SDL2-static
  SDL2_ttf::SDL2_ttf-static
  SDL2_image::SDL2_image-static
)
ament_target_dependencies(${PROJECT_NAME} PUBLIC
  ${THIS_PACKAGE_INCLUDE_DEPENDS}
)

# Install
install(
  DIRECTORY include/
  DESTINATION include/${PROJECT_NAME}/
)
install(
  TARGETS ${PROJECT_NAME}
  DESTINATION lib/${PROJECT_NAME}/
)
install(
  DIRECTORY resources
  DESTINATION share/${PROJECT_NAME}/
)

if(BUILD_TESTING)
  find_package(ament_cmake_gmock REQUIRED)

  ament_add_gmock(test_${PROJECT_NAME} test/test_${PROJECT_NAME}.cpp)
  ament_target_dependencies(test_${PROJECT_NAME}
    geometry_msgs
  )
  find_package(ament_lint_auto REQUIRED)
  ament_lint_auto_find_test_dependencies()
endif()

ament_export_dependencies(${THIS_PACKAGE_INCLUDE_DEPENDS})
ament_package()