SpaceNightVision/build.gradle at master · Reddishye/SpaceNightVision · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
plugins {
    id 'com.gradleup.shadow' version '9.0.0-beta4'
    id 'java'
}

group = 'es.redactado'
version = '1.0-SNAPSHOT'

repositories {
    mavenCentral()
    maven {
        name = "papermc-repo"
        url = "https://repo.papermc.io/repository/maven-public/"
    }
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/groups/public/"
    }
}

dependencies {
    compileOnly("io.papermc.paper:paper-api:1.20.4-R0.1-SNAPSHOT")

    annotationProcessor 'org.projectlombok:lombok:1.18.34'
    implementation 'org.spongepowered:configurate-yaml:4.1.2'
    implementation 'com.google.inject:guice:7.0.0'
    implementation "net.kyori:adventure-platform-bukkit:4.3.2"
    implementation "net.kyori:adventure-text-minimessage:4.16.0"
    implementation "net.kyori:adventure-api:4.16.0"
    implementation "org.slf4j:slf4j-api:2.0.0-alpha1"
    compileOnly 'org.projectlombok:lombok:1.18.34'
}

def targetJavaVersion = 17
java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    sourceCompatibility = javaVersion
    targetCompatibility = javaVersion
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'

    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        options.release.set(targetJavaVersion)
    }
}

shadowJar {
    archiveBaseName.set('SpaceNightVision')
    archiveClassifier.set('')
    archiveVersion.set(project.version.toString())

    from('LICENSE') {
        into('/')
    }

    manifest {
        attributes(
                'Main-Class': 'es.redactado.spaceNightVision.core.loaders.PluginLoader',
                'Implementation-Version': project.version,
                'Implementation-Title': 'SpaceNightVision',
                'Implementation-Vendor': 'SpaceMC Network',
                'Implementation-Vendor-Id': 'SpaceMC',
                'Implementation-URL': 'https://github.com/Reddishye/SpaceNightVision'
        )
    }
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('paper-plugin.yml') {
        expand props
    }
}