CMakeLists.txt

# 最低CMake版本要求
cmake_minimum_required(VERSION 3.16)

# 项目名称和版本
set(GRID_SIM_BASE_VERSION "0.1.0")
project(GridSimSubsystem VERSION ${GRID_SIM_BASE_VERSION} LANGUAGES C CXX)
# Python interpreter for glad (set via -DPython_EXECUTABLE=... if auto-detect fails)

# 设置C++标准
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

# 设置构建类型（默认Debug）
if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE Debug)
endif()

# 构建选项
option(BUILD_EXAMPLES "Build examples" ON)
option(BUILD_VISUALIZATION "Build visualization example (GLFW + ImGui + GLAD)" ON)

# 配置生成路径
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

# 设置头文件目录
include_directories(${PROJECT_SOURCE_DIR}/include)

# 查找源文件
file(GLOB_RECURSE SOURCES
    "src/grid_sim/*.cpp"
    "src/grid_sim/api/*.cpp"
    "src/grid_sim/builder/*.cpp"
)

# 强制使用静态运行时库（MT）
if(MSVC)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MT")
endif()

# 创建静态库
add_library(grid_sim STATIC ${SOURCES})  # 创建静态库

# 如果需要链接其他库（例如OpenMP），可以在这里设置
find_package(OpenMP)
if(OpenMP_CXX_FOUND)
    target_link_libraries(grid_sim PUBLIC OpenMP::OpenMP_CXX)
endif()

# 配置 GoogleMock（如果需要）
option(BUILD_GMOCK "Build the googlemock subproject" ON)
option(INSTALL_GTEST "Enable installation of googletest" OFF)
option(GTEST_HAS_ABSL "Use Abseil and RE2" OFF)

if(GTEST_HAS_ABSL)
    if(NOT TARGET absl::base)
        find_package(absl REQUIRED)
    endif()
    if(NOT TARGET re2)
        find_package(re2 REQUIRED)
    endif()
endif()

# 添加 GoogleTest 子目录，指定独立的二进制目录
add_subdirectory(third_party/googletest ${CMAKE_BINARY_DIR}/googletest_build)

# 渲染可视化依赖
if(BUILD_VISUALIZATION)
    find_package(OpenGL REQUIRED)

    set(GLFW_BUILD_DOCS OFF CACHE BOOL "" FORCE)
    set(GLFW_BUILD_TESTS OFF CACHE BOOL "" FORCE)
    set(GLFW_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
    add_subdirectory(third_party/glfw ${CMAKE_BINARY_DIR}/glfw_build)

    add_subdirectory(third_party/glad/cmake ${CMAKE_BINARY_DIR}/glad_build)
    glad_add_library(glad STATIC REPRODUCIBLE API gl:compatibility=3.3)

    set(IMGUI_DIR ${PROJECT_SOURCE_DIR}/third_party/imgui)
    add_library(imgui STATIC
        ${IMGUI_DIR}/imgui.cpp
        ${IMGUI_DIR}/imgui_draw.cpp
        ${IMGUI_DIR}/imgui_tables.cpp
        ${IMGUI_DIR}/imgui_widgets.cpp
        ${IMGUI_DIR}/imgui_demo.cpp
        ${IMGUI_DIR}/backends/imgui_impl_glfw.cpp
        ${IMGUI_DIR}/backends/imgui_impl_opengl3.cpp
    )
    target_include_directories(imgui PUBLIC
        ${IMGUI_DIR}
        ${IMGUI_DIR}/backends
    )
    target_compile_definitions(imgui PUBLIC GLFW_INCLUDE_NONE)
    target_link_libraries(imgui PUBLIC glfw OpenGL::GL)
endif()

# 启用测试
enable_testing()
set(CTEST_OUTPUT_ON_FAILURE ON)
set(CMAKE_CTEST_ARGUMENTS "--output-on-failure")

# 创建测试可执行文件
file(GLOB_RECURSE TEST_SOURCES "tests/*.cpp")
add_executable(test_grid_sim ${TEST_SOURCES})
target_link_libraries(test_grid_sim PRIVATE grid_sim gtest gmock)

# 配置测试的目录
add_test(NAME GridSimTest COMMAND test_grid_sim)
add_custom_target(check
    DEPENDS test_grid_sim
    COMMAND ${CMAKE_CTEST_COMMAND} -C Debug --output-on-failure
    WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
)

# 示例程序
if(BUILD_EXAMPLES)
    if(BUILD_VISUALIZATION)
        add_executable(example_visualization examples/example_visualization.cpp)
        target_link_libraries(example_visualization PRIVATE grid_sim imgui glfw glad OpenGL::GL)
    endif()
endif()

# 可选：安装规则
install(TARGETS grid_sim DESTINATION lib)
if(BUILD_EXAMPLES)
    if(BUILD_VISUALIZATION)
        install(TARGETS example_visualization DESTINATION bin)
    endif()
endif()
install(DIRECTORY include/ DESTINATION include)

# 可选：定义不同平台的条件编译设置
if(WIN32)
    message(STATUS "Compiling on Windows")
elseif(UNIX)
    message(STATUS "Compiling on Unix-like system")
endif()


# Version info (tag preferred, fallback to base+sha)
set(GRID_SIM_GIT_SHA "unknown")
set(GRID_SIM_GIT_TAG "")
if(EXISTS "${CMAKE_SOURCE_DIR}/.git")
    find_package(Git QUIET)
    if(GIT_FOUND)
        execute_process(
            COMMAND "${GIT_EXECUTABLE}" rev-parse --short=7 HEAD
            WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
            OUTPUT_VARIABLE GRID_SIM_GIT_SHA
            OUTPUT_STRIP_TRAILING_WHITESPACE
            RESULT_VARIABLE GRID_SIM_GIT_SHA_RESULT
        )
        if(NOT GRID_SIM_GIT_SHA_RESULT EQUAL 0)
            set(GRID_SIM_GIT_SHA "unknown")
        endif()

        execute_process(
            COMMAND "${GIT_EXECUTABLE}" describe --tags --exact-match
            WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
            OUTPUT_VARIABLE GRID_SIM_GIT_TAG
            OUTPUT_STRIP_TRAILING_WHITESPACE
            RESULT_VARIABLE GRID_SIM_GIT_TAG_RESULT
            ERROR_QUIET
        )
        if(NOT GRID_SIM_GIT_TAG_RESULT EQUAL 0)
            set(GRID_SIM_GIT_TAG "")
        endif()
    endif()
endif()

set(GRID_SIM_VERSION "${PROJECT_VERSION}+g${GRID_SIM_GIT_SHA}")
set(GRID_SIM_SOURCE_VERSION "${PROJECT_VERSION}+g${GRID_SIM_GIT_SHA}")
if(GRID_SIM_GIT_TAG)
    string(REGEX REPLACE "^v" "" GRID_SIM_VERSION "${GRID_SIM_GIT_TAG}")
endif()
message(STATUS "GridSim version: ${GRID_SIM_VERSION}")

set(GRID_SIM_PLATFORM "${CMAKE_SYSTEM_NAME}")
if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
    set(GRID_SIM_PLATFORM "Windows")
elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
    set(GRID_SIM_PLATFORM "Linux")
elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
    set(GRID_SIM_PLATFORM "macOS")
endif()

set(GRID_SIM_COMPILER_LABEL "${CMAKE_CXX_COMPILER_ID}")
if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
    set(GRID_SIM_COMPILER_LABEL "gcc")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
    set(GRID_SIM_COMPILER_LABEL "clang")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "AppleClang")
    set(GRID_SIM_COMPILER_LABEL "clang")
elseif(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
    set(GRID_SIM_COMPILER_LABEL "cl")
else()
    string(TOLOWER "${CMAKE_CXX_COMPILER_ID}" GRID_SIM_COMPILER_LABEL)
endif()

set(GRID_SIM_CPACK_BUILD_CONFIG "${CMAKE_BUILD_TYPE}")
if(CMAKE_CONFIGURATION_TYPES)
    set(GRID_SIM_CPACK_BUILD_CONFIG "\${CPACK_BUILD_CONFIG}")
endif()

set(GRID_SIM_PACKAGE_SUFFIX "")
if(GRID_SIM_GIT_TAG)
    set(GRID_SIM_PACKAGE_SUFFIX "-g${GRID_SIM_GIT_SHA}")
endif()

# CPack config (binary + source packages)
set(CPACK_PACKAGE_NAME "${PROJECT_NAME}")
set(CPACK_PACKAGE_VERSION "${GRID_SIM_VERSION}")
set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Grid simulation system")
set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.txt")
set(CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
set(CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${GRID_SIM_PLATFORM}-${GRID_SIM_CPACK_BUILD_CONFIG}-${GRID_SIM_COMPILER_LABEL}${GRID_SIM_PACKAGE_SUFFIX}")
set(CPACK_SOURCE_GENERATOR "TGZ;ZIP")
set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${GRID_SIM_SOURCE_VERSION}-Source")
set(CPACK_SOURCE_IGNORE_FILES
    "/build/;/out/;/bin/;/lib/;/cmake-build-.*/;/.git/;/.vs/;/.vscode/;/.github/;~$;${CPACK_SOURCE_IGNORE_FILES}"
)
include(CPack)