forked from PaperMC/paperweight-examples
-
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
149 lines (128 loc) · 4.87 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
plugins {
java
`maven-publish`
// Nothing special about this, just keep it up to date
id("com.github.johnrengelman.shadow") version "8.1.1" apply false
// In general, keep this version in sync with upstream. Sometimes a newer version than upstream might work, but an older version is extremely likely to break.
id("io.papermc.paperweight.patcher") version "1.5.11"
signing
}
val paperMavenPublicUrl = "https://repo.papermc.io/repository/maven-public/"
repositories {
mavenCentral()
maven(paperMavenPublicUrl) {
content { onlyForConfigurations(configurations.paperclip.name) }
}
}
dependencies {
remapper("net.fabricmc:tiny-remapper:0.8.10:fat") // Must be kept in sync with upstream
decompiler("net.minecraftforge:forgeflower:2.0.627.2") // Must be kept in sync with upstream
paperclip("io.papermc:paperclip:3.0.3") // You probably want this to be kept in sync with upstream
}
allprojects {
apply(plugin = "java")
apply(plugin = "maven-publish")
apply(plugin = "signing")
java {
toolchain {
languageVersion = JavaLanguageVersion.of(17)
}
}
}
subprojects {
tasks.withType<JavaCompile> {
options.encoding = Charsets.UTF_8.name()
options.release = 17
}
tasks.withType<Javadoc> {
options.encoding = Charsets.UTF_8.name()
}
tasks.withType<ProcessResources> {
filteringCharset = Charsets.UTF_8.name()
}
repositories {
mavenCentral()
maven(paperMavenPublicUrl)
}
}
paperweight {
serverProject = project(":onelitepaper-server")
remapRepo = paperMavenPublicUrl
decompileRepo = paperMavenPublicUrl
usePaperUpstream(providers.gradleProperty("paperRef")) {
withPaperPatcher {
apiPatchDir = layout.projectDirectory.dir("patches/api")
apiOutputDir = layout.projectDirectory.dir("onelitepaper-api")
serverPatchDir = layout.projectDirectory.dir("patches/server")
serverOutputDir = layout.projectDirectory.dir("onelitepaper-server")
}
patchTasks.register("generatedApi") {
isBareDirectory = true
upstreamDirPath = "paper-api-generator/generated"
patchDir = layout.projectDirectory.dir("patches/generatedApi")
outputDir = layout.projectDirectory.dir("paper-api-generator/generated")
}
patchTasks.register("mojangApi") {
isBareDirectory.set(true)
upstreamDirPath.set("Paper-MojangAPI")
patchDir.set(layout.projectDirectory.dir("patches/mojangapi"))
outputDir.set(layout.projectDirectory.dir("onelitepaper-mojangapi"))
}
}
}
//
// Everything below here is optional if you don't care about publishing API or dev bundles to your repository
//
tasks.generateDevelopmentBundle {
apiCoordinates = "net.onelitefeather.onelitepaper:onelitepaper-api"
mojangApiCoordinates = "io.papermc.paper:paper-mojangapi"
val ciApiv4Url = System.getenv("GITLAB_API_URL")
val projectId = System.getenv("GITLAB_PROJECT_ID")
libraryRepositories = listOf(
"https://repo.maven.apache.org/maven2/",
paperMavenPublicUrl,
"$ciApiv4Url/projects/$projectId/packages/maven"
// "https://my.repo/", // This should be a repo hosting your API (in this example, 'com.example.paperfork:forktest-api')
)
}
allprojects {
// Publishing API:
// ./gradlew :ForkTest-API:publish[ToMavenLocal]
publishing {
repositories {
maven {
name = "Gitlab"
val ciApiv4Url = System.getenv("GITLAB_API_URL")
val projectId = System.getenv("GITLAB_PROJECT_ID")
url = uri("$ciApiv4Url/projects/$projectId/packages/maven")
// See Gradle docs for how to provide credentials to PasswordCredentials
// https://docs.gradle.org/current/samples/sample_publishing_credentials.html
credentials(PasswordCredentials::class) {
username = System.getenv("GITLAB_USERNAME")
password = System.getenv("GITLAB_TOKEN")
}
authentication {
create("basic", BasicAuthentication::class)
}
}
}
}
}
publishing {
// Publishing dev bundle:
// ./gradlew publishDevBundlePublicationTo(MavenLocal|MyRepoSnapshotsRepository) -PpublishDevBundle
if (project.hasProperty("publishDevBundle")) {
publications.create<MavenPublication>("devBundle") {
artifact(tasks.generateDevelopmentBundle) {
artifactId = "dev-bundle"
}
}
}
}
signing {
isRequired = System.getenv("CI") != null
val privateKey = System.getenv("GPG_PRIVATE_KEY")
val keyPassphrase = System.getenv()["GPG_PASSPHRASE"]
useInMemoryPgpKeys(privateKey, keyPassphrase)
sign(publishing.publications)
}