[Python] Add three-body-Arrhenius to API

Author: ischoegl

interfaces/cython/cantera/_cantera.pxd

@@ -546,6 +546,17 @@ cdef extern from "cantera/kinetics/Reaction.h" namespace "Cantera":
         CxxCustomFunc1Rate()
         void setRateFunction(shared_ptr[CxxFunc1]) except +translate_exception
 
+    cdef cppclass CxxThreeBodyBase "Cantera::ThreeBodyBase":
+        void getEfficiencies(CxxAnyMap)
+        void efficiency(string&) except +translate_exception
+        double defaultEfficiency()
+        double thirdBodyConcentration()
+
+    cdef cppclass CxxThreeBodyArrheniusRate "Cantera::ThreeBodyArrheniusRate" (CxxReactionRate, CxxArrhenius, CxxThreeBodyBase):
+        CxxThreeBodyArrheniusRate()
+        CxxThreeBodyArrheniusRate(CxxAnyMap) except +translate_exception
+        CxxThreeBodyArrheniusRate(double, double, double)
+
     cdef cppclass CxxCoverageBase "Cantera::CoverageBase":
         void getCoverageDependencies(CxxAnyMap)
         void setCoverageDependencies(CxxAnyMap) except +translate_exception
@@ -1407,6 +1418,9 @@ cdef class CustomRate(ReactionRate):
     cdef CxxCustomFunc1Rate* cxx_object(self)
     cdef Func1 _rate_func
 
+cdef class ThreeBodyRateBase(ArrheniusRateBase):
+    cdef CxxThreeBodyBase* threebody
+
 cdef class InterfaceRateBase(ArrheniusRateBase):
     cdef CxxCoverageBase* coverage
 

interfaces/cython/cantera/reaction.pyx

@@ -685,6 +685,64 @@ cdef class CustomRate(ReactionRate):
         self.cxx_object().setRateFunction(self._rate_func._func)
 
 
+cdef class ThreeBodyRateBase(ArrheniusRateBase):
+    """
+    Base class collecting commonly used features of Arrhenius-type rate objects
+    that include three.
+    """
+
+    property efficiencies:
+        """
+        Get a `dict` defining non-default third-body efficiencies for this
+        reaction, where the keys are the species names and the values are the
+        efficiencies.
+        """
+        def __get__(self):
+            cdef CxxAnyMap cxx_effs
+            self.threebody.getEfficiencies(cxx_effs)
+            return anymap_to_dict(cxx_effs)
+
+    property default_efficiency:
+        """
+        Get the default third-body efficiency associated with this rate, used for
+        species used for species not in `efficiencies`.
+        """
+        def __get__(self):
+            return self.threebody.defaultEfficiency()
+
+    property third_body_concentration:
+        """Concentration of third-body collider"""
+        def __get__(self):
+            return self.threebody.thirdBodyConcentration()
+
+
+cdef class ThreeBodyArrheniusRate(ThreeBodyRateBase):
+    r"""
+    A reaction rate coefficient which depends on temperature and the concentration of
+    a third-body collider
+    """
+    _reaction_rate_type = "three-body-Arrhenius"
+
+    def __cinit__(self, A=None, b=None, Ea=None, input_data=None, init=True):
+
+        if init:
+            self._cinit(input_data, A=A, b=b, Ea=Ea)
+
+    def _from_dict(self, dict input_data):
+        self._rate.reset(new CxxThreeBodyArrheniusRate(dict_to_anymap(input_data)))
+
+    def _from_parameters(self, A, b, Ea):
+        self._rate.reset(new CxxThreeBodyArrheniusRate(A, b, Ea))
+
+    cdef set_cxx_object(self):
+        self.rate = self._rate.get()
+        self.base = <CxxArrhenius*>self.rate
+        self.threebody = <CxxThreeBodyBase*>self.cxx_object()
+
+    cdef CxxThreeBodyArrheniusRate* cxx_object(self):
+        return <CxxThreeBodyArrheniusRate*>self.rate
+
+
 cdef class InterfaceRateBase(ArrheniusRateBase):
     """
     Base class collecting commonly used features of Arrhenius-type rate objects
@@ -718,7 +776,6 @@ cdef class InterfaceRateBase(ArrheniusRateBase):
             return anymap_to_dict(cxx_deps)
         def __set__(self, dict deps):
             cdef CxxAnyMap cxx_deps = dict_to_anymap(deps)
-
             self.coverage.setCoverageDependencies(cxx_deps)
 
     def set_species(self, species):