server/build.gradle at develop · BookMoA/server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.3.1'
	id 'io.spring.dependency-management' version '1.1.5'
	id 'com.diffplug.spotless' version '6.23.3'
	id 'com.google.cloud.tools.jib' version '3.4.3'
}

group = 'com.umc'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(17)
	}
}


configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {

	implementation 'org.springframework.boot:spring-boot-starter-web'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'

	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	runtimeOnly 'com.mysql:mysql-connector-j'

	implementation 'io.github.cdimascio:java-dotenv:5.2.2' // .env 사용
	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.2.0' // 스웨거 설정

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	testImplementation 'io.rest-assured:rest-assured:5.3.1'
	testRuntimeOnly 'com.h2database:h2'

	implementation 'org.springframework.boot:spring-boot-starter-security'
	testImplementation 'org.springframework.security:spring-security-test'
	implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'

	// s3
	implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

	// mail
	implementation 'org.springframework.boot:spring-boot-starter-mail'
	implementation 'org.springframework:spring-context-support'

	implementation 'org.springframework.boot:spring-boot-starter-validation'
}

tasks.named('test') {
	useJUnitPlatform()
}

tasks.register('installLocalGitHook', Copy) {
	from("${rootProject.rootDir}/.github/hooks")
	into("${rootProject.rootDir}/.git/hooks")

	eachFile {
		mode = 0755
	}

	doLast {
		println 'pre-commit 훅이 성공적으로 설치되었습니다.'
	}
}

tasks.named('compileJava') {
	dependsOn 'installLocalGitHook'
}

tasks.named('build') {
	dependsOn 'spotlessApply'
}

spotless {
	java {
		// Google Java 포맷 적용
		googleJavaFormat().aosp()
		// 아래 순서로 import문 정렬
		importOrder()
		// 사용하지 않는 import 제거
		removeUnusedImports()
		// 각 라인 끝에 있는 공백을 제거
		trimTrailingWhitespace()
		// 파일 끝에 새로운 라인 추가
		endWithNewline()
	}
	format 'misc', {
		target "*.gradle", "*.md", ".gitignore"
		trimTrailingWhitespace()
		indentWithTabs()
		endWithNewline()
	}
}

jib {
	from {
		image = 'openjdk:17-alpine'
	}
	to {
		image = '339713156055.dkr.ecr.ap-northeast-2.amazonaws.com/bookmoa-server'
		credHelper = 'ecr-login'
		tags = ['latest']
	}
	container {
		jvmFlags = ['-Xms512m']
		format = 'OCI'
	}
}