No escaping of required characters by JSON

[TyrfingMjolnir]

No escaping of required characters by JSON according to json.org

escape
'"'
''
'/'
'b'
'n'
'r'
't'
'u' hex hex hex hex

[bojanbjelic]

Hi, that's true... I would appreciate if you would contribute this.

[genglefr]

+1
Any workaround to share until then?

[ilyar]

@TyrfingMjolnir please add an example for reproduction

[MaxandreOgeret]

I ended up having to solve this issue for backslashes and newlines, not sure if this can be useful or not.

Here is an example :

        <doc xml:space="preserve"
             filename="gst/gstelement.c"
             line="1210">Retrieves a pad from the element by name (e.g. "src_\%d"). This version only
retrieves request pads. The pad should be released with
gst_element_release_request_pad().

This method is slower than manually getting the pad template and calling
gst_element_request_pad() if the pads should have a specific name (e.g.
@name is "src_1" instead of "src_\%u").

Note that this function was introduced in GStreamer 1.20 in order to provide
a better name to gst_element_get_request_pad(). Prior to 1.20, users
should use gst_element_get_request_pad() which provides the same
functionality.</doc>

I am not the best with xsl, but here's what I ended up doing to solve the problem:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:output method="text" encoding="utf-8"/>

	<xsl:template match="/">
		<xsl:text>{</xsl:text>
		<xsl:apply-templates select="." mode="detect" />
		<xsl:text>}</xsl:text>
	</xsl:template>

	<xsl:template match="*" mode="detect">
		<xsl:choose>
			<xsl:when test="name(preceding-sibling::*[1]) = name(current()) and name(following-sibling::*[1]) != name(current())">
				<xsl:apply-templates select="." mode="obj-content" />
				<xsl:text>]</xsl:text>
				<xsl:if test="count(following-sibling::*[name() != name(current())]) &gt; 0">, </xsl:if>
			</xsl:when>
			<xsl:when test="name(preceding-sibling::*[1]) = name(current())">
				<xsl:apply-templates select="." mode="obj-content" />
				<xsl:if test="name(following-sibling::*) = name(current())">, </xsl:if>
			</xsl:when>
			<xsl:when test="following-sibling::*[1][name() = name(current())]">
				<xsl:text>"</xsl:text><xsl:value-of select="name()"/><xsl:text>" : [</xsl:text>
				<xsl:apply-templates select="." mode="obj-content" /><xsl:text>, </xsl:text>
			</xsl:when>
			<xsl:when test="count(./child::*) > 0 or count(@*) > 0">
				<xsl:text>"</xsl:text><xsl:value-of select="name()"/>" : <xsl:apply-templates select="." mode="obj-content" />
				<xsl:if test="count(following-sibling::*) &gt; 0">, </xsl:if>
			</xsl:when>
			<xsl:when test="count(./child::*) = 0">
				<xsl:text>"</xsl:text><xsl:value-of select="name()"/>" : "<xsl:call-template name="escape-string"><xsl:with-param name="s" select="."/></xsl:call-template><xsl:text>"</xsl:text>
				<xsl:if test="count(following-sibling::*) &gt; 0">, </xsl:if>
			</xsl:when>
		</xsl:choose>
	</xsl:template>

	<xsl:template match="*" mode="obj-content">
		<xsl:text>{</xsl:text>
		<xsl:apply-templates select="@*" mode="attr" />
		<xsl:if test="count(@*) &gt; 0 and (count(child::*) &gt; 0 or text())">, </xsl:if>
		<xsl:apply-templates select="./*" mode="detect" />
		<xsl:if test="count(child::*) = 0 and text() and not(@*)">
			<xsl:text>"</xsl:text><xsl:value-of select="name()"/>" : "<xsl:call-template name="escape-string"><xsl:with-param name="s" select="text()"/></xsl:call-template><xsl:text>"</xsl:text>
		</xsl:if>
		<xsl:if test="count(child::*) = 0 and text() and @*">
			<xsl:text>"text" : "</xsl:text><xsl:call-template name="escape-string"><xsl:with-param name="s" select="text()"/></xsl:call-template><xsl:text>"</xsl:text>
		</xsl:if>
		<xsl:text>}</xsl:text>
		<xsl:if test="position() &lt; last()">, </xsl:if>
	</xsl:template>

	<xsl:template match="@*" mode="attr">
		<xsl:text>"</xsl:text><xsl:value-of select="name()"/>" : "<xsl:call-template name="escape-string"><xsl:with-param name="s" select="."/></xsl:call-template><xsl:text>"</xsl:text>
		<xsl:if test="position() &lt; last()">,</xsl:if>
	</xsl:template>

	<xsl:template name="escape-string">
		<xsl:param name="s"/>
		<xsl:call-template name="escape-bs-string">
			<xsl:with-param name="s" select="$s"/>
		</xsl:call-template>
	</xsl:template>

	<xsl:template name="escape-bs-string">
		<xsl:param name="s"/>
		<xsl:choose>
			<xsl:when test="contains($s,'\')">
				<xsl:call-template name="escape-quot-string">
					<xsl:with-param name="s" select="concat(substring-before($s,'\'),'\\')"/>
				</xsl:call-template>
				<xsl:call-template name="escape-bs-string">
					<xsl:with-param name="s" select="substring-after($s,'\')"/>
				</xsl:call-template>
			</xsl:when>
			<xsl:otherwise>
				<xsl:call-template name="escape-quot-string">
					<xsl:with-param name="s" select="$s"/>
				</xsl:call-template>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

	<xsl:template name="escape-quot-string">
		<xsl:param name="s"/>
		<xsl:choose>
			<xsl:when test="contains($s,'&quot;')">
				<xsl:call-template name="encode-string">
					<xsl:with-param name="s" select="concat(substring-before($s,'&quot;'),'\&quot;')"/>
				</xsl:call-template>
				<xsl:call-template name="escape-quot-string">
					<xsl:with-param name="s" select="substring-after($s,'&quot;')"/>
				</xsl:call-template>
			</xsl:when>
			<xsl:otherwise>
				<xsl:call-template name="encode-string">
					<xsl:with-param name="s" select="$s"/>
				</xsl:call-template>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

	<xsl:template name="encode-string">
		<xsl:param name="s"/>
		<xsl:choose>
			<!-- tab -->
			<xsl:when test="contains($s,'&#x9;')">
				<xsl:call-template name="encode-string">
					<xsl:with-param name="s" select="concat(substring-before($s,'&#x9;'),'\t',substring-after($s,'&#x9;'))"/>
				</xsl:call-template>
			</xsl:when>
			<!-- line feed -->
			<xsl:when test="contains($s,'&#xA;')">
				<xsl:call-template name="encode-string">
					<xsl:with-param name="s" select="concat(substring-before($s,'&#xA;'),'\n',substring-after($s,'&#xA;'))"/>
				</xsl:call-template>
			</xsl:when>
			<!-- carriage return -->
			<xsl:when test="contains($s,'&#xD;')">
				<xsl:call-template name="encode-string">
					<xsl:with-param name="s" select="concat(substring-before($s,'&#xD;'),'\r',substring-after($s,'&#xD;'))"/>
				</xsl:call-template>
			</xsl:when>
			<xsl:otherwise>
				<xsl:value-of select="$s"/>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>

</xsl:stylesheet>