Placeholder Definition

Placeholder Definition

⚠️⚠️ THIS WIKI IS BEING USED TO JOT DOWN IDEAS AT PRESENT. DON'T ASSUME ANYTHING IS FIXED. ⚠️⚠️

A treacle place holder has the following form:

{{ source < arg1,arg2,argN > filter1 < arg1,arg2,argN > filterN < arg1,argN }}

or

{{ source: arg1,arg2,argN | filter1: arg1,arg2,argN | filterN: arg1,argN }}

in BNF:

<placeholder>           ::= "{{" <source> [ <filter-chain> ] "}}" 
<source>                ::= <variable> | <command> | <string-literal>
<filter-chain>          ::= <filter-pipe> <filter-section> [ <filter-chain> ]
<filter-section>        ::= <filter> [ <args-pipe> <args> ]
<args>                  ::= <arg> [ "," <args> ]
<arg>                   ::= <literal-arg> | <placeholder>
<variable>              ::= <token>
<command>               ::= "@" <token> [ <args-pipe> <args> ]
<filter>                ::= <token>
<token>                 ::= <letter> [ <token-body> ]
<token-body>            ::= (<letter> | <digit> | "_" | "-") [ <token-body> ]
<literal-arg>           ::= <string-literal> | <integer-literal>
<integer-literal>       ::= [ <number-sign> ] <digits>
<number-sign>           ::= "+" | "-"
<digits>                ::= <digit> [ <digits> ]
<string-literal>        ::= <single-quoted-literal> | <double-quoted-literal>
<single-quoted-literal> ::= <single-quote> [ <escaped-text ] <single-quote>
<double-quoted-literal> ::= <double-quote> [ <escaped-text ] <double-quote>
<filter-pipe>           ::= ">" | "|"
<args-pipe>             ::= "<" | ":"
<escaped-text>          ::= (<non-escaping-char> | <escape-sequence>)
                              [ <escaped-text> ]
<escape-sequence>       ::= "\" <escaping-char>
<escaping-char>         ::= "\" | <single-quote> | <double-quote>
<non-escaping-char>     ::= Any character except an <escaping-char> or a
                            control character
<digit>                 ::= Any digit
<single-quote>          ::= "'"
<double-quote>          ::= """