-
Notifications
You must be signed in to change notification settings - Fork 0
/
Mandelbrot.elm
188 lines (153 loc) · 4.45 KB
/
Mandelbrot.elm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
module Mandelbrot
exposing
( Model
, init
, zoomViewport
, computeCell
, computeRow
, computeAll
, view
)
import Dict exposing (Dict)
import Html exposing (Html, button, div, text)
import Html.Attributes exposing (..)
import Html.Events exposing (..)
import Complex exposing (Complex)
maxIterations =
200
type alias Point =
( Int, Int )
type alias Model =
{ width : Int
, height : Int
, computed : Dict Point Int
, min : Complex
, max : Complex
}
init : Int -> Model
init size =
{ width = size
, height = size
, computed = Dict.empty
, min = Complex.complex -2 -1.5
, max = Complex.complex 1 1.5
}
zoomViewport : Int -> Int -> Model -> Model
zoomViewport row col model =
let
focus =
complexNumberForPoint model row col
in
{ model
| min =
Complex.complex
((model.min.re + focus.re) / 2)
((model.min.im + focus.im) / 2)
, max =
Complex.complex
((model.max.re + focus.re) / 2)
((model.max.im + focus.im) / 2)
, computed = Dict.empty
}
calculate : Int -> Complex -> Int -> Complex -> Maybe Int
calculate maxIterations c iterations z =
let
-- z' = z^2 + c
z' =
Complex.mult z z
|> Complex.add c
in
if iterations >= maxIterations then
Nothing
else if Complex.abs z' >= 2 then
Just iterations
else
calculate maxIterations c (iterations + 1) z'
complexNumberForPoint : Model -> Int -> Int -> Complex
complexNumberForPoint model row col =
let
colPercent =
toFloat col / toFloat model.width
rowPercent =
toFloat row / toFloat model.height
in
Complex.complex
(model.min.re + (model.max.re - model.min.re) * colPercent)
(model.min.im + (model.max.im - model.min.im) * rowPercent)
computeCell : Int -> Int -> Model -> Model
computeCell row col model =
let
c =
complexNumberForPoint model row col
value =
calculate maxIterations c 0 c
in
case value of
Just iterations ->
{ model
| computed = Dict.insert ( col, row ) iterations model.computed
}
Nothing ->
{ model
| computed = Dict.remove ( col, row ) model.computed
}
computeRow : Int -> Model -> Model
computeRow row model =
List.foldl (computeCell row) model [0..model.width]
computeAll : Model -> Model
computeAll model =
List.foldl computeRow model [0..model.height]
-- the Mandelbrot formula is an iteration from
-- z = z^2 + c
-- in complex numbers
-- and this will go to infiniti (proven when result gets larger than 2) or remain a finite value,
-- the color is black when finite or based on the amount of iterations to get to 2
view : (( Int, Int ) -> msg) -> Model -> Html msg
view onCLickMsg model =
div [ style [ ( "padding", "8px" ) ] ]
(List.map (viewRow onCLickMsg model) [0..model.height])
viewRow : (( Int, Int ) -> msg) -> Model -> Int -> Html msg
viewRow onCLickMsg model row =
div
[ style
[ ( "height", "2px" )
]
]
(List.map (viewCell onCLickMsg model row) [0..model.width])
determineColor : Int -> String
determineColor iterations =
let
x =
iterations % 5
in
if x < 1 then
"yellow"
else if x < 2 then
"orange"
else if x < 3 then
"red"
else if x < 4 then
"pink"
else
"white"
viewCell : (( Int, Int ) -> msg) -> Model -> Int -> Int -> Html msg
viewCell onClickMsg model row col =
let
color =
Dict.get ( col, row ) model.computed
|> Maybe.map determineColor
|> Maybe.withDefault "black"
in
div
[ style
[ ( "width", "2px" )
, ( "height", "2px" )
, ( "line-height", "2px" )
, ( "background-color", color )
, ( "display", "inline-block" )
, ( "border", "none" )
, ( "vertical-align", "top" )
]
, onClick (onClickMsg ( col, row ))
]
[]