bekiper/flake.nix at main · caniko/bekiper · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
{
  description = "Bikipy — kinematic data analysis workspace";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane.url = "github:ipetkov/crane";

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      flake-utils,
      advisory-db,
      ...
    }:
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};

        inherit (pkgs) lib;

        craneLib = crane.mkLib pkgs;
        src = craneLib.cleanCargoSource ./.;

        commonArgs = {
          inherit src;
          strictDeps = true;

          buildInputs = [
          ]
          ++ lib.optionals pkgs.stdenv.isDarwin [
            pkgs.libiconv
          ];
        };

        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        individualCrateArgs = commonArgs // {
          inherit cargoArtifacts;
          inherit (craneLib.crateNameFromCargoToml { inherit src; }) version;
          doCheck = false;
        };

        fileSetForCrate =
          crate:
          lib.fileset.toSource {
            root = ./.;
            fileset = lib.fileset.unions [
              ./Cargo.toml
              ./Cargo.lock
              (craneLib.fileset.commonCargoSources ./crates/bikipy-core)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-math)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-perimeter)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-reader)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-feature)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-behaviour)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-ingress)
              (craneLib.fileset.commonCargoSources ./crates/bikipy-workspace-hack)
              (craneLib.fileset.commonCargoSources crate)
            ];
          };

        # Build the CLI as the top-level binary derivation.
        bikipy-cli = craneLib.buildPackage (
          individualCrateArgs
          // {
            pname = "bikipy-cli";
            cargoExtraArgs = "-p bikipy-cli";
            src = fileSetForCrate ./crates/bikipy-cli;
          }
        );

        # Python inspection package — matplotlib visualizations driven by Rust output.
        bikipy-inspect = pkgs.python312.pkgs.buildPythonApplication {
          pname = "bikipy-inspect";
          version = "0.1.0";
          format = "pyproject";
          src = ./bikipy-inspect;

          nativeBuildInputs = [ pkgs.python312.pkgs.hatchling ];

          propagatedBuildInputs = with pkgs.python312.pkgs; [
            numpy
            polars
            matplotlib
            seaborn
            moviepy
            opencv4
            click
          ];
        };

        # Combined wrapper that puts both bkpy (Rust) and bkpy-inspect (Python)
        # on the same PATH, so the Rust CLI can invoke Python seamlessly.
        bikipy = pkgs.symlinkJoin {
          name = "bikipy";
          paths = [ bikipy-cli bikipy-inspect ];
        };
      in
      {
        checks = {
          inherit bikipy-cli;

          bikipy-clippy = craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            }
          );

          bikipy-doc = craneLib.cargoDoc (
            commonArgs
            // {
              inherit cargoArtifacts;
              env.RUSTDOCFLAGS = "--deny warnings";
            }
          );

          bikipy-fmt = craneLib.cargoFmt {
            inherit src;
          };

          bikipy-toml-fmt = craneLib.taploFmt {
            src = pkgs.lib.sources.sourceFilesBySuffices src [ ".toml" ];
          };

          bikipy-audit = craneLib.cargoAudit {
            inherit src advisory-db;
          };

          bikipy-deny = craneLib.cargoDeny {
            inherit src;
          };

          bikipy-nextest = craneLib.cargoNextest (
            commonArgs
            // {
              inherit cargoArtifacts;
              partitions = 1;
              partitionType = "count";
              cargoNextestPartitionsExtraArgs = "--no-tests=pass";
            }
          );

        };

        packages = {
          inherit bikipy-cli bikipy-inspect bikipy;
          default = bikipy;
        };

        apps = {
          bikipy = flake-utils.lib.mkApp {
            drv = bikipy;
          };
          default = self.apps.${system}.bikipy;
        };

        devShells.default = craneLib.devShell {
          checks = self.checks.${system};

          packages = [
            bikipy-inspect
          ];
        };
      }
    );
}