I cannot figure out output position (niri)

[shaqaruden]

I have had a heck of time trying to figure out how to set position for my displays. I have every combination of values that I could think of that makes sense but nothing returns the proper KDL format. I tried using Google Gemini, Claude, ChatGPT, Kagi Assistant and plain Web Searches all either giving me something I have already tried or something that just plain does not work

I have tried

position = "x=3440 y=0";

position = {
  x = 3440;
  y = 0;
};

position = [ "x=3440" "y=0"];

and some other weird ones that AI gave that are just simply syntactically wrong. I am looking for my main

here is my entire niri config

{
  self,
  inputs,
  ...
}: {
  flake.nixosModules.nixiri = {
    pkgs,
    lib,
    ...
  }: {
    programs.niri = {
      enable = true;
      package = self.packages.${pkgs.stdenv.hostPlatform.system}.nixiri;
    };
  };

  perSystem = {
    pkgs,
    lib,
    self',
    ...
  }: {
    packages.nixiri = inputs.wrapper-modules.wrappers.niri.wrap {
      inherit pkgs;

      settings = {
        spawn-at-startup = [
          (lib.getExe self'.packages.nixtalia)
        ];

        outputs = {
          "DP-7" = {
            focus-at-startup = true;
            variable-refresh-rate = true;
            mode = "3440x1440@175";
            position = "x=0 y=0";
          };
          "DP-5" = {
            position = "x=3440 y=0";
            mode = "2560x1440@165";
          };
        };

        xwayland-satellite.path =
          lib.getExe pkgs.xwayland-satellite;

        input.keyboard = {
          xkb.layout = "us";
        };

        layout.gaps = 5;

        binds = {
          "Super+Return".spawn-sh = lib.getExe pkgs.ghostty;
          "Super+Q".close-window = null;
          "Super+Space".spawn-sh = "${lib.getExe self'.packages.nixtalia} ipc call launcher toggle";
        };
      };
    };
  };
}

[BirdeeHub]

It is done like this (now)

nix-wrapper-modules/wrapperModules/n/niri/check.nix

Lines 75 to 88 in 01cb23e

	outputs = {
	"DP-3" = {
	position = _: {
	props = {
	x = 1440;
	y = 1080;
	};
	};
	background-color = "#003300";
	hot-corners = {
	off = _: { };
	};
	};
	};

^ If that throws an error, update nix-wrapper-modules, it has been very recently updated. This way with a function is more complete, and implements the whole kdl spec now.

It used to be done like this

nix-wrapper-modules/wrapperModules/n/niri/check.nix

Lines 77 to 82 in 23b8770

	position = {
	_attrs = {
	x = 1440;
	y = 1080;
	};
	};

And also you used to include null if you wanted just the node name.

However, null is an actual thing in kdl, written #null

So, now to represent that, you do somename = _: {} instead of somename = null

If you were doing it correctly before, you will get a deprecation warning about this which tells you where they are and what to change (I hope, assuming my convertAndWarn function works correctly. It can be disabled with v2-settings once your config is compatible with the new version).

The reason for the confusion is that in kdl, a node can look like

  f "arg1" "key"="val" {
    g
  }

Or even weirder

  (string)"p" (string)"q" "r"=(string)"s" {
    "t" #null
    "t" 1
    "t" 2
  }

This means that a simple set conversion is not enough, we need some kind of meta info. We solve this issue by providing a function which allows us to return a set with more options if required.

There is now also a wlib.toKdl so, there is more info about this format in the docs than there was before

https://birdeehub.github.io/nix-wrapper-modules/lib/wlib.html#function-library-wlib.toKdl

You can actually also

    outputs = {
      "DP-3" = {
        position = [
          {
            x = 1440;
            y = 1080;
          }
          (_: { }) # <- stop it from treating this like a list of nodes and instead as props (empty functions become nothing)
        ];
        background-color = "#003300";
        hot-corners = {
          off = _: { };
        };
      };
    };

The function should return a set, because that would be how you set the extra options, but if you want a function to become just a blank value, they can return whatever as long as it doesn't have those values in it.

So you could even do

    outputs = {
      "DP-3" = {
        position = [
          {
            x = 1440;
            y = 1080;
          }
          (_: 1) # <- still becomes nothing
        ];
        background-color = "#003300";
        hot-corners = {
          off = _: 1; # <- also nothing, this node only has a name
        };
      };
    };

And those functions will still translate into nothing, other than maybe some weird but semantically insignificant spacing

I also have moved the issue to discussions (and also added nix highlighting to your question), because it just changed, and I want to leave it up for a bit.

[BirdeeHub]

In short, (and using the weird syntax I mentioned at the end a little bit because why not):

{ self, inputs, ... }: {
  flake.nixosModules.nixiri = { pkgs, lib, ... }: {
    programs.niri = {
      enable = true;
      package = self.packages.${pkgs.stdenv.hostPlatform.system}.nixiri;
    };
  };

  perSystem = { pkgs, lib, self', ... }: {
    packages.nixiri = inputs.wrapper-modules.wrappers.niri.wrap {
      inherit pkgs;
      v2-settings = true; # <- stops it from checking to do the deprecation warning from the most recent commit
      settings = {
        spawn-at-startup = [
          (lib.getExe self'.packages.nixtalia)
        ];

        outputs = {
          "DP-7" = {
            focus-at-startup = true;
            variable-refresh-rate = true;
            mode = "3440x1440@175";
            position = _: { props = { x = 0; y = 0; }; }; # <- like this
          };
          "DP-5" = {
            position = [ { x = 3440; y = 0; } (_: { }) ]; # <- or like this 
            mode = "2560x1440@165";
          };
        };

        xwayland-satellite.path = lib.getExe pkgs.xwayland-satellite;

        input.keyboard = {
          xkb.layout = "us";
        };

        layout.gaps = 5;

        binds = {
          "Super+Return".spawn-sh = lib.getExe pkgs.ghostty;
          "Super+Q".close-window = _: { };
          # ^ also when you update you are going to have to change this one from null to this
          # and if you leave v2-settings as false it will tell you about that without failing the build
          "Super+Space".spawn-sh = "${lib.getExe self'.packages.nixtalia} ipc call launcher toggle";
        };
      };
    };
  };
}

[BirdeeHub]

Also, since you are already using flake-parts, might I suggest:

{ self, inputs, ... }: {
  flake.nixosModules.nixiri = { pkgs, lib, ... }: {
    programs.niri = {
      enable = true;
      package = self.packages.${pkgs.stdenv.hostPlatform.system}.nixiri;
    };
  };

  # Import the flake parts module to use flake.wrappers.<name>
  imports = [ inputs.wrapper-modules.flakeModules.wrappers ];
  # then you can self.wrappers.nixiri.wrap { inherit pkgs; }
  # inputs.wrapper-modules.evalPackage [ self.wrapperModules.nixiri { inherit pkgs; } ]
  # and self.packages.${system}.nixiri

  flake.wrappers.nixiri = { pkgs, lib, wlib, ... }: let
    inherit (self.packages.${pkgs.stdenv.hostPlatform.system}) nixtalia;
  in {
    imports = [ wlib.wrapperModules.niri ]; # <- import the niri wrapper module
    v2-settings = true; # <- stops it from checking to do the deprecation warning from the most recent commit
    settings = {
      spawn-at-startup = [
        (lib.getExe nixtalia)
      ];
      outputs = {
        "DP-7" = {
          focus-at-startup = true;
          variable-refresh-rate = true;
          mode = "3440x1440@175";
          position = _: { props = { x = 0; y = 0; }; }; # <- like this
        };
        "DP-5" = {
          position = [ { x = 3440; y = 0; } (_: { }) ]; # <- or like this
          mode = "2560x1440@165";
        };
      };
      xwayland-satellite.path = lib.getExe pkgs.xwayland-satellite;
      input.keyboard = {
        xkb.layout = "us";
      };
      layout.gaps = 5;
      binds = {
        "Super+Return".spawn-sh = lib.getExe pkgs.ghostty;
        "Super+Q".close-window = _: { };
        # ^ also when you update you are going to have to change this one from null to this
        # and if you leave v2-settings as false it will tell you about that without failing the build
        "Super+Space".spawn-sh = "${lib.getExe nixtalia} ipc call launcher toggle";
      };
    };
  };
}

[shaqaruden]

Thanks! Lots of info here will need to read it again when I'm back on my desktop. I just watch the Vimjoyer video on using Flake Parts, Nix Wrappers, Niri and Noctalia this past weekend so this is still VERY new to me. I was having some issues with my old config so I thought after watching that video would be the perfect and poorest time to just start with a fresh install and completely change how I build my system 👍😅

Should add I got my outputs working correctly now. I appreciate the quick response!