cmake: Update versioning scheme (cvc5#12116)

The current versioning scheme follows the format:
```
<version-in-last-tag>-dev.<number-of-commits-since-last-tag>.<commit-sha>[-modified]
```
This leads to two main practical issues:

1. To retrieve `<number-of-commits-since-last-tag>`, a clone of the
repository with access to the full Git history is required. This is not
always desirable, since it introduces unnecessary overhead. For example,
the GitHub `checkout` action retrieves only the latest commit by
default. When this information is not available, the build system does
not include other useful details such as the branch name or commit SHA
in the `CVC5_GIT_INFO` constant.

2. Even when the full history is available, the list of tags may not be.
This is common when a user or developer works on their own fork of the
repository.

This PR changes the format to:
```
<latest-release-version>-dev.<branch-name>@<commit-sha>[-modified]
```
This makes the version scheme more robust when the Git history or list
of tags is not available.

In addition, this PR preserves the old behavior of incrementing the
patch version by one when a development version is detected.

Author: daniel-larraz

cmake/version.cmake

@@ -36,20 +36,48 @@ endif()
 # include basic version information
 include(version-base)
 
+if(CVC5_IS_RELEASE STREQUAL "false")
+  # increment patch part of version (CVC5_LAST_RELEASE + 0.0.1)
+  set(NEXT_CVC5_VERSION ${CVC5_LAST_RELEASE})
+  string(REGEX MATCHALL "[0-9]+" VERSION_LIST "${NEXT_CVC5_VERSION}")
+  list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
+  # append .0 until we have a patch part
+  while(VERSION_LIST_LENGTH LESS "3")
+    list(APPEND VERSION_LIST "0")
+    list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
+  endwhile()
+  # increment patch part
+  list(GET VERSION_LIST 2 VERSION_LAST_NUMBER)
+  list(REMOVE_AT VERSION_LIST 2)
+  math(EXPR VERSION_LAST_NUMBER "${VERSION_LAST_NUMBER} + 1")
+  list(APPEND VERSION_LIST ${VERSION_LAST_NUMBER})
+  # join version string into NEXT_CVC5_VERSION
+  list(GET VERSION_LIST 0 NEXT_CVC5_VERSION)
+  while(VERSION_LIST_LENGTH GREATER "1")
+    list(REMOVE_AT VERSION_LIST 0)
+    list(GET VERSION_LIST 0 TMP)
+    set(NEXT_CVC5_VERSION "${NEXT_CVC5_VERSION}.${TMP}")
+    list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
+  endwhile()
+
+  set(CVC5_VERSION "${NEXT_CVC5_VERSION}-dev")
+  set(CVC5_FULL_VERSION "${NEXT_CVC5_VERSION}-dev")
+endif()
+
 # now use git to retrieve additional version information
 find_package(Git)
 if(GIT_FOUND)
   # git is available
 
-  # call git describe. If result is not 0 this is not a git repository
+  # Call git. If result is 0 and prints "true", it is a git repository
   execute_process(
-      COMMAND ${GIT_EXECUTABLE} -C ${PROJECT_SOURCE_DIR} describe --long --tags --match cvc5-*
+      COMMAND ${GIT_EXECUTABLE} -C ${PROJECT_SOURCE_DIR} rev-parse --is-inside-work-tree
       RESULT_VARIABLE GIT_RESULT
-      OUTPUT_VARIABLE GIT_DESCRIBE
+      OUTPUT_VARIABLE GIT_INSIDE_WORK_TREE
       OUTPUT_STRIP_TRAILING_WHITESPACE
   )
 
-  if(GIT_RESULT EQUAL 0)
+  if(GIT_RESULT EQUAL 0 AND GIT_INSIDE_WORK_TREE STREQUAL "true")
     # it is a git working copy
 
     set(GIT_BUILD "true")
@@ -60,66 +88,33 @@ if(GIT_FOUND)
         OUTPUT_VARIABLE GIT_BRANCH
         OUTPUT_STRIP_TRAILING_WHITESPACE
     )
+    # get current git commit
+    execute_process(
+        COMMAND ${GIT_EXECUTABLE} -C ${PROJECT_SOURCE_DIR} rev-parse --short HEAD
+        RESULT_VARIABLE GIT_RESULT
+        OUTPUT_VARIABLE GIT_COMMIT
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+
+    if(CVC5_IS_RELEASE STREQUAL "false")
+      set(CVC5_FULL_VERSION "${CVC5_FULL_VERSION}-${GIT_BRANCH}@${GIT_COMMIT}")
+    endif()
+
     # result is != 0 if worktree is dirty
     # note: git diff HEAD shows both staged and unstaged changes.
     execute_process(
-      COMMAND ${GIT_EXECUTABLE} -C ${PROJECT_SOURCE_DIR} diff HEAD --quiet
+      COMMAND ${GIT_EXECUTABLE} -C ${PROJECT_SOURCE_DIR} diff-index --quiet HEAD
       RESULT_VARIABLE GIT_RESULT
     )
     if(GIT_RESULT EQUAL 0)
       set(GIT_DIRTY_MSG "")
     else()
       set(GIT_DIRTY_MSG " with local modifications")
+      set(CVC5_VERSION "${CVC5_VERSION}-modified")
+      set(CVC5_FULL_VERSION "${CVC5_FULL_VERSION}-modified")
     endif()
 
-    string(REGEX MATCH "^cvc5-([0-9.]+)-([0-9]+)-g([0-9a-f]+)$" MATCH "${GIT_DESCRIBE}")
-    if(NOT MATCH)
-      message(SEND_ERROR "Unexpected format from 'git describe': '${GIT_DESCRIBE}'")
-    endif()
-    set(GIT_LAST_TAG "${CMAKE_MATCH_1}")
-    set(GIT_COMMITS_SINCE_TAG "${CMAKE_MATCH_2}")
-    set(GIT_COMMIT "${CMAKE_MATCH_3}")
-
-    if(GIT_COMMITS_SINCE_TAG EQUAL "0")
-      # this version *is* a tag
-      set(CVC5_IS_RELEASE "true")
-      set(CVC5_VERSION "${GIT_LAST_TAG}")
-      set(CVC5_FULL_VERSION "${GIT_LAST_TAG}")
-      set(CVC5_GIT_INFO "git tag ${GIT_LAST_TAG} branch ${GIT_BRANCH}${GIT_DIRTY_MSG}")
-    else()
-      # this version is not a tag
-
-      # increment patch part of version
-      string(REGEX MATCHALL "[0-9]+" VERSION_LIST "${GIT_LAST_TAG}")
-      list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
-      # append .0 until we have a patch part
-      while(VERSION_LIST_LENGTH LESS "3")
-        list(APPEND VERSION_LIST "0")
-        list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
-      endwhile()
-      # increment patch part
-      list(GET VERSION_LIST 2 VERSION_LAST_NUMBER)
-      list(REMOVE_AT VERSION_LIST 2)
-      math(EXPR VERSION_LAST_NUMBER "${VERSION_LAST_NUMBER} + 1")
-      list(APPEND VERSION_LIST ${VERSION_LAST_NUMBER})
-      # join version string into GIT_LAST_TAG
-      list(GET VERSION_LIST 0 GIT_LAST_TAG)
-      while(VERSION_LIST_LENGTH GREATER "1")
-        list(REMOVE_AT VERSION_LIST 0)
-        list(GET VERSION_LIST 0 TMP)
-        set(GIT_LAST_TAG "${GIT_LAST_TAG}.${TMP}")
-        list(LENGTH VERSION_LIST VERSION_LIST_LENGTH)
-      endwhile()
-
-      if(CVC5_IS_RELEASE)
-        set(CVC5_VERSION "${CVC5_VERSION}-modified")
-        set(CVC5_FULL_VERSION "${CVC5_FULL_VERSION}-modified")
-      else()
-        set(CVC5_VERSION "${GIT_LAST_TAG}-dev")
-        set(CVC5_FULL_VERSION "${GIT_LAST_TAG}-dev.${GIT_COMMITS_SINCE_TAG}.${GIT_COMMIT}")
-      endif()
-      set(CVC5_GIT_INFO "git ${GIT_COMMIT} on branch ${GIT_BRANCH}${GIT_DIRTY_MSG}")
-    endif()
+    set(CVC5_GIT_INFO "git ${GIT_COMMIT} on branch ${GIT_BRANCH}${GIT_DIRTY_MSG}")
   endif()
 endif()