forked from rhobs/configuration
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathobservatorium-metrics-template-overwrites.libsonnet
514 lines (481 loc) · 16.4 KB
/
observatorium-metrics-template-overwrites.libsonnet
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
// This is the file overwriting and extending the upstream objects to, in the end,
// generate a OpenShift template specifically for AppSRE.
local jaegerAgent = import './sidecars/jaeger-agent.libsonnet';
local oauthProxy = import './sidecars/oauth-proxy.libsonnet';
local thanosRuleSyncer = import './sidecars/thanos-rule-syncer.libsonnet';
{
local s3EnvVars = [
{
name: 'AWS_ACCESS_KEY_ID',
valueFrom: {
secretKeyRef: {
key: 'aws_access_key_id',
name: '${THANOS_S3_SECRET}',
},
},
},
{
name: 'AWS_SECRET_ACCESS_KEY',
valueFrom: {
secretKeyRef: {
key: 'aws_secret_access_key',
name: '${THANOS_S3_SECRET}',
},
},
},
],
// JaegerAgent sidecar shared across components, thus instantiated outside components.
local jaegerAgentSidecar = jaegerAgent({
image: '${JAEGER_AGENT_IMAGE}:${JAEGER_AGENT_IMAGE_TAG}',
collectorAddress: 'dns:///${TRACING_COLLECTOR_ENDPOINT}',
}),
local ruleSyncerVolume = 'rule-syncer',
local ruleSyncerSidecar = thanosRuleSyncer({
image: '${THANOS_RULE_SYNCER_IMAGE}:${THANOS_RULE_SYNCER_IMAGE_TAG}',
rulesBackendURL: 'http://rules-objstore.${OBSERVATORIUM_NAMESPACE}.svc:8080',
volumeName: ruleSyncerVolume,
fileName: 'observatorium.yaml',
}),
thanos+:: {
local thanos = self,
config+:: {
serviceAccountName: '${SERVICE_ACCOUNT_NAME}',
},
// This extends and overwrites the objects generated by the upstream function for OpenShift specific needs.
compact+:: {
local compact = self,
// Create oauthProxy instance for compact and then merge its objects with the existing ones.
local oauth = oauthProxy({
name: 'compact',
image: '${OAUTH_PROXY_IMAGE}:${OAUTH_PROXY_IMAGE_TAG}',
upstream: 'http://localhost:10902',
serviceAccountName: thanos.config.serviceAccountName,
sessionSecretName: 'compact-proxy',
resources: {
requests: {
cpu: '${OAUTH_PROXY_CPU_REQUEST}',
memory: '${OAUTH_PROXY_MEMORY_REQUEST}',
},
limits: {
cpu: '${OAUTH_PROXY_CPU_LIMITS}',
memory: '${OAUTH_PROXY_MEMORY_LIMITS}',
},
},
}),
proxySecret: oauth.proxySecret {
metadata+: { labels+: compact.config.commonLabels },
},
service+: oauth.service,
statefulSet+: {
spec+: {
replicas: '${{THANOS_COMPACTOR_REPLICAS}}',
local disableDownsamplingFlag =
if !compact.config.disableDownsampling then
['${THANOS_COMPACTOR_RETENTION_DISABLE_DOWNSAMPLING}']
else [],
template+: {
spec+: {
securityContext: {},
containers: [
// Overwrite and extend the thanos-compact container only
if c.name == 'thanos-compact' then c {
env+: s3EnvVars,
// Temporary workaround on high cardinality blocks for 2w.
// Since we have only 2w retention, there is no point in having 2w blocks.
// See: https://issues.redhat.com/browse/OBS-437
args+: ['--debug.max-compaction-level=3'] + disableDownsamplingFlag,
} else c
for c in super.containers
],
},
},
},
} + oauth.statefulSet,
},
rule+:: {
service+: ruleSyncerSidecar.service,
serviceMonitor+: ruleSyncerSidecar.serviceMonitor,
statefulSet+: jaegerAgentSidecar.statefulSet + ruleSyncerSidecar.statefulSet {
spec+: {
replicas: '${{THANOS_RULER_REPLICAS}}',
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-rule' then c {
env+: s3EnvVars,
volumeMounts+: [{
name: ruleSyncerVolume,
mountPath: '/etc/thanos/rules/rule-syncer',
}],
readinessProbe+: {
failureThreshold: 3,
periodSeconds: 180,
initialDelaySeconds: 60,
},
livenessProbe+: {
failureThreshold: 10,
periodSeconds: 120,
},
} else c
for c in super.containers
],
},
},
},
},
},
metricFederationRule+:: {
statefulSet+: jaegerAgentSidecar.statefulSet {
spec+: {
replicas: '${{THANOS_RULER_REPLICAS}}',
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-rule' then c {
env+: s3EnvVars,
} else c
for c in super.containers
],
},
},
},
},
},
stores+:: {
shards:
std.mapWithKey(function(shard, obj) obj { // loops over each [shard-n]:obj
statefulSet+: jaegerAgentSidecar.statefulSet {
spec+: {
replicas: '${{THANOS_STORE_REPLICAS}}',
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-store' then c {
env+: s3EnvVars,
args+: [
'--store.grpc.touched-series-limit=${THANOS_STORE_SERIES_TOUCHED_LIMIT}',
'--store.grpc.series-sample-limit=${THANOS_STORE_SERIES_SAMPLE_LIMIT}',
'--max-time=${THANOS_STORE_MAX_TIME}',
],
} else c
for c in super.containers
],
},
},
},
},
}, super.shards),
},
receiveController+:: {
deployment+: {
spec+: {
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-receive-controller' then c {
securityContext: {},
} else c
for c in super.containers
],
},
},
},
},
},
storeIndexCache+:: {
statefulSet+: {
spec+: {
template+: {
spec+: {
securityContext: {},
},
},
replicas: '${{THANOS_STORE_INDEX_CACHE_REPLICAS}}',
volumeClaimTemplates:: null,
},
},
},
storeBucketCache+:: {
statefulSet+: {
spec+: {
template+: {
spec+: {
securityContext: {},
},
},
replicas: '${{THANOS_STORE_BUCKET_CACHE_REPLICAS}}',
volumeClaimTemplates:: null,
},
},
},
query+:: {
local query = self,
local oauth = oauthProxy({
name: 'query',
image: '${OAUTH_PROXY_IMAGE}:${OAUTH_PROXY_IMAGE_TAG}',
upstream: 'http://localhost:9090',
ports: { https: 9091 },
serviceAccountName: thanos.config.serviceAccountName,
sessionSecretName: 'query-proxy',
resources: {
requests: {
cpu: '${OAUTH_PROXY_CPU_REQUEST}',
memory: '${OAUTH_PROXY_MEMORY_REQUEST}',
},
limits: {
cpu: '${OAUTH_PROXY_CPU_LIMITS}',
memory: '${OAUTH_PROXY_MEMORY_LIMITS}',
},
},
}),
proxySecret: oauth.proxySecret {
metadata+: { labels+: query.config.commonLabels },
},
service+: oauth.service,
deployment+: oauth.deployment + jaegerAgentSidecar.deployment {
spec+: {
replicas: '${{THANOS_QUERIER_REPLICAS}}',
securityContext: {},
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-query' then c {
args+: [
'--grpc.proxy-strategy=${THANOS_QUERIER_PROXY_STRATEGY}',
'--query.promql-engine=${THANOS_QUERIER_ENGINE}',
'--query.max-concurrent=${THANOS_QUERIER_MAX_CONCURRENT}',
],
} else c
for c in super.containers
],
},
},
},
},
},
rulerQuery+:: {
local query = self,
local oauth = oauthProxy({
name: 'query',
image: '${OAUTH_PROXY_IMAGE}:${OAUTH_PROXY_IMAGE_TAG}',
upstream: 'http://localhost:9090',
ports: { https: 9091 },
serviceAccountName: thanos.config.serviceAccountName,
sessionSecretName: 'query-proxy',
resources: {
requests: {
cpu: '${OAUTH_PROXY_CPU_REQUEST}',
memory: '${OAUTH_PROXY_MEMORY_REQUEST}',
},
limits: {
cpu: '${OAUTH_PROXY_CPU_LIMITS}',
memory: '${OAUTH_PROXY_MEMORY_LIMITS}',
},
},
}),
proxySecret: oauth.proxySecret {
metadata+: { labels+: query.config.commonLabels },
},
service+: oauth.service,
deployment+: oauth.deployment + jaegerAgentSidecar.deployment {
spec+: {
replicas: '${{THANOS_RULER_QUERIER_REPLICAS}}',
securityContext: {},
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-query' then c {
args+: [
'--grpc.proxy-strategy=${THANOS_RULER_QUERIER_PROXY_STRATEGY}',
'--query.promql-engine=${THANOS_RULER_QUERIER_ENGINE}',
'--query.max-concurrent=${THANOS_RULER_QUERIER_MAX_CONCURRENT}',
],
} else c
for c in super.containers
],
},
},
},
},
},
volcanoQuery+:: {
local query = self,
local oauth = oauthProxy({
name: 'query',
image: '${OAUTH_PROXY_IMAGE}:${OAUTH_PROXY_IMAGE_TAG}',
upstream: 'http://localhost:9090',
ports: { https: 9091 },
serviceAccountName: thanos.config.serviceAccountName,
sessionSecretName: 'query-proxy',
resources: {
requests: {
cpu: '${OAUTH_PROXY_CPU_REQUEST}',
memory: '${OAUTH_PROXY_MEMORY_REQUEST}',
},
limits: {
cpu: '${OAUTH_PROXY_CPU_LIMITS}',
memory: '${OAUTH_PROXY_MEMORY_LIMITS}',
},
},
}),
proxySecret: oauth.proxySecret {
metadata+: { labels+: query.config.commonLabels },
},
service+: oauth.service,
deployment+: oauth.deployment + jaegerAgentSidecar.deployment {
spec+: {
securityContext: {},
template+: {
spec+: {
securityContext: {},
},
},
},
},
},
queryFrontendCache+:: {
statefulSet+: {
spec+: {
template+: {
spec+: {
securityContext: {},
},
},
volumeClaimTemplates:: null,
},
},
},
queryFrontend+:: {
local queryFrontend = self,
local oauth = oauthProxy({
name: 'query-frontend',
image: '${OAUTH_PROXY_IMAGE}:${OAUTH_PROXY_IMAGE_TAG}',
upstream: 'http://localhost:9090',
ports: { https: 9091 },
serviceAccountName: thanos.config.serviceAccountName,
sessionSecretName: 'query-frontend-proxy',
resources: {
requests: {
cpu: '${OAUTH_PROXY_CPU_REQUEST}',
memory: '${OAUTH_PROXY_MEMORY_REQUEST}',
},
limits: {
cpu: '${OAUTH_PROXY_CPU_LIMITS}',
memory: '${OAUTH_PROXY_MEMORY_LIMITS}',
},
},
}),
proxySecret: oauth.proxySecret {
metadata+: { labels+: queryFrontend.config.commonLabels },
},
service+: oauth.service,
deployment+: {
spec+: {
replicas: '${{THANOS_QUERY_FRONTEND_REPLICAS}}',
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-query-frontend' then c {
args: std.filter(function(arg)
!std.member([
'--query-range.split-interval',
'--query-range.max-retries-per-request',
'--labels.split-interval',
'--labels.max-retries-per-request',
'--labels.default-time-range',
'--cache-compression-type',
], std.split(arg, '=')[0]), super.args)
+ [
'--query-range.split-interval=%s' % '${THANOS_QUERY_FRONTEND_SPLIT_INTERVAL}',
'--labels.split-interval=%s' % '${THANOS_QUERY_FRONTEND_SPLIT_INTERVAL}',
'--query-range.max-retries-per-request=%s' % '${THANOS_QUERY_FRONTEND_MAX_RETRIES}',
'--labels.max-retries-per-request=%s' % '${THANOS_QUERY_FRONTEND_MAX_RETRIES}',
'--labels.default-time-range=336h',
'--cache-compression-type=snappy',
],
} else c
for c in super.containers
],
},
},
},
} + oauth.deployment + jaegerAgentSidecar.deployment,
},
receivers+:: {
hashrings:
std.mapWithKey(function(hashring, obj) obj { // loops over each [hashring]:obj
statefulSet+: jaegerAgentSidecar.statefulSet {
spec+: {
podManagementPolicy: 'Parallel',
replicas: '${{THANOS_RECEIVE_REPLICAS}}',
template+: {
spec+: {
securityContext: {},
containers: [
if c.name == 'thanos-receive' then c {
args+: [
'--receive.default-tenant-id=FB870BF3-9F3A-44FF-9BF7-D7A047A52F43',
'--receive.grpc-compression=none',
'--receive.hashrings-algorithm=${THANOS_RECEIVE_HASHRINGS_ALGORITHM}',
'--receive.hashrings-file-refresh-interval=5s',
'--store.limits.request-series=${THANOS_RECEIVE_REQUEST_SERIES_LIMIT}',
'--store.limits.request-samples=${THANOS_RECEIVE_REQUEST_SAMPLES_LIMIT}',
],
env+: s3EnvVars + [{
name: 'DEBUG',
value: '${THANOS_RECEIVE_DEBUG_ENV}',
}],
readinessProbe+: {
failureThreshold: 20,
periodSeconds: 30,
initialDelaySeconds: 60,
},
} + {
args: [
if std.startsWith(a, '--tsdb.path') then '--tsdb.path=${THANOS_RECEIVE_TSDB_PATH}'
else if std.startsWith(a, '--tsdb.retention') then '--tsdb.retention=${THANOS_RECEIVE_TSDB_RETENTION}' else a
for a in super.args
],
} else c
for c in super.containers
],
},
},
},
},
}, super.hashrings),
},
},
} + {
thanos+:: {
[name]+: {
serviceMonitor+: {
metadata+: {
labels+: {
prometheus: 'app-sre',
'app.kubernetes.io/version':: 'hidden',
},
},
spec+: {
namespaceSelector: {
// NOTICE:
// When using the ${{PARAMETER_NAME}} syntax only a single parameter reference is allowed and leading/trailing characters are not permitted.
// The resulting value will be unquoted unless, after substitution is performed, the result is not a valid json object.
// If the result is not a valid json value, the resulting value will be quoted and treated as a standard string.
matchNames: '${{NAMESPACES}}',
},
selector+: { matchLabels+: { 'app.kubernetes.io/version':: 'hidden' } },
},
},
}
for name in std.objectFieldsAll(super.thanos)
if std.objectHas(super.thanos[name], 'serviceMonitor')
},
}