SLATE-TO-BE/build.gradle at main · SLAT-TO/SLATE-TO-BE · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
buildscript {
	repositories {
		mavenCentral()
	}
	dependencies {
		classpath 'org.flywaydb:flyway-mysql:11.7.2'
		classpath 'com.mysql:mysql-connector-j:9.7.0'
	}
}

plugins {
	id 'java'
	id 'org.springframework.boot' version '3.5.15'
	id 'io.spring.dependency-management' version '1.1.7'
	id 'org.flywaydb.flyway' version '11.7.2'
}

group = 'com.slatto'
version = '0.0.1-SNAPSHOT'
description = 'SLAT-TO Backend'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

repositories {
	mavenCentral()
}

flyway {
	url = providers.environmentVariable('FLYWAY_URL').orNull
	user = providers.environmentVariable('FLYWAY_USER').orNull
	password = providers.environmentVariable('FLYWAY_PASSWORD').orNull
	locations = ['filesystem:src/main/resources/db/migration']
	baselineOnMigrate = true
	baselineVersion = '8'
	baselineDescription = 'legacy-schema'
	validateOnMigrate = true
	cleanDisabled = true
}

def flywayDatabaseTasks = [
	'flywayBaseline',
	'flywayClean',
	'flywayInfo',
	'flywayMigrate',
	'flywayRepair',
	'flywayUndo',
	'flywayValidate'
]

tasks.matching { it.name in flywayDatabaseTasks }.configureEach {
	doFirst {
		def missingVariables = ['FLYWAY_URL', 'FLYWAY_USER', 'FLYWAY_PASSWORD']
			.findAll { !providers.environmentVariable(it).orNull?.trim() }

		if (!missingVariables.isEmpty()) {
			throw new GradleException(
				"Flyway task requires explicit environment variables: ${missingVariables.join(', ')}"
			)
		}
	}
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	implementation 'org.springframework.boot:spring-boot-starter-mail'
	implementation 'org.flywaydb:flyway-core'
	implementation 'org.flywaydb:flyway-mysql'
	implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.16'
	implementation 'me.paulschwarz:spring-dotenv:4.0.0'
	implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'
	compileOnly 'org.projectlombok:lombok'
	developmentOnly 'org.springframework.boot:spring-boot-devtools'
	runtimeOnly 'com.mysql:mysql-connector-j'
	annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testRuntimeOnly 'com.h2database:h2'
	testCompileOnly 'org.projectlombok:lombok'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
	testAnnotationProcessor 'org.projectlombok:lombok'

	// AWS
	implementation platform('software.amazon.awssdk:bom:2.27.21')
	implementation 'software.amazon.awssdk:s3'
}

tasks.named('test') {
	useJUnitPlatform()
}

tasks.named('bootJar') {
    archiveFileName = 'slatto.jar'
}