build.gradle

plugins {
    // Apply the java plugin to add support for Java
    id 'java'

    // Apply the application plugin to add support for building an application
    id 'application'

    id 'idea'

    id 'org.springframework.boot' version '2.1.3.RELEASE'

    id 'io.spring.dependency-management' version "1.0.7.RELEASE"
}

repositories {
    // Use jcenter for resolving your dependencies.
    // You can declare any Maven/Ivy/file repository here.
    jcenter()
}

bootJar {
    version =  '0.1.0'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-test', {exclude group: 'junit', module: 'junit'}

    // JWT Auth
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'io.jsonwebtoken:jjwt:0.9.0'

    // Use JUnit5 test framework
    testCompile('org.junit.jupiter:junit-jupiter-api:5.5.2')
    testCompile('org.junit.jupiter:junit-jupiter-params:5.5.2')
    testRuntime('org.junit.jupiter:junit-jupiter-engine:5.5.2')
    testCompile 'io.rest-assured:rest-assured:3.3.0'
    testCompile 'com.github.kstyrc:embedded-redis:0.6'

    // Mockito
    testCompile "org.mockito:mockito-core:2.+"
    testCompile('org.mockito:mockito-junit-jupiter:2.18.3')
}

// Define the main class for the application
mainClassName = 'unit.test.training.UnitTestenForTesters'

sourceSets {
    integrationTest {
        compileClasspath += sourceSets.main.output
        runtimeClasspath += sourceSets.main.output
    }
}

configurations {
    integrationTestImplementation.extendsFrom testImplementation
    integrationTestRuntimeOnly.extendsFrom testRuntime
}

task integrationTest(type: Test) {
    outputs.upToDateWhen { false }

    testClassesDirs = sourceSets.integrationTest.output.classesDirs
    classpath = sourceSets.integrationTest.runtimeClasspath
    useJUnitPlatform()
}
task itest(type: Test) {
    dependsOn integrationTest
}

task start() {
    dependsOn bootRun;
}

test {
    useJUnitPlatform()
}

idea {
    module {
        testSourceDirs += project.sourceSets.integrationTest.java.srcDirs
        testSourceDirs += project.sourceSets.integrationTest.resources.srcDirs
    }
}