Custom Controller Routing

[s0kil]

How do I create custom routing for CategoriesController or any other controller?

[s0kil]

Here are the HasPath and CanRoute instances for custom routing, they belong in the Web.Routes or Admin.Routes module

instance HasPath CategoriesController where
   pathTo CategoriesAction = "/categories"
   pathTo NewCategoryAction = "/category/new"
   pathTo CreateCategoryAction = "/category/create"
   pathTo ShowCategoryAction { categoryId } = "/category/" <> tshow categoryId
   pathTo EditCategoryAction { categoryId } = "/category/edit/" <> tshow categoryId
   pathTo UpdateCategoryAction { categoryId } = "/category/update/" <> tshow categoryId
   pathTo DeleteCategoryAction { categoryId } = "/category/delete/" <> tshow categoryId

instance CanRoute CategoriesController where
   parseRoute' = do
       let categories = do
           string "/categories"
           optional "/"
           endOfInput
           pure CategoriesAction

       let newCategory = do
           string "/category/new"
           optional "/"
           endOfInput
           pure NewCategoryAction

       let createCategory = do
           string "/category/create"
           optional "/"
           endOfInput
           pure CreateCategoryAction

       let showCategory = do
           string "/category/"
           categoryId <- parseId
           optional "/"
           endOfInput
           pure ShowCategoryAction { categoryId }

       let editCategory = do
           string "/category/edit/"
           categoryId <- parseId
           optional "/"
           endOfInput
           pure EditCategoryAction { categoryId }

       let updateCategory = do
           string "/category/update/"
           categoryId <- parseId
           optional "/"
           endOfInput
           pure UpdateCategoryAction { categoryId }

       let deleteCategory = do
           string "/category/delete/"
           categoryId <- parseId
           optional "/"
           endOfInput
           pure DeleteCategoryAction { categoryId }

       categories <|> newCategory <|> createCategory <|> showCategory <|> editCategory <|> updateCategory <|> deleteCategory

Keep in mind that functions such as formFor rely on AutoRoute for the Create and Update paths, so if you are using custom routing, make sure to also update formFor category [hsx||] to formFor' category (pathTo CreateCategoryAction) [hsx||] and formFor' category (pathTo $ UpdateCategoryAction (get #id category)) [hsx||] respectively.

Read more about custom routing here

[s0kil]

Q: How to create a route like this /categories/<category_id>/questions/<question_id>, Which will basically show all questions related to a category.

A: Add this to the instance CanRoute parseRoute'

let categoryQuestions = do
    string "/categories/"
    categoryId <- parseId
    string "/questions/"
    questionId <- parseId
    optional "/"
    endOfInput
    pure MyAction { categoryId, questionId }

And, this to the instance HashPath MyController

pathTo MyAction { categoryId, questionId } = "/categories/" <> tshow categoryId <>  "/questions/" <> tshow questionId

[s0kil]

Here is also a demo project that showcases how to achieve custom routing with a one-to-many relationship.