build.gradle

buildscript {
    repositories {
        maven {
            name = 'KotDis'
            url = 'https://maven.kotlindiscord.com/repository/maven-public/'
        }
    }
}

plugins {
    id 'maven-publish'

    id 'com.github.jakemarsden.git-hooks' version '0.0.1'
    id 'com.github.johnrengelman.shadow' version '5.2.0'
    id 'io.gitlab.arturbosch.detekt' version '1.8.0'

    id 'org.jetbrains.kotlin.jvm' version '1.4.10'
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.4.10'
}

group 'com.kotlindiscord.api'
version '1.1-SNAPSHOT'

repositories {
    maven {
        name = 'KotDis'
        url = 'https://maven.kotlindiscord.com/repository/maven-public/'
    }
}

def ktor_version = "1.4.3"

dependencies {
    api "io.ktor:ktor-client-core:$ktor_version"
    api "io.ktor:ktor-client-cio:$ktor_version"
    api "io.ktor:ktor-client-json-jvm:$ktor_version"
    api "io.ktor:ktor-client-serialization-jvm:$ktor_version"

    implementation "org.jetbrains.kotlin:kotlin-stdlib-jdk8"
    implementation "org.jetbrains.kotlin:kotlin-reflect"

    api "org.jetbrains.kotlinx:kotlinx-serialization-json:1.0.1"

    implementation 'io.github.microutils:kotlin-logging:1.7.9'
}

compileKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

compileTestKotlin {
    kotlinOptions.jvmTarget = "1.8"
}

detekt {
    buildUponDefaultConfig = true
    config = files("detekt.yml")
}

gitHooks {
    hooks = ['pre-commit': 'detekt']
}

publishing {
    repositories {
        maven {
            name = "KotDis"
            url = uri("https://maven.kotlindiscord.com/repository/maven-snapshots/")

            credentials {
                username = project.findProperty("kotdis.user") ?: System.getenv("KOTLIN_DISCORD_USER")
                password = project.findProperty("kotdis.password") ?: System.getenv("KOTLIN_DISCORD_PASSWORD")
            }

            version = project.version
        }
    }

    publications {
        maven(MavenPublication) {
            from(components.java)
            artifacts {
                kotlinSourcesJar
            }
        }
    }
}