CMakeLists.txt

CMAKE_MINIMUM_REQUIRED (VERSION 3.1.0)

PROJECT (WALRUS VERSION 0.0.1)

# CONFIGURATION
SET (CMAKE_EXPORT_COMPILE_COMMANDS ON)

# input variable list
# WALRUS_ASAN, WALRUS_SMALL_CONFIG, WALRUS_DEBUG_INFO

MESSAGE(VERBOSE "CMAKE_SYSTEM_NAME: " ${CMAKE_SYSTEM_NAME})
MESSAGE(VERBOSE "CMAKE_SYSTEM_PROCESSOR: " ${CMAKE_SYSTEM_PROCESSOR})
# TODO: Support multi-config generator
MESSAGE(VERBOSE "CMAKE_BUILD_TYPE: " ${CMAKE_BUILD_TYPE})
IF (NOT DEFINED WALRUS_MODE)
    IF ("${CMAKE_BUILD_TYPE}" STREQUAL "")
        SET(WALRUS_MODE "release")
    ELSEIF (${CMAKE_BUILD_TYPE} STREQUAL "Release")
        SET(WALRUS_MODE "release")
    ELSEIF (${CMAKE_BUILD_TYPE} STREQUAL "RelWithDebInfo")
        SET(WALRUS_MODE "release")
        SET(WALRUS_DEBUG_INFO ON)
    ELSEIF (${CMAKE_BUILD_TYPE} STREQUAL "MinSizeRel")
        SET(WALRUS_MODE "release")
        SET(WALRUS_SMALL_CONFIG ON)
    ELSE()
        SET(WALRUS_MODE "debug")
    ENDIF()
ENDIF()

IF (NOT DEFINED WALRUS_ARCH)
    IF (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "X86" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86"
        OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i386" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "i686")
        SET(WALRUS_ARCH "x86")
    ELSEIF (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "AMD64" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x86_64"
            OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "x64" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "EM64T")
        SET(WALRUS_ARCH "x64")
    ELSEIF (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm32"
            OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "armv7l")
        SET(WALRUS_ARCH "arm")
    ELSEIF (${CMAKE_SYSTEM_PROCESSOR} STREQUAL "arm64" OR ${CMAKE_SYSTEM_PROCESSOR} STREQUAL "aarch64")
        SET(WALRUS_ARCH "aarch64")
    ENDIF()
ENDIF()

IF (NOT DEFINED WALRUS_HOST)
    IF (${CMAKE_SYSTEM_NAME} STREQUAL "Windows" OR ${CMAKE_SYSTEM_NAME} STREQUAL "WindowsStore")
        SET(WALRUS_HOST "windows")
    ELSEIF (${CMAKE_SYSTEM_NAME} STREQUAL "Android")
        SET(WALRUS_HOST "android")
    ELSEIF (${CMAKE_SYSTEM_NAME} STREQUAL "Darwin")
        SET(WALRUS_HOST "darwin")
    ELSE()
        SET(WALRUS_HOST "linux")
    ENDIF()
ENDIF()

IF (NOT DEFINED WALRUS_MODE)
    SET (WALRUS_MODE "release")
ENDIF()
IF (NOT DEFINED WALRUS_OUTPUT)
    SET (WALRUS_OUTPUT "shell")
ENDIF()

IF (NOT DEFINED WALRUS_WASI)
    # Enable WASI by default
    SET (WALRUS_WASI ON)
ENDIF()

MESSAGE(STATUS "Walrus Arch: " ${WALRUS_ARCH})
MESSAGE(STATUS "Walrus Host: " ${WALRUS_HOST})
MESSAGE(STATUS "Walrus Mode: " ${WALRUS_MODE})
MESSAGE(STATUS "Walrus Output: " ${WALRUS_OUTPUT})
MESSAGE(STATUS "Walrus WASI Enabled: " ${WALRUS_WASI})

SET (WALRUS_TARGET walrus)

INCLUDE (ProcessorCount)
PROCESSORCOUNT (NPROCS)

# INCLUDE CMAKE FILES
INCLUDE (${PROJECT_SOURCE_DIR}/build/config.cmake)
INCLUDE (${PROJECT_SOURCE_DIR}/build/walrus.cmake)