KhdM01.mod

TITLE I-h channel from Magee 1998 for distal dendrites

UNITS {
	(mA) = (milliamp)
	(mV) = (millivolt)

}

PARAMETER {
	v 		(mV)
    ehd  		(mV)        
	celsius 	(degC)
	ghdbar=.0001 	(mho/cm2)
    vhalfl=-90   	(mV)
    vhalft=-75   	(mV)
    a0t=0.011      	(/ms)
    zetal=4    	(1)
    zetat=2.2   (1)
    gmt=.4   	(1)
	q10=4.5
	qtl=1
}


NEURON {
	SUFFIX KhdM01
	NONSPECIFIC_CURRENT i
    RANGE ghdbar, vhalfl
    GLOBAL linf,taul
}

STATE {
    l
}

ASSIGNED {
	i (mA/cm2)
    linf      
    taul
    gbar
}

INITIAL {
	rate(v)
	l=linf
}


BREAKPOINT {
	SOLVE states METHOD cnexp
	gbar = ghdbar*l
	i = gbar*(v-ehd)
}


FUNCTION alpl(v(mV)) {
  alpl = exp(1.e-3*zetal*(v-vhalfl)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION alpt(v(mV)) {
  alpt = exp(1.e-3*zetat*(v-vhalft)*9.648e4/(8.315*(273.16+celsius))) 
}

FUNCTION bett(v(mV)) {
  bett = exp(1.e-3*zetat*gmt*(v-vhalft)*9.648e4/(8.315*(273.16+celsius))) 
}

DERIVATIVE states {     : exact when v held constant; integrates over dt step
        rate(v)
        l' =  (linf - l)/taul
}

PROCEDURE rate(v (mV)) { :callable from hoc
        LOCAL a,qt
        qt=q10^((celsius-33)/10)
        a = alpt(v)
        linf = 1/(1+ alpl(v))
        taul = bett(v)/(qtl*qt*a0t*(1+a))
}