build.gradle

buildscript {
    apply from: 'dependencies.gradle'
}


plugins {
    id 'com.diffplug.spotless' version "${spotlessVersion}"
}


allprojects {
    apply plugin: 'java'
    apply plugin: 'checkstyle'

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
        sourceCompatibility = JavaVersion.VERSION_21
    }

    [compileJava, compileTestJava]*.options*.encoding = 'UTF-8'

    repositories {
        mavenCentral()
    }

    tasks.withType(JavaExec).configureEach {
        dependsOn classes
        standardInput = System.in
        ignoreExitValue true
        systemProperty 'BASELOGDIR', project.baseLogDir
    }

    clean {
        delete project.baseLogDir
    }

    checkstyle {
        configFile = rootProject.file('.checkstyle.xml')
        // Default version vs. current version? The default version is quite old (9.3 from
        // Jan 30, 2022), so let's go with the current version (10.14).
        // However, this needs to be updated manually as Dependabot won't deal with this!
        toolVersion = '10.15.0'
        ignoreFailures = false
        maxWarnings = 0
    }
    // Workaround to resolve CS dependencies: https://github.com/checkstyle/checkstyle/issues/14123#issuecomment-1961029772
    configurations.checkstyle {
        resolutionStrategy.capabilitiesResolution.withCapability("com.google.collections:google-collections") {
            select("com.google.guava:guava:0")
        }
    }
}


spotless {
    java {
        targetExclude('build/generated-src/**')
        googleJavaFormat()

        target '**/*.java'
    }
}