build.gradle

buildscript {
    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
    }
    dependencies {
        classpath(libs.android.gradle)
        classpath(libs.kotlin.gradle)
        classpath(libs.kotlinx.binaryCompatibilityValidator)
    }
}

ext.projectVersions = [
    compileSdk: 34,
    minSdk: 21,
    targetSdk: 30,
]

apply plugin: 'binary-compatibility-validator'
apiValidation {
    ignoredProjects += ['xml-theme-demo']
}

ext {
    keystore = project.hasProperty('personalKeystore') ? personalKeystore : 'x'
    keystorePassword = project.hasProperty('personalKeystorePassword') ? personalKeystorePassword : 'x'
    keyAlias = project.hasProperty('personalKeyAlias') ? personalKeyAlias : 'x'
    keyPassword = project.hasProperty('personalKeyPassword') ? personalKeyPassword : 'x'
}

allprojects { project ->
    group = rootProject.property("GROUP")
    version = rootProject.property("VERSION_NAME")

    repositories {
        google()
        mavenCentral()
        gradlePluginPortal()
        maven { url = 'https://oss.sonatype.org/content/repositories/snapshots' }
    }

    project.configurations.all {
        // Don't cache snapshots:
        resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}