Updated random sampling of Box

For added consistency with gymnasium:
 - Finite intervals are sampled uniformly,
 - Infinite intervals are sampled normally,
 - Semi-infinite intervals are sampled as shifted exponential distributions.

Author: the-one-and-only-jackson

Project.toml

@@ -4,6 +4,7 @@ authors = ["Jun Tian <[email protected]> and contributors"]
 version = "0.2.1"
 
 [deps]
+Distributions = "31c24e10-a181-5473-b8eb-7969acd0382f"
 FillArrays = "1a297f60-69ca-5386-bcde-b61e274b549b"
 IntervalSets = "8197267c-284f-5f27-9208-e0e47529a953"
 Random = "9a3f8284-a2c9-5f02-9a11-845980a1fd5c"

src/CommonRLSpaces.jl

@@ -7,6 +7,7 @@ using Reexport
 using StaticArrays
 using FillArrays
 using Random
+using Distributions
 import Base: clamp
 
 export

src/array.jl

@@ -43,13 +43,61 @@ Box(lower::Array, upper::Array) = Box(lower, upper; convert_to_static=true)
 
 SpaceStyle(::Box) = ContinuousSpaceStyle()
 
-function Base.rand(rng::AbstractRNG, sp::Random.SamplerTrivial{<:Box})
+"""
+    Base.rand(::AbstractRNG, ::Random.SamplerTrivial{<:Box})
+
+Generate an array where each element is sampled from a dimension of a Box space.
+
+  * Finite intervals [a,b] are sampled from uniform distributions.
+  * Semi-infinite intervals (a,Inf) and (-Inf,b) are sampled from shifted exponential distributions.
+  * Infinite intervals (-Inf,Inf) are sampled from normal distributions.
+
+#Example
+```julia
+julia> using Random: seed!
+
+julia> using Distributions: Uniform, Normal, Exponential
+
+julia> box = Box([-10, -Inf, 3], [10, Inf, Inf])
+Box{StaticArraysCore.SVector{3, Float64}}([-10.0, -Inf, 3.0], [10.0, Inf, Inf])
+
+julia> seed!(0); rand(box)
+3-element StaticArraysCore.SVector{3, Float64} with indices SOneTo(3):
+ -1.8860105821594164
+  0.13392275765318448
+  3.837385552384043
+
+julia> seed!(0); [rand(Uniform(-10,10)), rand(Normal()), 3+rand(Exponential())]
+3-element Vector{Float64}:
+ -1.8860105821594164
+  0.13392275765318448
+  3.837385552384043
+```
+"""
+function Base.rand(rng::AbstractRNG, sp::Random.SamplerTrivial{Box{T}}) where {T}
     box = sp[]
-    return box.lower + rand_similar(rng, box.lower) .* (box.upper-box.lower)
+    x = [rand_interval(rng, lb, ub) for (lb, ub) in zip(box.lower, box.upper)]
+    return T(x)
 end
 
-rand_similar(rng::AbstractRNG, a::StaticArray) = rand(rng, typeof(a))
-rand_similar(rng::AbstractRNG, a::AbstractArray) = rand(rng, eltype(a), size(a)...)
+function rand_interval(rng::AbstractRNG, lb::T, ub::T) where {T <: Real}
+    offset, sign = zero(T), one(T)
+
+    if isfinite(lb) && isfinite(ub)
+        dist = Uniform(lb, ub)
+    elseif isfinite(lb) && !isfinite(ub)
+        offset = lb
+        dist = Exponential(one(T))
+    elseif !isfinite(lb) && isfinite(ub)
+        offset = ub
+        sign = -one(T)
+        dist = Exponential(one(T))
+    else
+        dist = Normal(zero(T), one(T))
+    end
+
+    return offset + sign * rand(rng, dist)
+end
 
 Base.in(x::AbstractArray, b::Box) = all(b.lower .<= x .<= b.upper)
 

test/array.jl

@@ -78,6 +78,15 @@
         end
     end
 
+    @testset "Box random sample" begin
+        box = Box([-10, -Inf, 3, -Inf], [10, Inf, Inf, 6])
+        Random.seed!(0)
+        x = rand(box)
+        Random.seed!(0)
+        y = SA[rand(Uniform(-10, 10)), rand(Normal()), 3+rand(Exponential()), 6-rand(Exponential())]
+        @test x == y
+    end
+
     @testset "Interval to box conversion" begin
         @test convert(Box, 1..2) == Box([1], [2])
     end

test/runtests.jl

@@ -2,6 +2,8 @@ using CommonRLSpaces
 using Test
 
 using StaticArrays
+using Distributions
+using Random
 
 @testset "CommonRLSpaces.jl" begin
     include("basic.jl")