MoneyPlan/build.gradle at main · GiYeons/MoneyPlan · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
plugins {
	id 'java'
	id 'org.springframework.boot' version '3.3.2'
	id 'io.spring.dependency-management' version '1.1.6'
	id 'jacoco'
}

group = 'com.moneyplan'
version = '0.0.1-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(17)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencies {
	developmentOnly("org.springframework.boot:spring-boot-devtools")
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'

	// DB
	implementation 'org.flywaydb:flyway-core'
	implementation 'org.flywaydb:flyway-mysql'
	runtimeOnly 'com.h2database:h2'
	runtimeOnly 'com.mysql:mysql-connector-j'

	// API Docs
	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.5.0'

	//security
	implementation 'org.springframework.boot:spring-boot-starter-security'

	// jwt
	implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-impl:0.11.5'
	implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'

	// queryDSL
	implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
	annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
	annotationProcessor "jakarta.annotation:jakarta.annotation-api"
	annotationProcessor "jakarta.persistence:jakarta.persistence-api"
}

/** Jacoco start **/
jacoco {
	toolVersion = "0.8.12"
}

test {
	finalizedBy jacocoTestReport
}

jacocoTestReport {
	dependsOn test // 테스트 이후에 수행

	reports {
		xml.required.set(true)
		html.required.set(true)

		// QueryDSL QDomain 제외시키기
		def QDomains = []

		for (qPattern in '**/QA'..'**/QZ') {
			QDomains.add(qPattern + '*')
		}
		afterEvaluate {
			classDirectories.setFrom(
					files(classDirectories.files.collect {
						fileTree(dir: it, excludes: [
								"com/moneyplan/**/model/**",
								"**/*Application*",
								"**/*Config*",
								"**/*Req*",
								"**/*Res*",
								"**/*Interceptor*",
								"**/*Exception*",
								"**/*specification*"
						] + QDomains)
					})
			)
		}

		xml.destination file("${layout.buildDirectory.get().asFile}/jacoco/index.xml")   // `build` 디렉토리에 리포트 파일 생성
		html.destination file("${layout.buildDirectory.get().asFile}/jacoco/index.html")
	}
}
/** Jacoco end **/


/** QueryDSL start **/
def querydslDir = "$buildDir/generated/querydsl"

sourceSets {
	main.java.srcDirs += [ querydslDir ]
}

// QClass 생성 위치 지정
tasks.withType(JavaCompile) {
	options.annotationProcessorGeneratedSourcesDirectory = file(querydslDir)
}

// gradle clean 시 QClass 디렉토리 삭제
clean.doLast {
	file(querydslDir).deleteDir()
}
/** QueryDSL end **/


tasks.named('test') {
	useJUnitPlatform()
}