build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "https://maven.minecraftforge.net/"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
		classpath ('com.anatawa12.forge:ForgeGradle:1.2-1.0.+') {
			changing = true
		}
    }
}

apply plugin: 'forge'
apply plugin: 'java'

compileJava.options.encoding = "UTF-8"
compileTestJava.options.encoding = "UTF-8"
compileTestJava.enabled = false

sourceCompatibility = targetCompatibility = '1.8'
compileJava {
    sourceCompatibility = targetCompatibility = '1.8'
}

version = "v417.57"
group = "gregtechmod"
archivesBaseName = "gregtechmod"

minecraft {
    version = "${mc_ver}-${forge_ver}-${mc_ver}"
    runDir = "eclipse"
	replace("@VERSION@", getValidVersion())
	replace("public static volatile int VERSION = 417",
			"public static volatile int VERSION = " + getValidVersion().replace('.', ''))

	includes.addAll([
		"GT_Mod.java",
		"GregTech_API.java",
		"BaseMetaTileEntity.java",
		"BaseMetaPipeEntity.java",
		"MetaTileEntity.java",
		"MetaPipeEntity.java",
		"GT_CircuitryBehavior.java",
		"GT_CoverBehavior.java",
		"GT_Config.java",
		"GT_LanguageManager.java",
		"GT_ModHandler.java",
		"GT_OreDictUnificator.java",
		"Recipe.java",
		"GT_Utility.java",
		"GT_RecipeRegistrator.java",
		"Element.java",
		"Materials.java",
		"OrePrefixes.java"
	])
}

repositories {
	maven {
		url = "https://gregtech.overminddl1.com/"
	}
	maven {
		name = "ChickenBones maven"
		url = "http://chickenbones.net/maven/"
	}
	maven {
		name = "forge"
        url = "https://maven.minecraftforge.net/"
	}
	maven {
		name = "cil"
		url = "https://maven.cil.li/"
	}
	maven {
		name = "buildcraft"
		url = "https://mod-buildcraft.com/maven/"
	}
	maven {
		name = "blamejared maven"
		url = "https://maven.blamejared.com/"
	}
}

jar {
	manifest {
		attributes 'FMLAT': 'gregtech_at.cfg'
		attributes 'FMLCorePluginContainsFMLMod': 'true'
		attributes 'FMLCorePlugin': 'gregtechmod.common.asm.GT_CoreMod'
	}
}

dependencies {
	compile "codechicken:CodeChickenCore:${mc_ver}-${ccc_version}:dev"
	compile "codechicken:NotEnoughItems:${mc_ver}-${nei_version}:dev"
	compile "codechicken:CodeChickenLib:${mc_ver}-${ccl_version}:dev"
	compile "net.sengir.forestry:forestry_${mc_ver}:${forestry_ver}:dev"
	compile "net.industrial-craft:industrialcraft-2:${ic2_ver}-experimental:dev"
	compile "MineTweaker3:MineTweaker3-MC1710-Main:${mc_ver}-${ct_version}" // CraftTweaker (MineTweaker3)
	compile files("libs/CoFHCore-[1.7.10]3.1.4-329-dev.jar")
	compile files("libs/ThermalDynamics-[1.7.10]1.2.1-172-dev.jar")
	compile files("libs/ThermalExpansion-[1.7.10]4.1.5-248-dev.jar")
	compile files("libs/ThermalFoundation-[1.7.10]1.2.6-118-dev.jar")
	compile files("libs/Railcraft_1.7.10-9.12.2.1-dev.jar")
	compile files("libs/MineFactoryReloaded-[1.7.10]2.8.1-174-dev.jar")
}

processResources {
	// this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version': getValidVersion(), 'mcversion':project.minecraft.version
    }

    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

def getValidVersion() {
	def version = new StringBuilder(project.version.toString())
	version.deleteCharAt(0)
	version.insert(1, '.')
	return version.toString()
}