build.gradle

plugins {
    id "architectury-plugin" version "3.4-SNAPSHOT"
    id "dev.architectury.loom" version "1.6-SNAPSHOT" apply false
    id "me.modmuss50.mod-publish-plugin" version "0.5.1"
}

architectury {
    minecraft = rootProject.minecraft_version
}


subprojects {
    apply plugin: "dev.architectury.loom"

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "com.mojang:minecraft:${rootProject.minecraft_version}"
        mappings loom.officialMojangMappings()
    }
}

allprojects {
    apply plugin: "java"
    apply plugin: "architectury-plugin"
    apply plugin: "maven-publish"

    archivesBaseName = rootProject.archives_base_name
    version = rootProject.mod_version
    group = rootProject.maven_group

    repositories {
        maven { url "https://maven.neoforged.net/releases/" }

        maven { url "https://maven.isxander.dev/releases" }
        maven { url "https://maven.quiltmc.org/repository/release/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
    }

    tasks.withType(JavaCompile).configureEach {
        options.encoding = "UTF-8"
        options.release.set(21)
    }

    java {
        withSourcesJar()
    }
}


ext.getChangeLog = { ->
    return ""
}

publishMods {
    changelog = project.getChangeLog()
    type = STABLE

    def optionsCurseforge = curseforgeOptions {
        accessToken = providers.environmentVariable("CURSEFORGE_API_KEY")
        projectId = "489631"
        projectSlug = "fuel-info"
        minecraftVersions.add("${project.minecraft_version}")
    }

    def optionsModrinth = modrinthOptions {
        accessToken = providers.environmentVariable("MODRINTH_TOKEN")
        projectId = "J1ueTDcI"
        minecraftVersions.add("${project.minecraft_version}")
    }


    curseforge("curseforgeForge") {
        from optionsCurseforge
        modLoaders.add("neoforge")
        file = project(":forge").tasks.named("remapJar").get().archiveFile
        displayName = "${rootProject.mod_version} (NeoForge)"
        version = "${rootProject.mod_version}-neoforge"

        requires("architectury-api")
        embeds("yacl")

        announcementTitle = "Download from CurseForge (NeoForge)"
    }

    curseforge("curseforgeFabric") {
        from optionsCurseforge
        modLoaders.add("fabric")
        file = project(":fabric").tasks.named("remapJar").get().archiveFile
        displayName = "${rootProject.mod_version} (Fabric)"
        version = "${rootProject.mod_version}-fabric"

        requires("fabric-api")
        requires("architectury-api")
        embeds("yacl")

        announcementTitle = "Download from CurseForge (Fabric)"
    }

    modrinth("modrinthForge") {
        from optionsModrinth
        modLoaders.add("neoforge")
        file = project(":forge").tasks.named("remapJar").get().archiveFile
        displayName = "${rootProject.mod_version} (NeoForge)"
        version = "${rootProject.mod_version}-neoforge"

        requires("architectury-api")
        embeds("yacl")

        announcementTitle = "Download from Modrinth (NeoForge)"
    }

    modrinth("modrinthFabric") {
        from optionsModrinth
        modLoaders.add("fabric")
        file = project(":fabric").tasks.named("remapJar").get().archiveFile
        displayName = "${rootProject.mod_version} (Fabric)"
        version = "${rootProject.mod_version}-fabric"

        requires("fabric-api")
        requires("architectury-api")
        embeds("yacl")

        announcementTitle = "Download from Modrinth (Fabric)"
    }

    discord {
        webhookUrl = providers.environmentVariable("CAFETERIA_MOD_RELEASE_WEBHOOK")
        username = "${rootProject.archives_base_name}"
        avatarUrl = "${rootProject.discordAnnouncementIconURL}"

        content = changelog.map { "# " + (project.archives_base_name as String) + " " + (project.mod_version as String) + " has been released \n" + it}
    }
}