Migrating from nixcats - "definition for option data is not of type null..."

[mettavi]

Hi, I have been using nixcats using the lazy template, but I would now like to remove lazy.nvim completely using the neovim wrapper from nix-wrapper-modules.

I am trying to implement this as a home-manager module. I am running home-manager as a module of nixos.

I started using the code from https://birdeehub.github.io/nix-wrapper-modules/md/getting-started.html#nixos-home-manager-and-friends along with code from the neovim template at https://github.com/BirdeeHub/nix-wrapper-modules/tree/main/templates/neovim

At first I had a lot of errors, so I decided to get it working with a minimal example first. Here is the code I managed to get working:

# nvim-wrap/default.nix
{
  config,
  inputs,
  lib,
  ...
}:
with lib;
let
  cfg = config.mettavi.shell.nvim-lib;
in
{
  # import the neovim wrapper module
  imports = [
    (inputs.wrappers.lib.getInstallModule {
      name = "neovim";
      value = inputs.wrappers.lib.wrapperModules.neovim;
    })
  ];

  options.mettavi.shell.nvim-lib = {
    enable = mkEnableOption "set up and configure the nvim wrapper module";
    cats = lib.mkOption {
      readOnly = true;
      type = lib.types.attrsOf lib.types.bool;
      default = builtins.mapAttrs (_: v: v.enable) config.specs;
    };
  config = mkIf cfg.enable {
    wrappers.neovim =
      { pkgs, ... }:
      {
        enable = true;
        env.NVIM_APPNAME = "nvim-wrap";
        # If you want to install multiple neovim derivations via home.packages or environment.systemPackages
        # in order to prevent path collisions:
        # set this to true:
        settings.dont_link = true;
        # and make sure these dont share values:
        binName = "nvw";
        # settings.aliases = [ ];

        settings.config_directory = ./config;

        specs.stylix = {
          data = with pkgs.vimPlugins; [
            mini-base16
            lazydev-nvim
          ];
          before = [ "INIT_MAIN" ];
          config = /* lua */ ''
            local info, pname, lazy = ...
            require("mini.base16").setup({ palette = info, })
          '';
        };
      };

    xdg.configFile = {
      "nvim-wrap".source = ./config;
    };
  }
 
  };
}

So, it works using specs.stylix, but anything else causes an error. When I add the following:

        specs.lua = {
          after = [ "lazy" ];
          lazy = true;
          data = with pkgs.vimPlugins; [
            lazydev-nvim
          ];
          extraPackages = with pkgs; [
            lua-language-server
            stylua
          ];
        };

I get the following error:

       error: A definition for option `home-manager.users.timotheos.wrappers.neovim.specs.lua.data' is not of type `null or str|path|drv or list of spec with main field: `data` of (null or str|path|drv)'. Definition values:
       - In `/nix/store/d5ndqy86a9is1wjyickly0xr5v94h2r7-source/home/shared/modules/shell/nvim-wrap':
           {
             after = [
               "lazy"
             ];
             data = [
           ...

I get the same error if I add specs.bash, specs.nix, or anything else.

Now, I am sure I am making a silly mistake here, can anyone help me solve this problem?

[nikoof]

Hey, I'm running into a similar issue trying to migrate from nixCats. I'm not a Nix expert by any means, but as far as I can see the problem is caused by setting extraPackages in a spec, which doesn't conform to its type. The documentation doesn't mention the attribute extraPackages for specs.<name> either, so it seems to only be a top-level attribute on the module. I'm not sure if the template is somehow stale, or if I am also missing something.

One other idea I had was to use the top-level extraPackages with lib.lists.optionals to add the packages, since the documentation says that specs.<name>.enable is an option. This seems to work, but I'm not sure how you're supposed to set this from outside the module declaration (which could very well be because I am fundamentally misunderstanding how this entire system is supposed to work). Can anyone clarify what is the intended way to conditionally include stuff like LSPs and formatters?

[BirdeeHub]

Oh! yep

That is probably it.

extraPackages is not something defined on the specs by default. You have to do that yourself. You can add anything you want to those specs, but the things you pass need to be valid

It is mentioned in the neovim Tips and Tricks section, and also it is shown in the template!

nix-wrapper-modules/templates/neovim/module.nix

Lines 167 to 202 in dc51840

	# These are from the tips and tricks section of the neovim wrapper docs!
	# https://birdeehub.github.io/nix-wrapper-modules/neovim.html#tips-and-tricks
	# We could put these in another module and import them here instead!
	# This submodule modifies both levels of your specs
	config.specMods =
	{
	# When this module is ran in an inner list,
	# this will contain `config` of the parent spec
	parentSpec ? null,
	# and this will contain `options`
	# otherwise they will be `null`
	parentOpts ? null,
	parentName ? null,
	# and then config from this one, as normal
	config,
	# and the other module arguments.
	...
	}:
	{
	# you could use this to change defaults for the specs
	# config.collateGrammars = lib.mkDefault (parentSpec.collateGrammars or false);
	# config.autoconfig = lib.mkDefault (parentSpec.autoconfig or false);
	# config.runtimeDeps = lib.mkDefault (parentSpec.runtimeDeps or false);
	# config.pluginDeps = lib.mkDefault (parentSpec.pluginDeps or false);
	# or something more interesting like:
	# add an extraPackages field to the specs themselves
	options.extraPackages = lib.mkOption {
	type = lib.types.listOf wlib.types.stringable;
	default = [ ];
	description = "a extraPackages spec field to put packages to suffix to the PATH";
	};
	# You could do this too
	# config.before = lib.mkDefault [ "INIT_MAIN" ];
	};
	config.extraPackages = config.specCollect (acc: v: acc ++ (v.extraPackages or [ ])) [ ];

In the above template, using the created extraPackages on the specs will allow you to enable or disable packages alongside those specs, as the values from config.specCollect have been filtered already.

config.specMods = {
  options.extraPackages = lib.mkOption { 
    type = lib.types.listOf wlib.types.stringable; 
    default = [ ]; 
    description = "a extraPackages spec field to put packages to suffix to the PATH"; 
  };
};
config.extraPackages = config.specCollect (acc: v: acc ++ (v.extraPackages or [ ])) [ ]; 

[nikoof]

Ah, I was a bit impatient and didn't read the entire thing, my bad. This makes a lot more sense now. Thanks a lot for the help!

[BirdeeHub]

Thanks for chiming in, I think you pointed out what was wrong for the other user too. I had only skimmed it and had not noticed yet but you pointed it out well.

[BirdeeHub]

You can do really quite a lot with just specMods and specCollect. There is also specMaps which lets you do whatever you want, but if you need it, you are probably doing something REALLY specific and otherwise you should see if you can do it another way XD

Heres my current list of spec modifications from my config if you wanted some ideas. Mine accept wrapper modules haha

{ config, lib, wlib, pkgs, ... }: {
  config.specMods = { config, ... }: let
    wrappers = lib.pipe config.wrappers [
      builtins.attrValues
      (builtins.filter (v: v.enable))
      (lib.partition (v: v.prefix))
      ({ right, wrong, }: {
        pre = map (v: v.wrapper) right;
        post = map (v: v.wrapper) wrong;
      })
    ];
  in {
    # I split it into prepkgs and postpkgs instead of just extraPackages (which is post)
    options.prepkgs = lib.mkOption {
      type = lib.types.listOf wlib.types.stringable;
      description = "a prepkgs spec field to put packages to prefix to the PATH";
    };
    config.prepkgs = wrappers.pre;
    options.postpkgs = lib.mkOption {
      type = lib.types.listOf wlib.types.stringable;
      description = "a postpkgs spec field to put packages to suffix to the PATH";
    };
    config.postpkgs = wrappers.post;
    options.mainInfo = lib.mkOption {
      type = wlib.types.attrsRecursive;
      default = {};
      description = "an optional mainInfo spec field to add to the main info plugin instead of the spec specific one";
    };
    options.settings = lib.mkOption {
      type = lib.types.submoduleWith { modules = [ { freeformType = wlib.types.attrsRecursive; } ]; };
      default = {};
      description = "no-op freeform submodule for putting stuff in a spec and grabbing it in that spec in a way that acts like settings for that spec";
    };
    options.wrappers = lib.mkOption {
      type = lib.types.attrsOf (wlib.types.subWrapperModule {
        config.pkgs = pkgs;
        options.prefix = lib.mkOption {
          type = lib.types.bool;
          default = false;
        };
        options.enable = lib.mkOption {
          type = lib.types.bool;
          default = true;
        };
      });
      default = {};
      description = "attrs of wrapper modules to be installed with this spec";
    };
  };
  config.info = lib.mkMerge (config.specCollect (acc: v: acc ++ lib.optional (v.mainInfo or {} != {}) v.mainInfo) []);
  config.prefixVar = let
    autodeps = config.specCollect (acc: v: acc ++ (v.prepkgs or [])) [];
  in lib.optional (autodeps != []) {
    name = "PREPKGS_ADDITIONS";
    data = [
      "PATH"
      ":"
      "${lib.makeBinPath (lib.unique autodeps)}"
    ];
  };
  config.suffixVar = let
    autodeps = config.specCollect (acc: v: acc ++ (v.postpkgs or [])) [];
  in lib.optional (autodeps != []) {
    name = "POSTPKGS_ADDITIONS";
    data = [
      "PATH"
      ":"
      "${lib.makeBinPath (lib.unique autodeps)}"
    ];
  };
}

[nikoof]

Thanks for the examples. They are quite helpful. If you don't mind me asking about one more thing. Is specs.<name>.enable meant to be set outside the neovim module declaration? If I try to set it in .apply or similar,

nvimFull = nvimWrapper.config.apply {
  specs.nix.enable = true;
};

I get

error: A definition for option `specs.nix.data' is not of type `null or str|path|drv or list of spec with main field: `data` of (null or str|path|drv)'. Definition values:
- In `<unknown-file>':
    {
      enable = true;
    }

Adding it to specMods doesn't seem to work either. I get an error saying it's already declared.

error: The option `enable' in `/nix/store/<hash>-source/wrapperModules/n/neovim/module.nix' is already declared in `/nix/store/<hash>-source/nvim/module.nix, via option specMods'.

[BirdeeHub]

So, it can. But yeah...

That is the 1 footgun with the wlib.types.spec type

https://birdeehub.github.io/nix-wrapper-modules/lib/wlib.html#function-library-wlib.ignoreSpecField

Hopefully this value/helper thing and its description explain what to do.

specs.nix = { ... }: { enable = true; }; but more about why is explained there

i.e. like this

[nikoof]

Ah, got it. This indeed makes it work for me. Thanks again for the tips, and also for the very quick replies!

[BirdeeHub]

The definition of wlib.ignoreSpecField is the most cursed line of nix code I have ever written. (wlib.ignoreSpecField = lib.mkIf false null;)

[BirdeeHub]

Happy to continue the discussion here, but I haven't been having any such issues so I figure it would be best to continue the discussion here if needed.

[mettavi]

Thanks a lot to both of you for the help. That points me in the right direction, but I still have a problem. To be honest, I feel a bit out of my depth, but I will persist for a bit longer.

I added the code you suggested, so that now I have:

{
  config,
  inputs,
  lib,
  ...
}:
with lib;
let
  cfg = config.mettavi.shell.nvim-lib;
in
{
  # import the neovim wrapper module
  imports = [
    (inputs.wrappers.lib.getInstallModule {
      name = "neovim";
      value = inputs.wrappers.lib.wrapperModules.neovim;
    })
  ];

  options.mettavi.shell.nvim-lib = {
    enable = mkEnableOption "set up and configure the nvim wrapper module";
    cats = lib.mkOption {
      readOnly = true;
      type = lib.types.attrsOf lib.types.bool;
      default = builtins.mapAttrs (_: v: v.enable) config.specs;
    };

 config = mkIf cfg.enable {
    specMods = {
      options.extraPackages = lib.mkOption {
        type = lib.types.listOf wlib.types.stringable;
        default = [ ];
        description = "a extraPackages spec field to put packages to suffix to the PATH";
      };
    };
    extraPackages = config.specCollect (acc: v: acc ++ (v.extraPackages or [ ])) [ ];

    wrappers.neovim =
      { pkgs, ... }:
      {
        enable = true;
        env.NVIM_APPNAME = "nvim-wrap";
        # If you want to install multiple neovim derivations via home.packages or environment.systemPackages
        # in order to prevent path collisions:
        # set this to true:
        settings.dont_link = true;
        # and make sure these dont share values:
        binName = "nvw";
        # settings.aliases = [ ];

        settings.config_directory = ./config;

        specs.lua = {
          # after = [ "lazy" ];
          lazy = true;
          data = with pkgs.vimPlugins; [
            lazydev-nvim
          ];
          extraPackages = with pkgs; [
            lua-language-server
            stylua
          ];
        };

        specs.stylix = {
          data = with pkgs.vimPlugins; [
            mini-base16
            lazydev-nvim
          ];
          before = [ "INIT_MAIN" ];
          # info = lib.filterAttrs (
          #   k: v: builtins.match "base0[0-9A-F]" k != null
          # ) config.lib.stylix.colors.withHashtag;
          config = /* lua */ ''
            local info, pname, lazy = ...
            require("mini.base16").setup({ palette = info, })
          '';
        };
      };

    xdg.configFile = {
      "nvim-wrap".source = ./config;
    };
  }

But when I do nixos-rebuild, I get:

error: attribute 'specCollect' missing
       at /home/timotheos/.nix-config/home/shared/modules/shell/nvim-wrap/default.nix:65:21:
           64|     };
           65|     extraPackages = config.specCollect (acc: v: acc ++ (v.extraPackages or [ ])) [ ];

I have a feeling I may have inserted that code in the wrong place, but I don't really know. Any suggestions?

[nikoof]

I think specMods and extraPackages should go under the wrappers.neovim module, not at the top-level of your home-manager module.

[mettavi]

Thanks a lot for the suggestion, that seems to have helped a bit, but now I am getting a different error:

error: undefined variable 'wlib'
       at /home/timotheos/.nix-config/home/shared/modules/shell/nvim-wrap/default.nix:76:37:
           75|           options.extraPackages = lib.mkOption {
           76|             type = lib.types.listOf wlib.types.stringable;
             |                                     ^
           77|             default = [ ];

As I am using this as a home-manager module, all I have in my flake.nix is:

inputs.wrappers = {
      url = "github:BirdeeHub/nix-wrapper-modules";
      inputs.nixpkgs.follows = "nixos-pkgs";
    };

And I don't know how to call the wlib prefix.

[nikoof]

I think just take wlib as a parameter in the module. Now that I look at it, if you do that you should probably also have config there (but if I understand how modules work correctly it should be fine either way). Something like

wrappers.neovim =
  { config, pkgs, wlib ... }:
  {
    specMods = {
      options.extraPackages = lib.mkOption {
        type = lib.types.listOf wlib.types.stringable;
        default = [ ];
        description = "a extraPackages spec field to put packages to suffix to the PATH";
      };
    };
    extraPackages = config.specCollect (acc: v: acc ++ (v.extraPackages or [ ])) [ ];

    # ...
  };

[mettavi]

That worked, thank you so much for your generous help!

[mettavi]

One more question: is this code necessary, or does the module take care of it already?...

    xdg.configFile = {
      "nvim-wrap".source = ./config;
    };

Regarding the extraPackage problem, at least I know how to make it work by adding this at the top level.

[nikoof]

I would say it isn't. If you set settings.config_directory to anything but a str, the wrapper should handle pointing Neovim to the correct config. If you want home-manager to handle placing your config under ~/.config/nvim-wrap, then you should set it to something like /home/<user>/.config/nvim-wrap (or however you spell that in home-manager). But I don't think there's any point in doing that, since the whole point of using wrappers is so you can have your config outside of $HOME.

[mettavi]

That makes sense, thank you.