nixpkgs-matrixai/flake.nix at staging · MatrixAI/nixpkgs-matrixai · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
{
  description = "Matrix AI Public Overlay";

  inputs = {
    # BEGIN: nixpkgs-pin (managed by scripts/nixpkgs-pin-policy.sh)
    nixpkgs = {
      type = "github";
      owner = "NixOS";
      repo = "nixpkgs";
      rev = "5b2c2d84341b2afb5647081c1386a80d7a8d8605";
    };
    # END: nixpkgs-pin

    flake-parts.url = "github:hercules-ci/flake-parts";
  };

  outputs = inputs@{ nixpkgs, flake-parts, ... }:
    let
      system = "x86_64-linux";

      defaultOverlay = import ./overlays;

      publicLib = import ./lib {
        lib = nixpkgs.lib;
        pkgs = nixpkgs.legacyPackages.${system};
        overlay = defaultOverlay;
        mkPkgsUpstream = { system, overlays ? [ ], config ? { } }:
          import nixpkgs {
            inherit system overlays config;
          };
      };

      pkgsFor = system:
        publicLib.mkPkgs {
          inherit system;
          config.allowUnfree = true;
        };

      pkgs = pkgsFor system;

      topLevelPackages = (import ./pkgs { }).exportTopLevel pkgs;

      moduleSets = import ./modules;

      nixosModulesSet = moduleSets.nixosModules;
      homeModulesSet = moduleSets.homeModules;

      templatesOss = {
        path = ./templates/oss;
        description = "Minimal flake-parts starter consuming nixpkgs-matrixai via lib.mkPkgs";
      };

      templatesSet = {
        oss = templatesOss;
        default = templatesOss;
      };
    in
    flake-parts.lib.mkFlake { inherit inputs; } {
      systems = [ system ];

      flake = rec {
        lib = publicLib;

        overlays.default = defaultOverlay;

        legacyPackages.${system} = pkgs;

        packages.${system} = topLevelPackages;

        templates = templatesSet;

        checks.${system} = import ./checks/default.nix {
          lib = nixpkgs.lib;
          inherit
            system
            pkgs
            publicLib
            defaultOverlay
            topLevelPackages
            nixosModulesSet
            homeModulesSet
            templatesSet
            ;
          legacyPackages = pkgs;
        };

        nixosModules = nixosModulesSet;

        homeModules = homeModulesSet;
      };

      perSystem = { pkgs, ... }: {
        devShells.default = pkgs.mkShell {
          packages = [
            pkgs.nix
            pkgs.git
            pkgs.jq
            pkgs.gnugrep
            pkgs.gawk
            pkgs.coreutils
            pkgs.gnused
            pkgs.findutils
            pkgs.curl
            pkgs.wget
          ];
        };
      };
    };
}