More efficient, but destructive 16-bit int to string rourines

Author: Zeda

conversion/i16toa_destructive.z80

@@ -0,0 +1,40 @@
+#ifndef included_itoa_16
+#define included_itoa_16
+#include conversion/u16toa_destructive.z80
+
+
+; A related routine can be found at conversion/itoa_16.z80 which preserves
+; registers.
+
+;written by Zeda
+;Converts a 16-bit signed integer to an ASCII string.
+;Note that this version destroys registers.
+
+#ifndef TOK_NEG
+#define TOK_NEG '-'
+#endif
+
+i16toa:
+;Input:
+;   DE is the number to convert
+;   HL points to where to write the ASCII string (up to 7 bytes needed).
+;Output:
+;   HL points to the null-terminated ASCII string
+;      NOTE: This isn't necessarily the same as the input HL.
+;Destroys:
+;   DE, BC, AF
+  ld a,d
+  add a,a
+  jp nc,u16toa
+  xor a
+  sub e
+  ld e,a
+  sbc a,a
+  sub d
+  ld d,a
+  inc hl  ; make space for a negative sign
+  call u16toa
+  dec hl
+  ld (hl),TOK_NEG
+  ret
+#endif

conversion/u16toa_destructive.z80

@@ -0,0 +1,78 @@
+#ifndef included_u16toa
+#define included_u16toa
+
+; A related routine can be found at conversion/utoa_16.z80 which preserves
+; registers.
+
+;written by Zeda
+;Converts a 16-bit unsigned integer to an ASCII string.
+;Note that this version destroys registers.
+
+u16toa:
+;Input:
+;   DE is the number to convert
+;   HL points to where to write the ASCII string (up to 6 bytes needed).
+;Output:
+;   HL points to the null-terminated ASCII string
+;      NOTE: This isn't necessarily the same as the input HL.
+;Destroys:
+;   BC, DE, AF
+  ex de,hl
+
+; First digit
+  ld bc,-10000
+  ld a,'0'-1
+  inc a     ;\
+  add hl,bc ; | Loop
+  jr c,$-2  ;/
+  ld (de),a
+  inc de
+
+; Second digit
+  ld bc,1000
+  ld a,'9'+1
+  dec a     ;\
+  add hl,bc ; | Loop
+  jr nc,$-2 ;/
+  ld (de),a
+  inc de
+
+; Third digit
+  ld bc,-100
+  ld a,'0'-1
+  inc a     ;\
+  add hl,bc ; | Loop
+  jr c,$-2  ;/
+  ld (de),a
+  inc de
+
+; Fourth digit, remainder is fifth digit
+  ld a,l
+  ld h,'9'+1
+  dec h     ;\
+  add a,10  ; | Loop
+  jr nc,$-3 ;/
+  ex de,hl
+  ld (hl),d
+  inc hl
+  add a,'0'
+  ld (hl),a
+  inc hl
+  ld (hl),0
+
+;Now strip the leading zeros
+  ld c,-6
+  add hl,bc
+
+  ld a,'0'
+  inc hl    ;\
+  cp (hl)   ; | Loop
+  jr z,$-2  ;/
+
+;Make sure that the string is non-empty!
+  xor a
+  cp (hl)
+  ret z
+  dec hl
+  ret
+#endif