CMakeLists.txt

cmake_minimum_required(VERSION 3.19)
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake/")

project(laghos CXX)

# build flags
if(NOT CMAKE_BUILD_TYPE)
  message(STATUS "Setting build type to 'Release' as none was specified.")
  set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
endif()

if(NOT CMAKE_CONFIGURATION_TYPES)
  # Set the possible values of build type for cmake-gui
  set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
endif()

# Load 'user.cmake' settings file if it exists
set(USER_CONFIG "${CMAKE_CURRENT_SOURCE_DIR}/user.cmake" CACHE PATH "Path to user configuration file" FORCE)
include("${USER_CONFIG}" OPTIONAL RESULT_VARIABLE USER_CONFIG_LOADED)
if (USER_CONFIG_LOADED)
  message(STATUS "USER_CONFIG = ${USER_CONFIG} (LOADED)")
endif()

find_package(HYPRE REQUIRED)
find_package(MFEM REQUIRED)
find_package(MPI REQUIRED)

if (MFEM_USE_RAJA)
  find_package(RAJA REQUIRED)
endif()

option(LAGHOS_USE_CALIPER "Use Caliper" OFF)
if (LAGHOS_USE_CALIPER)
  find_package(caliper REQUIRED)
endif()

if (MFEM_USE_RAJA OR MFEM_USE_UMPIRE)
  set(CMAKE_CXX_STANDARD 20 CACHE STRING "C++ standard to use.")
else()
  set(CMAKE_CXX_STANDARD 17 CACHE STRING "C++ standard to use.")
endif()
set(CMAKE_CXX_STANDARD_REQUIRED ON CACHE BOOL
  "Force the use of the chosen C++ standard.")
set(CMAKE_CXX_EXTENSIONS OFF CACHE BOOL "Enable C++ standard extensions.")

if (MFEM_USE_CUDA)
  if (MFEM_USE_HIP)
    message(FATAL_ERROR " *** MFEM_USE_HIP cannot be combined with MFEM_USE_CUDA.")
  endif()
  if(NOT DEFINED CMAKE_CUDA_ARCHITECTURES)
    set(CMAKE_CUDA_ARCHITECTURES 70)
  endif()
  # Use ${CMAKE_CXX_COMPILER} as the cuda host compiler.
  if (NOT CMAKE_CUDA_HOST_COMPILER)
    set(CMAKE_CUDA_HOST_COMPILER ${CMAKE_CXX_COMPILER})
  endif()
  enable_language(CUDA)
  set(CMAKE_CUDA_STANDARD ${CMAKE_CXX_STANDARD} CACHE STRING
    "CUDA standard to use.")
  set(CMAKE_CUDA_STANDARD_REQUIRED ON CACHE BOOL
    "Force the use of the chosen CUDA standard.")
  set(CMAKE_CUDA_EXTENSIONS OFF CACHE BOOL "Enable CUDA standard extensions.")
  set(CUDA_FLAGS "--expt-extended-lambda")
  message(STATUS "Using CUDA architecture: ${CMAKE_CUDA_ARCHITECTURES}")
  set(CMAKE_CUDA_FLAGS "${CMAKE_CUDA_FLAGS} ${CUDA_FLAGS}")
endif()

if (MFEM_USE_HIP)
  if(NOT DEFINED CMAKE_HIP_ARCHITECTURES)
    set(CMAKE_HIP_ARCHITECTURES gfx942)
  endif()
  enable_language(HIP)
  set(CMAKE_HIP_STANDARD ${CMAKE_CXX_STANDARD} CACHE STRING
    "HIP standard to use.")
  set(CMAKE_HIP_STANDARD_REQUIRED ON CACHE BOOL
    "Force the use of the chosen HIP standard.")
  set(CMAKE_HIP_EXTENSIONS OFF CACHE BOOL "Enable HIP standard extensions.")
  message(STATUS "Using HIP architecture: ${CMAKE_HIP_ARCHITECTURES}")
endif()


list(APPEND SOURCES
  laghos_assembly.cpp laghos.cpp laghos_solver.cpp sedov/sedov_sol.cpp
)

if (MFEM_USE_CUDA)
  set_source_files_properties(${SOURCES} PROPERTIES LANGUAGE CUDA)
endif()

if (MFEM_USE_HIP)
  set_source_files_properties(${SOURCES} PROPERTIES LANGUAGE HIP)
endif()

add_executable(laghos ${SOURCES})

target_include_directories(laghos PUBLIC "${MFEM_DIR}/../../../include/mfem")

target_link_libraries(laghos
  PUBLIC mfem
  PUBLIC MPI::MPI_CXX
  PUBLIC HYPRE::HYPRE
)
if(LAGHOS_USE_RAJA)
  target_link_libraries(laghos PUBLIC RAJA)
endif()
if(LAGHOS_USE_CALIPER)
  target_link_libraries(laghos
    PUBLIC caliper
  )
  target_compile_definitions(laghos
    PUBLIC LAGHOS_USE_CALIPER)
endif()

if (MFEM_USE_CUDA)
  set_source_files_properties(sedov/sedov_sol.cpp sedov/sedov.cpp PROPERTIES LANGUAGE CUDA)
endif()

if (MFEM_USE_HIP)
  set_source_files_properties(sedov/sedov_sol.cpp sedov/sedov.cpp PROPERTIES LANGUAGE HIP)
endif()

add_executable(sedov sedov/sedov_sol.cpp sedov/sedov.cpp)

target_include_directories(sedov PUBLIC "${MFEM_DIR}/../../../include/mfem")

target_link_libraries(sedov
  PUBLIC mfem
  PUBLIC MPI::MPI_CXX
  PUBLIC HYPRE::HYPRE
)