SecureCheck-Back/build.gradle at main · GerarC/SecureCheck-Back · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.3'
    id 'io.spring.dependency-management' version '1.1.6'
    id "org.springdoc.openapi-gradle-plugin" version "1.9.0"
    id "org.sonarqube" version "4.4.1.3373"
    id 'jacoco'
}

group = 'co.edu.udea'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    annotationProcessor 'org.projectlombok:lombok'
    annotationProcessor group: 'org.mapstruct', name: 'mapstruct-processor', version: '1.6.0'

    implementation group: 'org.mapstruct', name: 'mapstruct', version: '1.6.0'
    implementation group: 'org.springdoc', name: 'springdoc-openapi-starter-webmvc-ui', version: '2.6.0'
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-validation', version: '3.3.3'

    implementation 'org.springframework.boot:spring-boot-starter-data-jdbc'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'

    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    runtimeOnly 'org.postgresql:postgresql'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    testImplementation group: 'org.springframework.security', name: 'spring-security-test', version: '6.3.3'
    implementation group: 'org.springframework.security', name: 'spring-security-web', version: '6.3.3'
    implementation group: 'org.springframework.boot', name: 'spring-boot-starter-security', version: '3.3.3'
    implementation group: 'io.jsonwebtoken', name: 'jjwt-api', version: '0.12.6'
    runtimeOnly group: 'io.jsonwebtoken', name: 'jjwt-impl', version: '0.12.6'
    runtimeOnly group: 'io.jsonwebtoken', name: 'jjwt-jackson', version: '0.12.6'
}

tasks.named('test') {
    useJUnitPlatform()
}

def jacocoExclude = [
        "co/edu/udea/securecheck/**/model/*.class",
        "**/configuration/*"
]

test {
    finalizedBy jacocoTestReport
}

jacoco {
    toolVersion = "0.8.12"
}


jacocoTestReport {
    dependsOn test
    reports {
        xml.required = true
        html.required = true
    }
    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: jacocoExclude)
        }))
    }
    finalizedBy jacocoTestCoverageVerification
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            excludes = jacocoExclude
            limit {
                minimum = 0.3
            }
        }
    }
}

sonar {
    properties {
        property "sonar.gradle.skipCompile", "true"
        property "sonar.projectKey", "GerarC_SecureCheck-Back"
        property "sonar.organization", "gerarc"
        property "sonar.host.url", "https://sonarcloud.io"
        property "sonar.coverage.jacoco.xmlReportPaths", "build/reports/jacoco/test/jacocoTestReport.xml"
        property "sonar.qualitygate.wait", "true"
    }
}