DurabilityGuard/settings.gradle.kts at main · BigBrainRobin29/DurabilityGuard · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
pluginManagement {
    repositories {
        gradlePluginPortal()
        mavenCentral()

        // Modstitch
        maven("https://maven.isxander.dev/releases/")

        // Loom platform
        maven("https://maven.fabricmc.net/")

        // MDG platform
        maven("https://maven.neoforged.net/releases/")

        // Stonecutter
        maven("https://maven.kikugie.dev/releases")
        maven("https://maven.kikugie.dev/snapshots")
    }
}

plugins {
    id("dev.kikugie.stonecutter") version "0.9+"
}

stonecutter {
    kotlinController = true
    centralScript = "build.gradle.kts"

    create(rootProject) {
        fun mc(mcVersion: String, name: String = mcVersion, loaders: Iterable<String>) =
            loaders.forEach { version("$name-$it", mcVersion) }

        mc("1.20", loaders = listOf("fabric"))
        mc("1.20.3", loaders = listOf("fabric"))
        mc("1.21", loaders = listOf("fabric", "neoforge"))
        mc("1.21.2", loaders = listOf("fabric", "neoforge"))
        mc("1.21.9", loaders = listOf("fabric", "neoforge"))
        mc("1.21.11", loaders = listOf("neoforge"))
        mc("26.1", loaders = listOf("fabric", "neoforge"))

        vcsVersion = "26.1-fabric"
    }
}

rootProject.name = "Durability Guard"