Build.cmd

@echo off

echo Testing prerequisites
:: Check if dotnet.exe is installed
for /f "tokens=*" %%i in ('where dotnet.exe') do (
  echo - 'dotnet.exe' command: found
  goto :dotnet-found
)
echo - 'dotnet.exe' command: NOT FOUND
goto :ErrorStop
:dotnet-found
:: Check if dotnet-compose is installed
for /f "tokens=*" %%i in ('where docker-compose') do (
  echo - 'docker-compose' command: found
  goto :docker-compose-found
 )
echo - 'docker-compose' command: NOT FOUND
goto :ErrorStop
:docker-compose-found
:: Check if the file with the connection string exists
if exist connection-string.txt (
  echo - 'connection-string.txt' file: found
) else (
  echo - 'connection-string.txt' file: NOT FOUND
  goto :ErrorStop
)

:: Publishing the solution with dotnet
echo. 
echo Building the solution
call dotnet publish -c Release -o publish
@if ERRORLEVEL 1 GOTO :ErrorStop

:: Building the docker images with docker-compose
echo.
echo Building the docker images
call docker-compose build
@if ERRORLEVEL 1 GOTO :ErrorStop

:: Everything is fine!
echo.
echo Docker images build successful
goto :EOF

:: Something bad happened
:ErrorStop
echo.
echo Error during the build
exit /B %RC%

:EOF