Trouble getting field to propagate down

[jszwedko]

Hi all,

I'm having trouble getting a field to propagate down through my types.

I've stripped down the cue example to:

installation: {
	#OperatingSystem: {
		interfaces: [installation.#Interface & {_shell: shell}, ...installation.#Interface & {_shell: shell}]
		name:  string
		shell: string
	}

	#OperatingSystems: [Name=string]: #OperatingSystem & {
		name: Name
	}

	operating_systems: #OperatingSystems
}

installation: {
	#Commands: {
		{[Name=string]: string | null}
	} & {
		_config_path: string | *null
		let ConfigPath = _config_path

		_shell: string | *null
		let Shell = _shell

		configure: string | null | *"none"

		if Shell == "bash" {
			configure: string | *#"""
					cat <<-'VECTORCFG' > \#(ConfigPath)
					{config}
					VECTORCFG
					"""#
		}

		if Shell == "powershell" {
			configure: string | *#"""
					@"
					{config}
					"@ | Out-File -FilePath \#(ConfigPath)
					"""#
		}
	}

	#Interface: {
		_shell: string | *null
		let Shell = _shell

		paths: {
			bin:         string | null
			bin_in_path: bool | null
			config:      string | null
		}
		role_implementations: #RoleImplementations & {_shell: Shell}
		name:                 string
	}

	#Interfaces: [Name=string]: #Interface & {
		name: Name
	}

	#RoleImplementation: {
		_shell: string | *null
		let Shell = _shell
		commands:  #Commands & {_shell: Shell}
		name:      string
		tutorials: #Tutorials
	}

	#RoleImplementations: [Name=string]: #RoleImplementation & {
		name: Name
	}

	#Tutorials: {
		installation: [...{
			title:   string
			command: string
		}]
	}

	_interfaces: #Interfaces
}

installation: operating_systems: ubuntu: {
	interfaces: [
		installation._interfaces.apt,
	]

	shell: "bash"
}

installation: _interfaces: apt: {
	paths: {
		bin:         "/usr/bin/vector"
		bin_in_path: true
		config:      "/etc/vector/vector.{config_format}"
	}

	role_implementations: [string]: {
		commands: {
			_config_path: paths.config
		}
		tutorials: {
			installation: [
				{
					title:   "Configure Vector"
					command: commands.configure
				},
			]
		}
	}

	role_implementations: {
		agent: {}
	}
}

The full cue config is over here: https://github.com/timberio/vector/tree/master/docs

With the above example, cue export gives me:

{
    "installation": {
        "operating_systems": {
            "ubuntu": {
                "interfaces": [
                    {
                        "paths": {
                            "bin": "/usr/bin/vector",
                            "bin_in_path": true,
                            "config": "/etc/vector/vector.{config_format}"
                        },
                        "role_implementations": {
                            "agent": {
                                "commands": {
                                    "configure": "none"
                                },
                                "name": "agent",
                                "tutorials": {
                                    "installation": [
                                        {
                                            "title": "Configure Vector",
                                            "command": "none"
                                        }
                                    ]
                                }
                            }
                        },
                        "name": "apt"
                    }
                ],
                "name": "ubuntu",
                "shell": "bash"
            }
        }
    }
}

The issue is that the shell set in OperatingSystem isn't making it all the way down to Command so configure is not correctly set (it defaults to none). Ideally that none default wouldn't even be there, but it complains about incomplete types if I remove it (which make sense).

I'm fairly new new to cue so I'm guessing I'm missing something. Any pointers would be appreciated!

[mpvl]

The issue is that installation._interfaces.apt in itself doesn't set the shell, but rather just the agent.

At the same time, the bash shell is passed down from #Interface into #RoleImplementations, but not from there into #RoleImplementation, from which apt is defined. Doing so will fix it:

	#RoleImplementations: {
		X=_shell:      _
		[Name=string]: #RoleImplementation & {
			name:   Name
			_shell: X
		}
	}

or using v0.4.0 CUE:

	#RoleImplementations: X={
		[Name=string]: #RoleImplementation & {
			name:   Name
			_shell: X._shell
		}
	}

[mpvl]

BTW, I noticed that there is a regression that broke the -H flag. The problem would have been easy to spot using cue eval -H, but that didn't work here because the flag was broken. I'll send a fix for that.

[mpvl]

BTW, you could also avoid having to "pass down" values too much by using nested definitions. The following will yield the same results:

installation: {
	#OperatingSystem: {
		interfaces: [...installation.#Interface & {_shell: shell}]
		interfaces: [_]
		name:  string
		shell: string
	}

	#OperatingSystems: [Name=string]: #OperatingSystem & {
		name: Name
	}

	operating_systems: #OperatingSystems
}

installation: {
	#Interface: {
		_shell: string | *null

		paths: {
			bin:         string | null
			bin_in_path: bool | null
			config:      string | null
		}

		role_implementations: #RoleImplementations
		name:                 string

		#RoleImplementations: [Name=string]: #RoleImplementation & {
			name: Name
		}

		#RoleImplementation: {
			commands:  #Commands
			name:      string
			tutorials: #Tutorials
		}

		#Commands: {
			configure: string | *null

			if _shell == "bash" {
				configure: string | *#"""
					cat <<-'VECTORCFG' > \#(paths.config)
					{config}
					VECTORCFG
					"""#
			}

			if _shell == "powershell" {
				configure: string | *#"""
					@"
					{config}
					"@ | Out-File -FilePath \#(paths.config)
					"""#
			}
		}
	}

	#Interfaces: [Name=string]: #Interface & {
		name: Name
	}

	#Tutorials: {
		installation: [...{
			title:   string
			command: string
		}]
	}

	_interfaces: #Interfaces
}

installation: operating_systems: ubuntu: {
	interfaces: [
		installation._interfaces.apt,
	]

	shell: "bash"
}

installation: _interfaces: apt: {
	paths: {
		bin:         "/usr/bin/vector"
		bin_in_path: true
		config:      "/etc/vector/vector.{config_format}"
	}

	role_implementations: [string]: {
		commands: {}
		tutorials: installation: [{
			title:   "Configure Vector"
			command: commands.configure
		}]
	}

	role_implementations: agent: {}
}

[jszwedko]

Thanks @mpvl ! The nested definitions make this much cleaner. Thanks for the suggestion! I was able to get it working following this as a guide.

It resulted in vectordotdev/vector#7498 if you are curious.

[cueckoo]

This discussion has been migrated to cue-lang/cue#975.

For more details about CUE's migration to a new home, please see cue-lang/cue#1078.