-
Notifications
You must be signed in to change notification settings - Fork 0
/
herb-o-matic.ino
161 lines (134 loc) · 3.74 KB
/
herb-o-matic.ino
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
#include "credentials.h"
#include <ESP8266WiFi.h>
#include <PubSubClient.h>
const char* ssid = CRED_SSID;
const char* password = CRED_PASSWORD;
const char* mqtt_server = CRED_MQTT_SERVER;
const int mqtt_port = CRED_MQTT_PORT;
const char* mqtt_user = CRED_MQTT_USER;
const char* mqtt_pwd = CRED_MQTT_PASSWD;
const char* clientId = CRED_CLIENT_ID;
const char* pub_topic = CRED_PUB_TOPIC;
#define soilMoistPin A0
#define powerLedPin D5
#define errorLedPin D2
#define pumpPin D1
WiFiClient espClient;
PubSubClient client(espClient);
int averageSoilMoistness;
boolean pumpWasActive = false;
void successBlink(){
digitalWrite(powerLedPin, LOW);
delay(100);
digitalWrite(powerLedPin, HIGH);
}
void errorBlink(int numOfBlinks){
for (int i = 0; i < numOfBlinks; i++) {
digitalWrite(errorLedPin, HIGH);
delay(100);
digitalWrite(errorLedPin, LOW);
if(i != numOfBlinks - 1){
delay(100);
}
}
}
void handleError(char* errorText){
Serial.print("Error: ");
Serial.print(errorText);
errorBlink(10);
ESP.deepSleep(1 * 60 * 6e7);
}
void connectWifi(){
Serial.println();
Serial.print("Connecting to ");
Serial.println(ssid);
WiFi.begin(ssid, password);
int count = 0 ;
while (WiFi.status() != WL_CONNECTED && count <= 15) {
delay(1000);
Serial.print(".");
count++;
}
if(WiFi.status() != WL_CONNECTED){
handleError("Failed to connect to Wifi.");
} else{
Serial.println();
Serial.println("WiFi connected.");
Serial.println("IP address: "+ WiFi.localIP().toString() + ".");
successBlink();
}
}
int measureSoilMoistPercentage(){
return constrain(map(analogRead(soilMoistPin), 630, 240, 0, 100), 0, 100);
}
void calculateAverageSoilMoistness(int numOfMeasurements, int timeBetweenMeasurementsInMS){
Serial.println();
Serial.println("Calculating avarage soil moist percentage.");
int sumOfMeasurements = 0;
for (int i = 0; i < numOfMeasurements; i++) {
sumOfMeasurements += measureSoilMoistPercentage();
if(i != numOfMeasurements - 1){
delay(timeBetweenMeasurementsInMS);
}
}
averageSoilMoistness = sumOfMeasurements / numOfMeasurements;
Serial.println();
Serial.println("Average soil moistness: " + String(averageSoilMoistness) + " %.");
successBlink();
}
void pumpWater(int pumpTimeInS){
Serial.println();
Serial.println("Started pumping water.");
digitalWrite(pumpPin,HIGH);
delay(pumpTimeInS * 1000);
Serial.println("Stopped pumping water");
digitalWrite(pumpPin,LOW);
}
void decideToPump(){
if(averageSoilMoistness < 40){
pumpWater(60);
pumpWasActive = true;
}else{
Serial.println();
Serial.println("No need to pump water.");
}
}
void publishData(){
Serial.println();
Serial.println("Connecting to MQTT server...");
if (client.connect(clientId, mqtt_user, mqtt_pwd)) {
Serial.println("MQTT connected");
successBlink();
char payload[40];
sprintf(payload, "{\"soilMoistness\": %i, \"pumpWasActive\": %s}", averageSoilMoistness, pumpWasActive ? "true" : "false");
boolean published = client.publish(pub_topic, payload);
delay(500);
if(published){
Serial.println();
Serial.println("Planter data was published:");
Serial.println(payload);
successBlink();
} else{
handleError("Failed to publish planter data");
}
} else {
handleError("Failed to connect to MQTT server.");
}
}
void setup() {
Serial.begin(9600);
pinMode(D0, WAKEUP_PULLUP);
pinMode(pumpPin,OUTPUT);
pinMode(powerLedPin,OUTPUT);
pinMode(errorLedPin,OUTPUT);
delay(200);
digitalWrite(powerLedPin,HIGH);
connectWifi();
client.setServer(mqtt_server, mqtt_port);
calculateAverageSoilMoistness(5, 200);
decideToPump();
publishData();
ESP.deepSleep(1 * 60 * 6e7);
}
void loop() {
}