"The option `flake.wrappers.neovim.addFlag' does not exist" error when using .install with flake-parts

[rishyramen]

error: The option `flake.wrappers.neovim.addFlag' does not exist. Definition values:
- In `/nix/store/ksqg3ja7xwak87yhyylm3qb6mpps5pl6-source/terminal/neovim.nix': [ ]
- Did you mean `flake.wrappers.neovim.apply', `flake.wrappers.neovim.drv' or `flake.wrappers.neovim.eval'?

I receive the above error when using .install on the wrapper module. I don't encounter this issue when using getInstallModule though the documentation seems to suggest this shouldn't be necessary if I'm using the wrapper flake modules? Below is my neovim flake-parts module.

{
  config,
  lib,
  self,
  inputs,
  ...
}:
let
  inherit (inputs) nixpkgs wrappers;
  module = nixpkgs.lib.modules.importApply ./module.nix {
    inherit inputs;
    flake-path = "${self}";
  };
  wrapper = wrappers.lib.evalModule module;
in
{
  imports = [ wrappers.flakeModules.wrappers ];

  flake = {
    wrappers.neovim = wrapper.config;
    overlays.neovim = final: prev: { neovim = wrapper.config.wrap { pkgs = final; }; };
    homeModules.neovim =
      { config, lib, ... }:
      let
        inherit (config.home) dotfilesDir;
        inherit (config.lib.file) mkOutOfStoreSymlink;
        cfg = config.wrappers.neovim;
      in
      {
        imports = [ self.wrappers.neovim.install ];

        wrappers.neovim = {
          enable = true;

          settings.config_directory = lib.mkForce (mkOutOfStoreSymlink "${dotfilesDir}/terminal/neovim");
        };

        home.sessionVariables = lib.mkIf cfg.enable {
          EDITOR = "${cfg.wrapper}/bin/nvim";
          VISUAL = "${cfg.wrapper}/bin/nvim";
        };

        programs.zsh.shellAliases = {
          vi = cfg.binName;
        };
      };
  };
}

[BirdeeHub]

    wrappers.neovim = wrapper.config;

^ the problem is that line

You are importing just the config set of a module as a module

So, it is missing the import statements and stuff, such as the one that imports the base neovim module from this repo.

I would think, with what you have, that building the package directly via nix build .#neovim also does not work, correct?

What you are looking for is:

    wrappers.neovim = module;

i.e.

{
  config,
  lib,
  self,
  inputs,
  ...
}:
let
  inherit (inputs) nixpkgs wrappers;
  # if you set _file and key in the module you dont need importApply you can just import and call it
  # but I left it here for now anyway
  module = nixpkgs.lib.modules.importApply ./module.nix {
    inherit inputs;
    flake-path = "${self}";
  };
in
{
  imports = [ wrappers.flakeModules.wrappers ];

  flake = {
    # this is a submodule option. It accepts modules. (it was created with wlib.types.subWrapperModule)
    wrappers.neovim = module; # <- this was where your bug was from.

    # you should use self.wrappers.neovim here probably, since we got rid of the thing we were getting this from before
    overlays.neovim = final: prev: { neovim = self.wrappers.neovim.wrap { pkgs = final; }; };
    # same thing you had (although improvements for this are below)
    homeModules.neovim =
      { config, lib, ... }:
      let
        inherit (config.home) dotfilesDir;
        inherit (config.lib.file) mkOutOfStoreSymlink;
        cfg = config.wrappers.neovim;
      in
      {
        imports = [ self.wrappers.neovim.install ];

        wrappers.neovim = {
          enable = true;

          settings.config_directory = lib.mkForce (mkOutOfStoreSymlink "${dotfilesDir}/terminal/neovim");
        };

        home.sessionVariables = lib.mkIf cfg.enable {
          EDITOR = "${cfg.wrapper}/bin/nvim";
          VISUAL = "${cfg.wrapper}/bin/nvim";
        };

        programs.zsh.shellAliases = {
          vi = cfg.binName;
        };
      };
  };
}

---

However some things that may be of interest for you

3 things I notice about your config

1. for the neovim module we actually have a config.settings.aliases, you don't need to declare those in home manager if you don't want to. For most of the other modules, it is just config.aliases, but basically all of them have this option or an equivalent. It makes a symlink in the bin directory of the derivation to the main wrapper output path

2. settings.config_directory already allows an impure path, no need to use mkOutOfStoreSymlink (and also we offer wlib.mkOutOfStoreSymlink anyway if you need it)

3. You are declaring a separate home manager module. You can actually add stuff to the install module directly (shown in the next section of this reply)

---

In my config I have this

  config.install.modules.homeManager = { config, lib, ... }: let
    cfg = top.config.install.getWrapperConfig config;
  in {
    home.sessionVariables = lib.mkIf cfg.enable (let
      nvimpath = lib.getExe cfg.wrapper;
    in {
      EDITOR = nvimpath;
      MANPAGER = "${nvimpath} +Man!";
    });
  };

You could do all of it like

{ config, lib, wlib, ... }@top: { # <- this is a wrapper module to import inside your neovim wrapper module
  config.settings.aliases = [ "vi" ]; # <- add the vi alias
  config.install.modules.homeManager = { config, lib,  ... }: let # <- add instructions to the install module for home manager
    # get the wrapper config from top.config.install.optionLocation
    cfg = top.config.install.getWrapperConfig config;
  in {
    config = lib.mkMerge [ # <- mkMerge is fancy // (which would work here too, but this is technically better)
      # creates an extra wrapper module at the correct top.config.install.optionLocation
      (top.config.install.mkWrapperExtension "this name just has to be unique for this nvim wrapper module" {
        # It accepts an impure path, no need to wlib.mkOutOfStoreSymlink
        settings.config_directory = lib.mkForce "${config.home.dotfilesDir}/terminal/neovim";
      })
      # the rest of the regular home manager config set
      {
        home.sessionVariables = lib.mkIf cfg.enable (let
          nvimpath = lib.getExe cfg.wrapper;
        in {
          EDITOR = nvimpath;
          MANPAGER = "${nvimpath} +Man!";
        });
      }
    ];
  };
}

And then the install module you have will include all the instructions and you wouldn't need to declare it as a separate home manager module.

So, then your flake-parts module with all the neovim stuff would look something like

{
  config,
  lib,
  self,
  inputs,
  ...
}:
let
  inherit (inputs) nixpkgs wrappers;
  module = nixpkgs.lib.modules.importApply ./module.nix {
    inherit inputs;
    flake-path = "${self}";
  };
in
{
  imports = [ wrappers.flakeModules.wrappers ];
  flake = {
    wrappers.neovim = { imports = [ module ./thatfileIputabovewiththeinstallmoduleadditions.nix ]; }; # <- or you could import the file inside the ./module.nix idk, I just wanted to have it in the example
    overlays.neovim = final: prev: { neovim = self.wrappers.neovim.wrap { pkgs = final; }; };
    # homeModules.neovim = self.wrappers.neovim.install; # or, more exactly what you had
    homeModules.neovim = { imports = [ self.wrappers.neovim.install; ]; wrappers.neovim.enable = true; };
  };
}

---

Also you might find this flake parts module useful

{ inputs, ... }: # <- idk, however you want to get inputs, this one was called with importApply
{ config, ... }:
{
  _file = ./thisfile.nix;
  key = ./thisfile.nix;
  imports = [
    inputs.flake-parts.flakeModules.modules
    inputs.wrappers.flakeModules.wrappers
  ];
  config.flake.modules.generic = builtins.mapAttrs (_: v: v.install) config.flake.wrappers;
}

And probably also eventually this discussion #493

---

Also, whenever you see that particular error message, it almost certainly means you did not import wlib.modules.default, or more specifically, wlib.modules.makeWrapper somehow. In this case, it happened because you imported the config set of a module, and not the module itself.

[rishyramen]

Thank you, I got my config working in the ideal way now!

Fyi, some of my confusion stemmed from initially following https://github.com/BirdeeHub/nix-wrapper-modules/blob/main/templates/neovim/flake.nix (which is why I had wrappers.neovim = wrapper.config;) but after the mkInstallModule deprecation and switching over to flake-parts it wasn't quite clear what the appropriate changes to the config should be and the details seemed kind of scattered across the wrapper lib/core documentation. For example I initially did try using the wrapper module instead of the wrapper config but I naively tried imports = [ module.install ] instead of imports = [ self.wrappers.neovim.install ] but if you do that module.install is missing so I thought I was doing something wrong. I believe this has to do with some behaviors of flake-parts modules which I don't really have a deep understanding of.

And thank you for the additional suggestions! I opted not to do 1. because I needed the process path suffix to stay as nvim for some other parts of my setup (the symlink would change it to the alias), but I'll incorporate the rest.