build.gradle

import com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar
import net.minecraftforge.gradleutils.PomUtils

plugins {
    id 'java'
    id 'eclipse'
    id 'maven-publish'
    id 'org.cadixdev.licenser' version '0.6.1'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'com.github.ben-manes.versions' version '0.47.0'
    id 'net.minecraftforge.gradleutils' version '2.+'
}

group = 'net.minecraftforge'
version = gradleutils.tagOffsetVersion
println "Version: $version"

repositories {
    mavenCentral()
    maven gradleutils.forgeMaven
}

license {
    header = file('LICENSE-header.txt')
    newLine = false
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(8)
    }
    withSourcesJar()
}

tasks.named('jar', Jar).configure {
    from(configurations.markers.collect { zipTree(it) } ) {
        into 'markers'
        include '**/*.class'
        rename { it.replace('.class', '.marker') }
    }
    manifest {
        attributes('Main-Class': 'net.minecraftforge.mergetool.ConsoleMerger')
        attributes('Implementation-Version': project.version)
    }
}

tasks.named('shadowJar', ShadowJar).configure {
    archiveClassifier = 'fatjar'
}

configurations {
    markers
    implementation.extendsFrom(markers)
}

dependencies {
    implementation 'org.ow2.asm:asm:9.5'
    implementation 'org.ow2.asm:asm-tree:9.5'
    implementation 'org.ow2.asm:asm-util:9.5'
    implementation 'net.sf.jopt-simple:jopt-simple:5.0.4'
    implementation 'net.minecraftforge:srgutils:0.4.15'
    
    markers 'net.minecraftforge:mergetool-cpw:1.0'
    markers 'net.minecraftforge:mergetool-fml:1.0'
    markers 'net.minecraftforge:mergetool-api:1.0'
}

artifacts {
    archives shadowJar
}

publishing {
    publications.register('mavenJava', MavenPublication) {
        from components.java

        artifactId = 'mergetool'

        pom {
            name = 'MergeTool'
            description = 'Merges two jar files together, useful for rebuilding Retroguard stripped jars.'
            url = 'https://github.com/MinecraftForge/MergeTool'
            
            PomUtils.setGitHubDetails(pom, 'MergeTool')

            license PomUtils.Licenses.LGPLv2_1

            developers {
                developer PomUtils.Developers.LexManos
            }
        }
    }
    
    repositories {
        maven gradleutils.getPublishingForgeMaven()
    }
}