Problem with constraints

[JulesArcher]

Hi,

I am trying to use the constraints option without success as follows:

using Distributed
using SymbolicRegression
using SymbolicUtils
procs = addprocs()

@everywhere using SymbolicRegression

X = randn(Float32, 5, 100)
y = 2 * cos.(X[4, :]) + X[1, :] .^ 2 .- 2

options = SymbolicRegression.Options(
    binary_operators=(+, *, /, -,^),
    unary_operators=(cos, exp),
    npopulations=30,loss=L2DistLoss(),constraints=[(^)=>(-1, 3)]
)
niterations = 5

hallOfFame = EquationSearch(X, y, niterations=niterations, options=options)

rmprocs(procs)

Output gives a type error as follows:

TypeError: in typeassert, expected Union{Nothing, Tuple, Vector{Pair{Any, Any}}}, got a value of type Vector{Pair{typeof(^), Tuple{Int64, Int64}}}

Any ideas as to what I'm doing wrong?

Thanks!

[MilesCranmer]

Hi @JulesArcher,

Thanks for raising this. Looks like a bug! I'll fix this straight away.

Cheers,
Miles

[MilesCranmer]

Fixed on 0.8.1 (registry will update in ~1 hour). Let me know if it works for you.

Cheers,
Miles

[MilesCranmer]

btw, note that since you aren't passing procs to EquationSearch, so they won't actually be used. You can either let SymbolicRegression.jl handle the multiprocessing automatically, with:

using SymbolicRegression
X = randn(Float32, 5, 100)
y = 2 * cos.(X[4, :]) + X[1, :] .^ 2 .- 2

options = SymbolicRegression.Options(
    binary_operators=(+, *, /, -,^),
    unary_operators=(cos, exp),
    loss=L2DistLoss(),
    constraints=[(^)=>(-1, 3)]
)
niterations = 5

hallOfFame = EquationSearch(X, y, niterations=niterations, options=options, numprocs=4)

No use of @everywhere needed. This will create and then remove the extra processes internally. (Although I recommend numprocs=0, multithreading=true instead - it's more stable - just be search to launch julia with multithreading).

If you do want to do everything manually, you should change your code to:

using Distributed
procs = addprocs(4)
using Pkg
project_path = splitdir(Pkg.project().path)[1]

@everywhere procs begin
    # Activate project on processes:
    Base.MainInclude.eval(quote
        using Pkg
        Pkg.activate($$project_path)
    end)
end
@everywhere using SymbolicRegression
X = randn(Float32, 5, 100)
y = 2 * cos.(X[4, :]) + X[1, :] .^ 2 .- 2
options = SymbolicRegression.Options(
    binary_operators=(+, *, /, -,^),
    unary_operators=(cos, exp),
    loss=L2DistLoss(),
    constraints=[(^)=>(-1, 3)]
)
niterations = 5

hallOfFame = EquationSearch(
    X, y,
    niterations=niterations,
    options=options,
    procs=procs
)

rmprocs(procs)

[JulesArcher]

Hi,

Yes, the options I was trying to use now seems to work with the new version.

Thank you for the quick reply and fix!