COM Error 130 with WL-134 Module

[argus25]

I came across your library for the WL-134 RFID tag reader while trying to build an automated cat feeder for our four cats, each of whom have specific dietary needs. I bought a bunch of stuff to try to develop a system that'll do what I want but I'm running into problems with getting it to spit out anything but an error code in the serial monitor.

I have one of these: Amazon.com: LICHIFIT 134.2K AGV RFID Module FDXB Animal Ear Tag Reader TTL FDX-B ISO11784/85 Long Distance Card Reader Module : Electronics. It is being powered by a 12v DC adapter going thru an LM2596 dropping the voltage to 9v (8.89v on the display). I have the antenna and power soldered onto the board and the TX from the module going into port 0 on the Arduino board (Arduino Uno R4 Minima) as that's supposedly the serial port input (I think).

All I ever get out of the serial monitor is "Com Error 130". It repeats over and over and over every couple of seconds.

I was able to find this note in Github on your page: Enhance to support HDX tag data format · Issue #10 · Makuna/Rfid134 · GitHub where someone from the UK was having the same error code and you made a change to handle tags from other countries but I have no idea how to see if that's the error I have.

I don't even know if the tags I bought are compatible. Amazon.com: Manruta RFID Microchip Replacement Collar Tag 2 Pack for Cats and Dogs Use for Smart Auto Pet Door and Feeder 1.1 Inch Dia Waterproof (Blue) : Pet Supplies But I've tried reading other RFID stuff that works on the standard RFID reader that came with another Arduino kit I have (the sample tags as well as various things from old jobs and door reader cards, etc) but all I get is this Com Error 130 over and over and over.

I don't know what to do next.

This is the sample code from the sketch (it's the default code included as a sample with the library)

#include <SoftwareSerial.h>
#include <Rfid134.h>

// implement a notification class,
// its member methods will get called 
//
class RfidNotify
{
public:
  static void OnError(Rfid134_Error errorCode)
  {
    // see Rfid134_Error for code meaning
    Serial.println();
    Serial.print("Com Error ");
    Serial.println(errorCode);
  }

  static void OnPacketRead(const Rfid134Reading& reading)
  {
    char temp[8];

    Serial.print("TAG: ");

    // since print doesn't support leading zero's, use sprintf
    sprintf(temp, "%03u", reading.country);
    Serial.print(temp);   

    Serial.print(" ");
    
    // since print doesn't support leading zero's, use sprintf
    // since sprintf with AVR doesn't support uint64_t (llu/lli), use /% trick to
    // break it up into equal sized leading zero pieces
    sprintf(temp, "%06lu", static_cast<uint32_t>(reading.id / 1000000));
    Serial.print(temp); 
    sprintf(temp, "%06lu", static_cast<uint32_t>(reading.id % 1000000));
    Serial.print(temp); 

    Serial.print(" ");
    if (reading.isData)
    {
        Serial.print("data");
    }
    if (reading.isAnimal)
    {
        Serial.print("animal");
    }
    Serial.println();
  }

};

// instance a Rfid134 object, 
// defined with the above notification class and the hardware serial class
//
Rfid134<HardwareSerial, RfidNotify> rfid(Serial1);

// Some arduino boards only have one hardware serial port, so a software serial port is needed instead.
// comment out the above definition and uncomment these lines
//SoftwareSerial secondarySerial(10, 11); // RX, TX
//Rfid134<SoftwareSerial, RfidNotify> rfid(secondarySerial);

void setup() 
{
  Serial.begin(115200);

  Serial.println("initializing...");
  
  // due to design differences in (Software)SerialConfig that make the serial.begin
  // method inconsistent between implemenations, it is required that the sketch
  // call serial.begin() that is specific to the platform
  // 
  // hardware
  Serial1.begin(9600, SERIAL_8N2);
  // software ESP
  //secondarySerial.begin(9600, SWSERIAL_8N2);
  // software AVR
  //secondarySerial.begin(9600);
  
  rfid.begin();
 
  Serial.println("starting...");
}

void loop() 
{
  rfid.loop();
}

[Makuna]

I made a small change to the code a few days ago that was suggested by the issue you pointed out. Pick up the Master branch and see if that fixes the issue.

The "read me" file will give you the basic instructions to clone the project onto your local computer.

If that doesn't work, then I will provide a simple sketch you can run to help us diagnose the modified data stream from the different tags.

[argus25]

I was able to clone the git project as zip file and include it as library in Arduino IDE. I removed the old one and replaced with the new one. However, same issue continues. There also appears to be a lot of variability in how long it takes to reply with the COM 130 error, usually around 6 seconds but much longer or shorter in some cases.
15:24:58.133 -> Com Error 130
15:25:11.455 -> Com Error 130
15:25:17.070 -> Com Error 130
15:25:24.228 -> Com Error 130
15:25:30.966 -> Com Error 130
What is the next troubleshooting step? Thank you kindly!

[Makuna]

Below is a test sketch. Build and run it and copy the output from the debug output here.

Once it is running, swipe first the included tag (that worked with my library) and then swipe the tag you have that is giving you problems.

#include <SoftwareSerial.h>

//SoftwareSerial secondarySerial(10, 11); // RX, TX

void setup()
{
    Serial.begin(115200);
    Serial.println("initializing...");

    // RFID reader on Serial1
    Serial1.begin(9600, SERIAL_8N2);

    // software serial 
    //secondarySerial.begin(9600, SWSERIAL_8N2);
    // software AVR, doesn't support 8N2, thus may not work
    //secondarySerial.begin(9600);

    Serial1.setTimeout(1000);

    Serial.println("starting...");
}

void loop()
{
    if (Serial1.available())
    {
        for (;;)
        {
            int value = Serial1.read();

            if (value == -1)
            {
                Serial.println();
                break;
            }

            char temp[8];

            // since print doesn't support leading zero's, use sprintf
            sprintf(temp, "%02x ", value);
            Serial.print(temp);
        }
    }
}