build.gradle

plugins {
	id "fabric-loom" version "1.7-SNAPSHOT"
	id "co.uzzu.dotenv.gradle" version "2.0.0"
	id "maven-publish"
}

version = "${project.mod_version}+${project.minecraft_version}"
group = project.maven_group

base {
	archivesName = project.archives_base_name
}

repositories {
	// owo
	maven {
		url 'https://maven.wispforest.io'
	}

	// Mod Menu
	maven {
		url "https://maven.terraformersmc.com/releases"
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	// owo
	modImplementation "io.wispforest:owo-lib:${project.owo_version}"
	annotationProcessor "io.wispforest:owo-lib:${project.owo_version}"

	// Mod Menu
	modImplementation "com.terraformersmc:modmenu:${mod_menu_version}"
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.release = 21
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()

	sourceCompatibility = JavaVersion.VERSION_21
	targetCompatibility = JavaVersion.VERSION_21
}

jar {
	from("LICENSE") {
		rename { "${it}_${this.base.archivesName.get()}" }
	}
}

tasks.register('printProjectVersion') {
	doLast {
		println(project.findProperty('mod_version'))
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			groupId = group
			artifactId = archivesBaseName

			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		maven {
			name "lilydevMaven"

			url "https://maven.lilydev.com/releases"

			credentials {
				username System.getenv("MAVEN_USERNAME")
				password System.getenv("MAVEN_PASSWORD")
			}
		}
	}
}