LinDamped.mpl

#!/home/tzdyrski/bin/maple -q
#
# Solves the Linear damped oscillator using the method of multiple scales.
#
# Written for Maple 2017
# Thomas Zdyrski (tzdyrski@ucsd.edu)
# 10 April 2018

restart():

LinDamped := module()

export
  UnitTests,
  LinDamped:

UnitTests := proc()

description "Run unit tests.":

# Test 1st-order LinDamped procedure
CodeTools:-Test(LinDamped(1),
{[y(t) = exp(-t__1)*cos(1/2*t__1+t__0)+sin(t__0)*epsilon]},
label="1st-Order LinDamped Procedure Test"):

# Test 2nd-order LinDamped procedure
CodeTools:-Test(LinDamped(2),
{[y(t) =
exp(-t__1)*cos(-5/8*t__2+1/2*t__1+t__0)+exp(-t__1)*sin(1/2*t__1+t__0)*epsilon-1/2*sin(t__0)*epsilon^2]},
label="2nd-Order LinDamped Procedure Test"):

end proc:

LinDamped := proc(
  e_order::integer:=1, # highest order in epsilon to keep (leading order is e_order 1)
  {leading_order_eqs::integer:=0, # Leading order of perturbation expansion for dependent variable
   t_num::integer:=e_order-leading_order_eqs+1}, # number of time scales to implement
  $)
local
  PDEs,
  ICs:

# Load packages
read("MultipleScales.mpl"):

interface(ansi=true, errorbreak=2):

# Define our system of equations
PDEs := {diff(y(t),t,t) + (1+epsilon)*y(t) + 2*epsilon*diff(y(t),t) = 0}:

# Generate initial conditions
ICs := {y(0) = 1, D(y)(0)=0}:

# Solve equations
MultipleScales:-CompleteSystem(PDEs, e_order,
  ':-scales'=t, ':-leading_order_eqs'=leading_order_eqs,
  'ICs'=ICs, ':-restrict_scales'=true):

return %:

end proc:

end module:

#LinDamped:-LinDamped(2):
#combine(%, trig);