Correct syntax for niri config file

[sizmen]

How do I write the nix expression correctly to get this in the niri config file:
Mod+Space repeat=false { toggle-overview; }

I don’t know how to insert repeat=false into an expression:
"Mod+Space".toggle-overview = _: {};

[Majavaa]

It is something like...

"Mod+Space".toggle-overview = _: {
  props.repeat = false;
};

[BirdeeHub]

"Mod+Space" = _: {
  props.repeat = false;
  content.toggle-overview = _: { };
};

"Mod+Space" "repeat"=false {
  "toggle-overview"
}

The props are on the Mod+Space block

When we need both a block and props, we need to provide a function

---

Increasingly unhinged examples below.

wlib.toKdl [
  { position = _: { props = { x = 0; y = 0; }; }; }
  { position = [ { x = 3440; y = 0; } (_: { }) ]; }
]

position "x"=0 "y=0"
position "x"=3440 "y=0"

wlib.toKdl {
  "Mod+Space" = _: {
    props = [ "hi" { repeat = _: { type = "bool"; content = false; }; } ];
    content = [
      { toggle-overview = _: { }; }
      { toggle-overview = _: { }; }
      { toggle-overview = _: { type = "string"; }; }
    ];
  };
}

"Mod+Space" "hi" "repeat"=(bool)false {
  "toggle-overview"
  "toggle-overview"
  (string)"toggle-overview"
}

You can also completely phone it in whenever

wlib.toKdl {
  "Mod+Space" = _: {
    custom = { indent, lvl, name }: ''
    Mod+Space "hi" "repeat"=(bool)false {
      toggle-overview
      toggle-overview
      (string)toggle-overview
    }
    '';
  };
}

wlib.toKdl {
  "Mod+Space" = _: {
    custom = { indent, lvl, name }: ''
    ${wlib.genStr indent lvl}${name} "hi" "repeat"=(bool)false {
    ${wlib.genStr indent (lvl + 1)}toggle-overview
    ${wlib.genStr indent (lvl + 1)}toggle-overview
    ${wlib.genStr indent (lvl + 1)}(string)toggle-overview
    ${wlib.genStr indent lvl}}
    '';
  };
}

Or... uhhhhhh.... toKdl inception (idk why you would do this but you can)

wlib.toKdl {
  "Mod+Space" = self: {
    custom = { indent, lvl, name, }:
      "${wlib.toKdl (_: {
        inherit lvl indent;
        content = {
          ${name} = _: removeAttrs self [ "custom" ];
        };
      })}";
    props = [ "hi" { repeat = _: { type = "bool"; content = false; }; } ];
    content = [
      { toggle-overview = _: { }; }
      { toggle-overview = _: { }; }
      { toggle-overview = _: { type = "string"; }; }
    ];
  };
}

"Mod+Space" "hi" "repeat"=(bool)false {
  "toggle-overview"
  "toggle-overview"
  (string)"toggle-overview"
}