build.gradle

/*
 * Copyright (C) 2021 Emerson Pinter - All Rights Reserved
 */

buildscript {
    repositories {
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
}

plugins {
    id "application"
    id "java"
    id "org.sonarqube" version "5.0.0.4638"
}

group 'br.com.pinter.tqrespec'

apply from: "gradle/patchModulesJar.gradle"

import org.gradle.nativeplatform.platform.internal.DefaultNativePlatform

sourceSets {
    main.output.resourcesDir = main.java.classesDirectory.get()
}

OperatingSystem OS = DefaultNativePlatform.currentOperatingSystem
ext.distAppName = 'TQRespec'
version = '0.13.1'

application {
    mainClass = "br.com.pinter.tqrespec.Main"
}

java {
    sourceCompatibility = JavaVersion.VERSION_21
}

project.ext {
    moduleName = 'br.com.pinter.tqrespec'
    mainPackageName = 'br.com.pinter.tqrespec'
    javahome = System.getProperty("java.home")
    moduleInfoPresent = false
    osArch = System.getProperty("os.arch").toLowerCase()
    javafxSdkDir = file(String.format("%s/sdk/javafx-sdk-%s-%s-%s",
                                    projectDir, compileJava.javaCompiler.get().metadata.languageVersion,
                                    OS.toFamilyName().toLowerCase(), osArch))
    javafxSdkBinDir = file("${javafxSdkDir}/bin")
    javafxSdkLibDir = file("${javafxSdkDir}/lib")
    appArchiveOs = ""
    appArchiveArch = ""
    // toggle patch-jar feature, enable jpms on non-modular jars
    patchJars = true
    // directory for patched jars
    patchjarDir = layout.buildDirectory.dir('patchedjar').get().asFile.getPath()
    // modules dependencies to be passed to jdeps
    patchJarModuleDeps = [
        "com.google.guice": ["com.google.common", "aopalliance", "jakarta.inject"],
        "com.google.common": ["com.google.errorprone.annotations", "j2objc.annotations", "jsr305", "failureaccess"],
    ]
    //ignore dependencies when generating module-info for the given package
    //use only when all required deps are satisfied
    patchJarIgnoreMissingDeps = ["com.google.guice"]
}

if (file('src/main/java/module-info.java').exists()) {
    ext['moduleInfoPresent'] = true
}

if (!file(javafxSdkDir).directory) {
    throw new GradleException(String.format("ERROR: openjfx-sdk for java '%s' (%s) not found in %s", compileJava.javaCompiler.get().metadata.languageVersion, System.getProperty("os.arch"), javafxSdkDir))
}

if (project.hasProperty('buildVersion')) {
    project.version = project.properties.get("buildVersion")
}

if(!OS.isWindows()) {
    ext['appArchiveOs'] = String.format("-%s",OS.toFamilyName().toLowerCase())
}
if (osArch != "amd64") {
    ext['appArchiveArch'] = String.format("-%s",ext.osArch)
}

ext['appArchiveName'] = "${distAppName}-${project.version}${ext.appArchiveOs}${ext.appArchiveArch}.zip"

repositories {
    mavenCentral()
}

dependencies {
    implementation fileTree(dir: javafxSdkLibDir, include: [
                    'javafx.base.jar', 'javafx.controls.jar', 'javafx.fxml.jar', 'javafx.graphics.jar'])
    implementation 'com.google.inject:guice:7.0.0'
    implementation 'org.apache.commons:commons-lang3:3.14.0'
    implementation 'org.apache.commons:commons-text:1.12.0'
    implementation 'net.java.dev.jna:jna-platform-jpms:5.14.0'
    implementation 'com.fasterxml.jackson.core:jackson-core:2.17.1'
    implementation 'com.fasterxml.jackson.core:jackson-annotations:2.17.1'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.17.1'

    implementation project(':tqdatabase')

    testImplementation 'org.junit.jupiter:junit-jupiter-engine:5.11.0-M2'
    testImplementation 'org.mockito:mockito-core:5.11.0'
    testImplementation 'org.mockito:mockito-junit-jupiter:5.12.0'
    testImplementation 'com.google.inject:guice:7.0.0'
}

test {
    useJUnitPlatform()
    jvmArgs '--add-opens', 'java.base/java.lang=ALL-UNNAMED',
            '--add-opens', 'java.base/java.util.concurrent=ALL-UNNAMED',
            '--add-opens', 'java.base/java.io=ALL-UNNAMED',
            '--add-opens', 'java.base/java.nio=ALL-UNNAMED',
            '--add-opens', 'java.base/java.nio.file=ALL-UNNAMED',
            '--add-opens', 'java.logging/java.util.logging=ALL-UNNAMED'
}

if (OS.isWindows()) {
    ext.binjlink = javahome + "/bin/jlink.exe"
    ext.binjpackage = javahome + "/bin/jpackage.exe"
} else {
    ext.binjlink = javahome + "/bin/jlink"
    ext.binjpackage = javahome + "/bin/jpackage"
}

jar {
    //noinspection GroovyAssignabilityCheck
    manifest {
        attributes('Class-Path': configurations.runtimeClasspath.collect { it.getName() }.join(' '),
                'Implementation-Title': distAppName,
                'Implementation-Version': project.version,
                'Implementation-Vendor': 'Emerson Pinter',
                'Automatic-Module-Name': moduleName,
                'Main-Class': application.mainClass.get())
    }
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

tasks.register('copyMetaInf', Copy) {
    group = 'tqrespec'
    from fileTree(new File(sourceSets.main.output.resourcesDir, '/META-INF'))
    into sourceSets.main.java.classesDirectory.get().dir('/META-INF')
}

if (moduleInfoPresent) {
    compileJava {
        inputs.property("moduleName", moduleName)
        doFirst {
            options.compilerArgs = [
                    '--module-path', classpath.asPath,
            ]
            classpath = files()
        }
    }

    run {
        inputs.property("moduleName", moduleName)
        doFirst {
            jvmArgs = [
                    '-XX:+UseSerialGC',
                    '-Dguice_bytecode_gen_option=DISABLED',
                    '-XX:MinHeapFreeRatio=10', '-XX:MaxHeapFreeRatio=15',
                    '--module-path', classpath.asPath,
                    '--class-path', classpath.asPath,
                    '--module', moduleName,
            ] as List<String>
            classpath = files()
        }
    }
} else {
    run {
        doFirst {
            jvmArgs = [
                    '-XX:+UseSerialGC',
                    '-XX:MinHeapFreeRatio=10', '-XX:MaxHeapFreeRatio=15',
                    '--module-path', "${javafxSdkLibDir}",
                    '--add-modules', 'javafx.base,javafx.fxml,javafx.graphics,javafx.controls',
            ]
        }
    }
}

tasks.register('copyToLib', Copy) {
    group = 'tqrespec'
    doFirst {
        mkdir layout.buildDirectory.dir("jardist")
    }

    from(configurations.runtimeClasspath.findAll { !it.getName().toLowerCase().matches("javafx.*\\.jar") }).collect { it.getPath() }
    from jar
    into layout.buildDirectory.dir("jardist")
}

copyToLib.dependsOn(jar)
classes.dependsOn('copyMetaInf')

tasks.register('copyJarsToModuleDeps', Copy) {
    group = 'tqrespec'
    if (patchJars) {
        from project(':tqdatabase').configurations.compileClasspath
        from project.configurations.compileClasspath
        into patchjarDir
    }
}

tasks.register('patchModulesJar', PatchJarModuleTask) {
    group = 'tqrespec'
    dependsOn 'copyJarsToModuleDeps'
    dependsOn 'copyToLib'
    delete = true
    ignoreMissingDeps = patchJarIgnoreMissingDeps
    tempPatchDir = layout.buildDirectory.dir('temppatch').get().asFile.getPath()
    tempJarDir = patchjarDir
    moduleDeps = patchJarModuleDeps
    modulesDepsDir = layout.buildDirectory.dir("jardist").get().asFile
}

tasks.register('createDirs') {
    doLast {
        mkdir layout.buildDirectory.dir("appimage-files")
        mkdir layout.buildDirectory.dir("appimage-modules")
    }
}

tasks.register('copyAppimageModules', Copy) {
    duplicatesStrategy = DuplicatesStrategy.WARN
    group = 'tqrespec'
    dependsOn jar
    dependsOn 'tqdatabase:jar'
    if (patchJars) {
        dependsOn patchModulesJar
    }

    from tasks.jar.outputs.files.collect { it.getPath() }
    from configurations.runtimeClasspath.filter {
        !file(patchjarDir).listFiles().collect {p -> p.getName().toLowerCase()}.contains(it.getName().toLowerCase())
    }
    from project(':tqdatabase').tasks.jar.outputs.files.collect { it.getPath() }

    if (moduleInfoPresent && patchJars) {
        from patchjarDir
    }

    into layout.buildDirectory.dir("appimage-modules")
}

tasks.register('copyAppimageFiles') {
    group = 'tqrespec'
    dependsOn jar
    dependsOn 'tqdatabase:jar'
    dependsOn copyAppimageModules

    def excludeJars = new ArrayList<>()

    doFirst {
        excludeJars.addAll(configurations.runtimeClasspath.collect { x -> x.getName() })
    }

    doLast {
        copy {
            if (!moduleInfoPresent) {
                from project(':tqdatabase').tasks.jar.outputs.files.collect { it.getPath() }
                from jar
            }

            from configurations.runtimeClasspath.findAll {
                !excludeJars.contains(it.getName().toLowerCase())
            }.collect()

            into layout.buildDirectory.dir("appimage-files")
        }
    }
}

tasks.register('jlink', Exec) {
    group = 'tqrespec'
    dependsOn createDirs
    dependsOn 'copyAppimageFiles'
    workingDir layout.buildDirectory.get().asFile

    doFirst {
        if (moduleInfoPresent) {
            commandLine binjlink,
                    '-J-Djlink.debug=true',
                    '--module-path', layout.buildDirectory.dir("appimage-modules").get().asFile,
                    '--add-modules', "ALL-MODULE-PATH",
                    '--output', layout.buildDirectory.dir("jre-image").get().asFile,
                    '--compress', 'zip-6',
                    '--no-header-files',
                    '--no-man-pages',
                    '--strip-native-commands'
        } else {
            commandLine binjlink,
                    '--module-path', layout.buildDirectory.dir("appimage-modules").get().asFile,
                    '--add-modules', "ALL-MODULE-PATH",
                    '--output', layout.buildDirectory.dir("jre-image").get().asFile,
                    '--compress', 'zip-6',
                    '--no-header-files',
                    '--no-man-pages',
                    '--strip-native-commands'
        }
    }
}

tasks.register('archiveAppimage', Zip) {
    group = 'tqrespec'
    dependsOn clean
    dependsOn 'appimage'
    doLast {
        println("Creating archive '${appArchiveName}'")
    }
    from layout.buildDirectory.dir("app-image").get().asFile
    archiveFileName = appArchiveName
    destinationDirectory = layout.buildDirectory.get().asFile
}

tasks.register('appimage', Exec) {
    group = 'tqrespec'
    dependsOn clean
    dependsOn jlink
    workingDir layout.buildDirectory
    if (moduleInfoPresent) {
        commandLine binjpackage,
                '--type', 'app-image',
                '--verbose',
                '--runtime-image', layout.buildDirectory.dir("jre-image").get().asFile,
                '--module', "${moduleName}/${application.mainClass.get()}",
                '--dest', layout.buildDirectory.dir("app-image").get().asFile,
                '--name', distAppName,
                '--icon', "${projectDir}/src/main/resources/icon/icon64.ico",
                '--app-version', project.version,
                '--vendor', 'Emerson Pinter',
                '--input', layout.buildDirectory.dir("appimage-files").get().asFile,
                '--description', 'The respec tool for Titan Quest game',
                '--java-options',
                '-XX:+UseSerialGC ' +
                        '-Dguice_bytecode_gen_option=DISABLED ' +
                        '-XX:MinHeapFreeRatio=10 -XX:MaxHeapFreeRatio=15 '
    } else {
        commandLine binjpackage,
                '--type', 'app-image',
                '--verbose',
                '--runtime-image', layout.buildDirectory.dir("jre-image").get().asFile,
                '--dest', layout.buildDirectory.dir("app-image").get().asFile,
                '--name', distAppName,
                '--icon', "${projectDir}/src/main/resources/icon/icon64.ico",
                '--app-version', project.version,
                '--vendor', 'Emerson Pinter',
                '--input', layout.buildDirectory.dir("appimage-files").get().asFile,
                '--description', 'The respec tool for Titan Quest game',
                '--main-jar', jar.outputs.files.collect { it.getName() }.get(0),
                '--main-class', ${application.mainClass.get()},
                '--java-options',
                '-XX:+UseSerialGC ' +
                        '-Dguice_bytecode_gen_option=DISABLED ' +
                        '-XX:MinHeapFreeRatio=10 -XX:MaxHeapFreeRatio=15 ' +
                        '--add-opens javafx.base/com.sun.javafx.reflect=ALL-UNNAMED ' +
                        '--add-opens java.base/java.lang=ALL-UNNAMED '
    }
    doLast {
        copy {
            if (OS.isWindows()) {
                from javafxSdkBinDir.listFiles().findAll {
                    it.getName().equalsIgnoreCase("decora_sse.dll") ||
                    it.getName().equalsIgnoreCase("fxplugins.dll") ||
                    it.getName().equalsIgnoreCase("glass.dll") ||
                    it.getName().equalsIgnoreCase("javafx_font.dll") ||
                    it.getName().equalsIgnoreCase("javafx_iio.dll") ||
                    it.getName().equalsIgnoreCase("glib-lite.dll") ||
                    it.getName().equalsIgnoreCase("prism_common.dll") ||
                    it.getName().equalsIgnoreCase("prism_d3d.dll") ||
                    it.getName().equalsIgnoreCase("prism_sw.dll")
                }.collect()

                into layout.buildDirectory.dir("app-image/${distAppName}")
            } else {
                from javafxSdkLibDir.listFiles().findAll { it.getName().toLowerCase().endsWith('.so') }.collect()
                into layout.buildDirectory.dir("app-image/${distAppName}/lib/runtime/lib")
            }
        }

        copy {
            if (OS.isWindows()) {
                from javafxSdkBinDir.listFiles().findAll {
                    it.getName().equalsIgnoreCase("ucrtbase.dll") ||
                    it.getName().toLowerCase().startsWith("vcruntime") ||
                    it.getName().toLowerCase().startsWith("msvcp") ||
                    it.getName().toLowerCase().startsWith("api-ms-win-core") ||
                    it.getName().toLowerCase().startsWith("api-ms-win-crt")
                }.collect()

                into layout.buildDirectory.dir("app-image/${distAppName}/runtime/bin")
            }
        }

        copy {
            from "${projectDir}/README.md"
            into layout.buildDirectory.dir("app-image/${distAppName}")
        }
        copy {
            if (OS.isLinux()) {
                from "${projectDir}/src/dist/TQRespec.sh"
                into layout.buildDirectory.dir("app-image/${distAppName}")
            }
        }
        layout.buildDirectory.dir("app-image/${distAppName}/savedata").get().asFile.mkdir()
        layout.buildDirectory.dir("app-image/${distAppName}/gamedata").get().asFile.mkdir()
        layout.buildDirectory.dir("jre-image").get().asFile.deleteDir()
    }
}

clean.dependsOn subprojects.collect { it.tasks.matching { it.name == 'clean' } }