build.gradle

apply plugin: 'java'
apply plugin: 'nexus'
apply plugin: 'eclipse'

group = 'com.trigonic'
version = '0.3-SNAPSHOT'

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'org.gradle.api.plugins:gradle-nexus-plugin:0.2'
    }
}

repositories {
    mavenCentral()
}

dependencies {
    compile 'commons-io:commons-io:1.4'
    compile 'log4j:log4j:1.2.16'

    testCompile 'junit:junit:4.+'
    testCompile 'org.easymock:easymock:2.4'
    testCompile 'org.easymock:easymockclassextension:2.4'
}

task packageJavadoc(type: Jar, dependsOn: 'javadoc') {
    from javadoc.destinationDir
    classifier = 'javadoc'
}

task packageSources(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

artifacts {
    archives jar
    archives packageJavadoc
    archives packageSources
}

modifyPom {
    project {
        name 'jrobotx - Java Robot Exclusion Compliance Library'
        packaging 'jar'
        description 'Library to provide compliance with the Web Robot Exclusion protocol (robots.txt)'
        url 'https://github.com/TrigonicSolutions/jrobotx'
        inceptionYear '2011'

        parent {
            groupId 'org.sonatype.oss'
            artifactId 'oss-parent'
            version '7'
        }
 
        scm {
            url 'scm:git://github.com/TrigonicSolutions/jrobotx.git'
            connection 'scm:git://github.com/TrigonicSolutions/jrobotx.git'
        }
 
        licenses {
            license {
                name 'The Apache Software License, Version 2.0'
                url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                distribution 'repo'
            }
        }
 
        developers {
            developer {
                id 'akrueger'
                name 'Alan Krueger'
                email 'alan@trigonic.com'
                roles{
                    role 'Developer'
                }
                timezone '-6'
            }
        }
    }
}

task createWrapper(type: Wrapper) {
    gradleVersion = '1.2'
}