- fix for leak caused by ddc65a96fdb1163b
1 Deprecated and Removed Features
1.1 Clojure 1.5 reducers library requires Java 6 or later
2 New and Improved Features
2.1 Reducers
2.2 Reader Literals improved
2.3 clojure.core/set-agent-send-executor!, set-agent-send-off-executor!, and send-via
2.4 New threading macros
2.5 Column metadata captured by reader
2.6 gen-class improvements
2.7 Support added for marker protocols
2.8 clojure.pprint/print-table output compatible with Emacs Org mode
2.9 clojure.string/replace and replace-first handle special characters more predictably
2.10 Set and map constructor functions allow duplicates
2.11 More functions preserve metadata
2.12 New edn reader, improvements to *read-eval*
3 Performance Enhancements
4 Improved error messages
5 Improved documentation strings
6 Bug Fixes
7 Binary Compatibility Notes
The new reducers library (see below) requires Java 6 plus a ForkJoin library, or Java 7 or later. Clojure 1.5 can still be compiled and run with Java 5. The only limitations with Java 5 are that the new reducers library will not work, and building Clojure requires skipping the test suite (e.g. by using the command "ant jar").
Reducers provide a set of high performance functions for working with collections. The actual fold/reduce algorithms are specified via the collection being reduced. This allows each collection to define the most efficient way to reduce its contents.
The implementation details of reducers are available at the Clojure blog and therefore won't be repeated in these change notes. However, as a summary:
- There is a new namespace: clojure.core.reducers
- It contains new versions of map, filter etc based upon transforming reducing functions - reducers
- It contains a new function, fold, which is a parallel reduce+combine fold uses fork/join when working with (the existing!) Clojure vectors and maps
- Your new parallel code has exactly the same shape as your existing seq-based code
- The reducers are composable
- Reducer implementations are primarily functional - no iterators
- The model uses regular data structures, not 'parallel collections' or other OO malarkey
- It's fast, and can become faster still
- This is work-in-progress
Examples:
user=> (require '[clojure.core.reducers :as r])
user=> (reduce + (r/filter even? (r/map inc [1 1 1 2])))
;=> 6
;;red is a reducer awaiting a collection
user=> (def red (comp (r/filter even?) (r/map inc)))
user=> (reduce + (red [1 1 1 2]))
;=> 6
user=> (into #{} (r/filter even? (r/map inc [1 1 1 2])))
;=> #{2}
-
CLJ-1034 "Conflicting data-reader mapping" should no longer be thrown where there really isn't a conflict. Until this patch, having data_readers.clj on the classpath twice would cause the above exception.
-
CLJ-927 Added
*default-data-reader-fn*to clojure.core. When no data reader is found for a tag and*default-data-reader-fn*is non-nil, it will be called with two arguments, the tag and the value. If*default-data-reader-fn*is nil (the default), an exception will be thrown for the unknown tag.
Added two new functions:
-
clojure.core/set-agent-send-executor!
Allows the user to set the
java.util.concurrent.Executorused when callingclojure.core/send. Defaults to a fixed thread pool of size: (numCores + 2) -
clojure.core/set-agent-send-off-executor!
Allows the user to set the
java.util.concurrent.Executorused when callingclojure.core/send-off. Defaults to a cached thread pool. -
clojure.core/send-via
Like
send, andsend-off, except the first argument to this function is an executor to use when sending.
-
clojure.core/cond-> [expr & clauses]
Takes an expression and a set of test/form pairs. Threads the expression (via ->) through each form for which the corresponding test expression (not threaded) is true.
Example:
user=> (cond-> 1
true inc
false (* 42)
(= 2 2) (* 3))
6
-
clojure.core/cond->> [expr & clauses]
Takes an expression and a set of test/form pairs. Threads expr (via ->>) through each form for which the corresponding test expression (not threaded) is true.
Example:
user=> (def d [0 1 2 3])
#'user/d
user=> (cond->> d
true (map inc)
(seq? d) (map dec)
(= (count d) 4) (reduce +)) ;; no threading in the test expr
;; so d must be passed in explicitly
10
- clojure.core/as-> [expr name & forms]
Binds name to expr, evaluates the first form in the lexical context of that binding, then binds name to that result, repeating for each successive form
Note: this form does not actually perform any threading. Instead it allows the user to assign a name and lexical context to a value created by a parent threading form.
Example:
user=> (-> 84
(/ 4)
(as-> twenty-one ;; uses the value from ->
(* 2 twenty-one))) ;; no threading here
42
- clojure.core/some-> [expr & forms]
When expr is not nil, threads it into the first form (via ->), and when that result is not nil, through the next etc.
Example:
user=> (defn die [x] (assert false))
#'user/die
user=> (-> 1 inc range next next next die)
AssertionError Assert failed: false user/die (NO_SOURCE_FILE:65)
user=> (some-> 1 inc range next next next die)
nil
-
clojure.core/some->> [expr & forms]
When expr is not nil, threads it into the first form (via ->>), and when that result is not nil, through the next etc.
Same as some-> except the value is threaded as the last argument in each form.
- CLJ-960 Data read by the clojure reader is now tagged with :column in addition to :line.
- CLJ-745
It is now possible to expose protected final methods via
:exposes-methodsingen-class. This allows Clojure classes created via gen-class to access protected methods of its parent class.
Example:
(gen-class :name clojure.test_clojure.genclass.examples.ProtectedFinalTester
:extends java.lang.ClassLoader
:main false
:prefix "pf-"
:exposes-methods {findSystemClass superFindSystemClass})
- CLJ-948
It is now possible to annotate constructors via
gen-class.
Example:
(gen-class :name foo.Bar
:extends clojure.lang.Box
:constructors {^{Deprecated true} [Object] [Object]}
:init init
:prefix "foo")
- CLJ-966
defprotocolno longer requires that at least one method be given in the definition of the protocol. This allows for marker protocols, whose sole reason of existence is to allowsatisfies?to be true for a given type.
Example:
user=> (defprotocol P (hi [_]))
P
user=> (defprotocol M) ; marker protocol
M
user=> (deftype T [a] M P (hi [_] "hi there"))
user.T
user=> (satisfies? P (T. 1))
true
user=> (satisfies? M (T. 1))
true
user=> (hi (T. 1))
"hi there"
user=> (defprotocol M2 "marker for 2") ; marker protocol again
M2
user=> (extend-type T M2)
nil
user=> (satisfies? M2 (T. 1))
true
For the convenience of those that use Emacs Org mode,
clojure.pprint/print-table now prints tables in the form used by
that mode. Emacs Org mode has features to make it easy to edit such
tables, and even to do spreadsheet-like calculations on their
contents. See the Org mode documentation on
tables for details.
user=> (clojure.pprint/print-table [:name :initial-impression]
[{:name "Rich" :initial-impression "rock star"}
{:name "Andy" :initial-impression "engineer"}])
| :name | :initial-impression |
|-------+---------------------|
| Rich | rock star |
| Andy | engineer |
clojure.string/replace and clojure.string/replace-first are now
consistent in the way that they handle the replacement strings: all
characters in the replacement strings are treated literally, including
backslash and dollar sign characters.
user=> (require '[clojure.string :as s])
user=> (s/replace-first "munge.this" "." "$")
;=> "munge$this"
user=> (s/replace "/my/home/dir" #"/" (fn [s] "\\"))
;=> "\\my\\home\\dir"
There is one exception, which is described in the doc strings. If you
call these functions with a regex to search for and a string as the
replacement, then dollar sign and backslash characters in the
replacement string are treated specially. Occurrences of $1 in the
replacement string are replaced with the string that matched the first
parenthesized subexpression of the regex, occurrences of $2 are
replaced with the match of the second parenthesized subexpression,
etc.
user=> (s/replace "x12, b4" #"([a-z]+)([0-9]+)" "$1 <- $2")
;=> "x <- 12, b <- 4"
Individual occurrences of $ or \ in the replacement string that
you wish to be treated literally can be escaped by prefixing them with
a \. If you wish your replacement string to be treated literally
and its contents are unknown to you at compile time (or you don't wish
to tarnish your constant string with lots of backslashes), you can use
the new function clojure.string/re-quote-replacement to do the
necessary escaping of special characters for you.
user=> (s/replace "x12, b4" #"([a-z]+)([0-9]+)"
(s/re-quote-replacement "$1 <- $2"))
;=> "$1 <- $2, $1 <- $2"
All of the functions that construct sets such as set and
sorted-set allow duplicate elements to appear in their arguments,
and they are documented to treat this case as if by repeated uses of
conj.
Similarly, all map constructor functions such as hash-map,
array-map, and sorted-map allow duplicate keys, and are documented
to treat this case as if by repeated uses of assoc.
As before, literal sets, e.g. #{1 2 3}, do not allow duplicate
elements, and while elements can be expressions evaluated at run time
such as #{(inc x) (dec y)}, this leads to a check for duplicates at
run time whenever the set needs to be constructed, throwing an
exception if any duplicates are found.
Similarly, literal maps do not allow duplicate keys. New to Clojure 1.5 is a performance optimization: if all keys are compile time constants but one or more values are expressions requiring evaluation at run time, duplicate keys are checked for once at compile time only, not each time a map is constructed at run time.
- CLJ-1065 Allow duplicate set elements and map keys for all set and map constructors
Most functions that take a collection and return a "modified" version
of that collection preserve the metadata that was on the input
collection, e.g. conj, assoc, dissoc, etc. One notable
exception was into, which would return a collection with metadata
nil for several common types of input collections.
Now the functions into, select-keys, clojure.set/project, and
clojure.set/rename return collections with the same metadata as
their input collections.
The new clojure.edn namespace reads edn (http://edn-format.org) data,
and should be used for reading data from untrusted sources.
Clojure's core read* functions can evaluate code, and should not be
used to read data from untrusted sources. As of 1.5, *read-eval*
supports a documented set of thread-local bindings, see the doc string
for details.
*read-eval*'s default can be set to false by setting a system property:
-Dclojure.read.eval=false
- CLJ-988 Multimethod tables are now protected by a read/write lock instead of a synchronized method. This should result in a performance boost for multithreaded code using multimethods.
- CLJ-1061
when-firstnow evaluates its expression only once. - CLJ-1084
PersistentVector$ChunkedSeqnow implementsCountedinterface, to avoid some cases where vector elements were being counted by iterating over their elements. - CLJ-867 Records with same fields and field values, but different types, now usually hash to different values.
- CLJ-1000 Cache hasheq() for seqs, sets, vectors, maps and queues
- (no ticket) array-map perf tweaks
- CLJ-1111 Allows loop to evaluate to primitive values
- CLJ-103 Improved if-let error message when form has a improperly defined body.
- CLJ-897 Don't use destructuring in defrecord/deftype arglists to get a slightly better error message when forgetting to specify the fields vector
- CLJ-788 Add source and line members and getters to CompilerException
- CLJ-157 Better error messages for syntax errors w/ defn and fn
- CLJ-940 Passing a non-sequence to refer :only results in uninformative exception
- CLJ-1052
assocnow throws an exception if the last key argument is missing a value.
- CLJ-893 Document that vec will alias Java arrays
- CLJ-892 Clarify doc strings of sort and sort-by: they will modify Java array arguments
- CLJ-1019 ns-resolve doc has a typo
- CLJ-1038 Docstring for deliver doesn't match behavior
- CLJ-1055 "be come" should be "become"
- CLJ-917 clojure.core/definterface is not included in the API docs
- (no ticket) clojure.core/read, read-string, and read-eval all have more extensive documentation.
- CLJ-962 Vectors returned by subvec allow access at negative indices
- CLJ-952 bigdec does not properly convert a clojure.lang.BigInt
- CLJ-975 inconsistent destructuring behaviour when using nested maps
- CLJ-954 TAP support in clojure.test.tap Needs Updating
- CLJ-881 exception when cl-format is given some ~f directive/value combinations
- CLJ-763 Do not check for duplicates in destructuring map creation
- CLJ-667 Allow loops fully nested in catch/finally
- CLJ-768 cl-format bug in ~f formatting
- CLJ-844 NPE calling keyword on map from bean
- CLJ-934 disj! Throws exception when attempting to remove multiple items in one call
- CLJ-943 When load-lib fails, a namespace is still created
- CLJ-981 clojure.set/rename-keys deletes keys when there's a collision
- CLJ-961 with-redefs loses a Var's root binding if the Var is thread-bound
- CLJ-1032 seque leaks threads from the send-off pool
- CLJ-1041 reduce-kv on sorted maps should stop on seeing a Reduced value
- CLJ-1011 clojure.data/diff should cope with null and false values in maps
- CLJ-977 (int \a) returns a value, (long \a) throws an exception
- CLJ-964 test-clojure/rt.clj has undeclared dependency on clojure.set
- CLJ-923 Reading ratios prefixed by + is not working
- CLJ-1012 partial function should also accept 1 arg (just f)
- CLJ-932 contains? Should throw exception on non-keyed collections
- CLJ-730 Create test suite for functional fns (e.g. juxt, comp, partial, etc.)
- CLJ-757 Empty transient maps/sets return wrong value for .contains
- CLJ-828 clojure.core/bases returns a cons when passed a class and a Java array when passed an interface
- CLJ-1062 CLJ-940 breaks compilation of namespaces that don't have any public functions
- CLJ-1070 PersistentQueue's hash function does not match its equality
- CLJ-987 pprint doesn't flush the underlying stream
- CLJ-963 Support pretty printing namespace declarations under code-dispatch
- CLJ-902 doc macro broken for namespaces
- CLJ-909 Make LineNumberingPushbackReader's buffer size configurable
- CLJ-910 Allow for type-hinting the method receiver in memfn
- CLJ-1048 add test.generative to Clojure's tests
- CLJ-1071 ExceptionInfo does no abstraction
- CLJ-1085 clojure.main/repl unconditionally refers REPL utilities into
*ns* - (no ticket) Rich Hickey fix: syntax-quote was walking records, returning maps
- CLJ-1116 More REPL-friendly 'ns macro
- (no ticket) Rich Hickey fix: deref any j.u.c.Future
- CLJ-1092 New function re-quote-replacement has incorrect :added metadata
- CLJ-1098 Implement IKVReduce and CollFold for nil
- (no ticket) Rich Hickey fix: impose once semantics on fabricated closures for e.g. loops
- CLJ-1140 Restore {:as x} destructuring for empty lists
- CLJ-1150 Make some PersistentVector's and APersistentVector.SubVector's internals public
- (no ticket) Rich Hickey fix: use non-loading classForName
- CLJ-1106 Fixing set equality
public static inner class LispReader.ReaderException(int line, Throwable cause)Constructor changed toReaderException(int line, int column, Throwable cause)public Object clojure.lang.Agent.dispatch(IFn fn, ISeq args, boolean solo)Replaced withdispatch(IFn fn, ISeq args, Executor exec)
We have made all the changes, bug fixes, etc., listed above that are relevant to ClojureCLR, except for the change to use test.generative. The test.generative lib is used only in the test suite. We plan to make that change in the future when we have a more robust build system that facilitates pulling in clojure libs.
The new reducers library (see above) in ClojureCLR also has a version dependency. In .Net 4.0 and later, the fork/join capability required by the reducers library is implemented using System.Threading.Tasks.Task. in .Net 3.5 and earlier, we use our own minimal implmenentation of Task named clojure.lang.Task35 to provide the needed functionality for this use. This should be invisible to the user.
The build process has been cleaned up and enhancements made to allow builds to work using Mono.
We now allow type hints such as ^System.Double to work the same as ^double. This was required in order to allow extend-protocol to extend to primitive types. (And also to meet user expectations.)
Added clojure.lang.PushbackInputStream, parallel to clojure.lang.PushbackTextReader, corresponding to the difference between streams and readers.
- Updated arr with ^objects type information so the aget function will be properly resolved
- Make re-groups.direct (clojure.string) private
- Fix RT.nth problem with infinite LazySeqs
- Fix clojure.repl proxy of PushbackTextReader problem under .Net 4.5
- Add IDisposable type hint in with-open
- Handle the same type occurring in more than one assembly in RT.classForName
- Fix tag declarations in clojure.clr.io/Coercion
- Fix problem reading global keywords with namespace = :ns/name
- Fix generated code for volatile field references
- Do not look for embedded resources in dynamic assemblies
- CLJCLR-7 HostExpr does not support IntPtr and UIntPtr
- CLJCLR-8 Enhance compiler support for loading namespaces from .Net assemblies
- Convert assembly load methods to exceptions versus status return
- CLJCLR-14 ASP.NET apps cannot find .clj and .clj.dll files
- CLJCLR-15 Protected internal methods are not considered for overriding
- CLJCLR-4 Error running recursion example (Define missing RT.box needed in boxing let expressions)
- CLJCLR-9 Need better error message for clojure.core/cast
- Fix clojure.core/cast to properly handle nil, to match JVM version
- Fix bugs in io.clj and pprint.clj for the Clojure.Test project
- Fix the one buggy pprint test. Yay!
- Add primitive array types for sbyte, ushort, uint, ulong
1 Deprecated and Removed Features
1.1 Fields that Start With a Dash Can No Longer Be Accessed Using Dot Syntax
2 New/Improved Features
2.1 Reader Literals
2.2 clojure.core/mapv
2.3 clojure.core/filterv
2.4 clojure.core/ex-info and clojure.core/ex-data
2.5 clojure.core/reduce-kv
2.6 clojure.core/contains? Improved
2.7 clojure.core/min and clojure.core/max prefer NaN
2.8 clojure.java.io/as-file and clojure.java.io/as-url Handle URL-Escaping Better
2.9 New Dot Syntax for Record and Type Field Access
2.10 Record Factory Methods Available Inside defrecord
2.11 assert-args Displays Namespace and Line Number on Errors
2.12 File and Line Number Added to Earmuff Dynamic Warning
2.13 require Can Take a :refer Option
2.14 *compiler-options* Var
2.15 Improved Reporting of Invalid Characters in Unicode String Literals
2.16 clojure.core/hash No Longer Relies on .hashCode
2.17 Java 7 Documentation
2.18 loadLibrary Loads Library Using System ClassLoader
2.19 Java int is boxed as java.lang.Integer
3 Performance Enhancements
4 Bug Fixes
Clojure 1.4 introduces a field accessor syntax for the dot special form that aligns Clojure field lookup syntax with ClojureScript's.
For example, in Clojure 1.3, one can declare a record with a field starting with dash and access it like this:
(defrecord Bar [-a]) ;=> user.Bar
(.-a (Bar. 10)) ;=> 10
In 1.4, the above code results in IllegalArgumentException No matching field found: a for class user.Bar
However, the field may still be accessed as a keyword:
(:-a (Bar. 10)) ;=> 10
Clojure 1.4 supports reader literals, which are data structures tagged by a symbol to denote how they will be read.
When Clojure starts, it searches for files named data_readers.clj
at the root of the classpath. Each such file must contain a Clojure
map of symbols, like this:
{foo/bar my.project.foo/bar
foo/baz my.project/baz}
The key in each pair is a tag that will be recognized by the Clojure reader. The value in the pair is the fully-qualified name of a Var which will be invoked by the reader to parse the form following the tag. For example, given the data_readers.clj file above, the Clojure reader would parse this form:
#foo/bar [1 2 3]
by invoking the Var #'my.project.foo/bar on the vector [1 2 3]. The
data reader function is invoked on the form AFTER it has been read
as a normal Clojure data structure by the reader.
Reader tags without namespace qualifiers are reserved for Clojure. Default
reader tags are defined in clojure.core/default-data-readers but may be
overridden in data_readers.clj or by rebinding *data-readers*.
Clojure supports literals for instants in the form
#inst "yyyy-mm-ddThh:mm:ss.fff+hh:mm". These literals are parsed as java.util.Dates
by default. They can be parsed as java.util.Calendars or java.util.Timestamps
by binding *data-readers* to use clojure.instant/read-instant-calendar or
clojure.instant/read-instant-timestamp.
(def instant "#inst \"@2010-11-12T13:14:15.666\"")
; Instants are read as java.util.Date by default
(= java.util.Date (class (read-string instant)))
;=> true
; Instants can be read as java.util.Calendar or java.util.Timestamp
(binding [*data-readers* {'inst read-instant-calendar}]
(= java.util.Calendar (class (read-string instant))))
;=> true
(binding [*data-readers* {'inst read-instant-timestamp}]
(= java.util.Timestamp (class (read-string instant))))
;=> true
Clojure supports literals for UUIDs in the form #uuid "uuid-string". These
literals are parsed as java.util.UUIDs.
mapv takes a function f and one or more collections and returns a
vector consisting of the result of applying f to the set of first items of
each collection, followed by applying f to the set of second items in each
collection, until any one of the collections is exhausted. Any remaining
items in other collections are ignored. f should accept a number of arguments
equal to the number of collections.
(= [1 2 3] (mapv + [1 2 3]))
;=> true
(= [2 3 4] (mapv + [1 2 3] (repeat 1)))
;=> true
filterv takes a predicate pred and a collection and returns a vector
of the items in the collection for which (pred item) returns true. pred
must be free of side-effects.
(= [] (filterv even? [1 3 5]))
;=> true
(= [2 4] (filter even? [1 2 3 4 5]))
;=> true
ex-info creates an instance of ExceptionInfo. ExceptionInfo is a
RuntimeException subclass that takes a string msg and a map of data.
(ex-info "Invalid use of robots" {:robots false})
;=> #<ExceptionInfo clojure.lang.ExceptionInfo: Invalid use of robots {:robots false}>
ex-data is called with an exception and will retrieve that map of data
if the exception is an instance of ExceptionInfo.
(ex-data (ex-info "Invalid use of robots" {:robots false}))
;=> {:robots false}
reduce-kv reduces an associative collection. It takes a function f,
an initial value init and an associative collection coll. f should
be a function of 3 arguments. Returns the result of applying f to init,
the first key and the first value in coll, then applying f to that result
and the 2nd key and value, etc. If coll contains no entries, returns init
and f is not called. Note that reduce-kv is supported on vectors,
where the keys will be the ordinals.
(reduce-kv str "Hello " {:w \o :r \l :d \!})
;=> "Hello :rl:d!:wo"
(reduce-kv str "Hello " [\w \o \r \l \d \!])
;=> "Hello 0w1o2r3l4d5!"
contains? now works with java.util.Set.
min and max now give preference to returning NaN if either of their
arguments is NaN.
as-file and as-url now handle URL-escaping in both directions.
Clojure 1.4 introduces a field accessor syntax for the dot special form that aligns Clojure field lookup syntax with ClojureScript's.
In 1.4, to declare a record type and access its property x, one can
write:
(defrecord Foo [x]) ;=> user.Foo
(.-x (Foo. 10)) ;=> 10
This addition makes it easier to write code that will run as expected in both Clojure and ClojureScript.
Prior to 1.4, you could not use the factory functions (->RecordClass
and map->RecordClass) to construct a new record from inside a
defrecord definition.
The following example did not work prior to 1.4, but is now
valid. This example makes use of ->Mean which would have not yet
been available.
(defrecord Mean [last-winner]
Player
(choose [_] (if last-winner last-winner (random-choice)))
(update-strategy [_ me you] (->Mean (when (iwon? me you) me))))
assert-args now uses &form to report the namespace and line number where
macro syntax errors occur.
When a variable is defined using earmuffs but is not declared dynamic, Clojure emits a warning. That warning now includes the file and line number.
require can now take a :refer option. :refer takes a list of symbols
to refer from the namespace or :all to bring in all public vars.
The dynamic var *compiler-options* contains a map of options to send
to the Clojure compiler.
Supported options:
:elide-meta: Have certain metadata elided during compilation. This should be set to a collection of keywords.:disable-locals-clearing: Set to true to disable clearing. Useful for using a debugger.
The main function of the Clojure compiler sets the
*compiler-options* from properties prefixed by clojure.compiler,
e.g.
java -Dclojure.compiler.elide-meta='[:doc :file :line]'
When the reader finds an invalid character in a Unicode string literal, it now reports the character instead of its numerical representation.
hash no longer directly uses .hashCode() to return the hash of a Clojure
data structure. It calls clojure.lang.Util.hasheq, which has its own implementation
for Integer, Short, Byte, and Clojure collections. This ensures that the hash code
returned is consistent with =.
*core-java-api* will now return the URL for the Java 7 Javadoc when you are
running Java 7.
A static method, loadLibrary, was added to clojure.lang.RT to load a
library using the system ClassLoader instead of Clojure's class loader.
Java ints are now boxed as java.lang.Integers. See
the discussion on clojure-dev
for more information.
(= char char)is now optimizedequivis inlined in variadic =toStringcached on keywords and symbols- [CLR] Completely rewrote the code generation phase of the compiler
-
CLJ-829 Transient hashmaps mishandle hash collisions
-
CLJ-773 Macros that are expanded away still have their vars referenced in the emitted byte code
-
CLJ-837 java.lang.VerifyError when compiling deftype or defrecord with argument name starting with double underscore characters
-
CLJ-369 Check for invalid interface method names
-
CLJ-845 Unexpected interaction between protocol extension and namespaced method keyword/symbols
- Ignoring namespace portion of symbols used to name methods in extend-type and extend-protocol
-
CLJ-852 IllegalArgumentException thrown when defining a var whose value is calculated with a primitive fn
-
CLJ-855 catch receives a RuntimeException rather than the expected checked exception
-
CLJ-876 #^:dynamic vars declared in a nested form are not immediately dynamic
-
CLJ-886 java.io/do-copy can garble multibyte characters
-
CLJ-895 Collection.toArray implementations do not conform to Java API docs
- obey contract for toArray return type
-
CLJ-898 Agent sends consume heap
- Only capture a shallow copy of the current Frame in binding-conveyor-fn, so that sends in agent actions don't build infinite Frame stacks
-
CLJ-928 Instant literal for Date and Timestamp should print in UTC
-
CLJ-931 Syntactically broken clojure.test/are tests succeed
-
CLJ-933 Compiler warning on clojure.test-clojure.require-scratch
-
CLJCLR-??? Removed RhinoMocks dependency, get NUnit from NuGet, update tests
-
CLJCLR-??? Removed superfluous NUnit and RHino.Mocks license files
-
CLJCLR-??? Output compiled assemblies to current working directory.
-
CLJCLR-??? Restructured DLR conversion code, enabled generic method type inferencing
-
CLJCLR-??? Fixed one-off bug in arg gen in GenClass
-
CLJCLR-??? Extend conversions to IEnumerable, IList, IDictionary<K,V>
-
CLJCLR-??? Fixed a small bug in extended conversions
-
CLJCLR-??? Added assembly-load-with-partial-name
-
CLJCLR-??? Added |-escapting to print-dup on symbols
-
CLJCLR-??? Promoted fp-str to public
-
CLJCLR-??? Fix lookup for generic types
-
CLJCLR-??? Fix letfn init and bug in objmethod compile with primitive hint in params
-
CLJCLR-??? Make certain convert operations culture-invariant
-
CLJCLR-??? Make assemblies output from compiling respect compile-path
-
CLJCLR-??? Extend printf to handle DateTimeOffsets
-
CLJCLR-??? Fix printf handling of tz for DateTimeOffsets
-
CLJCLR-??? Fix infinite recursion on generic type lookup when type name is bad
- CLJCLR-??? Fix RT.nth problem with LazySeq
- CLJCLR-??? Fix with-open to include type hint for IDisposable before Dispose call
- CLJCLR-??? Fix clojure.repl proxy of PushbackTextREader problem under 4.5
1 Deprecated and Removed Features
1.1 Earmuffed Vars are No Longer Automatically Considered Dynamic
1.2 ISeq No Longer Inherits from Sequential
1.3 Removed Bit Operation Support for Boxed Numbers
1.4 Ancillary Namespaces No Longer Auto-Load on Startup
1.5 Replicate Deprecated
2 New/Improved Features
2.1 Enhanced Primitive Support
2.2 defrecord and deftype Improvements
2.3 Better Exception Reporting
2.4 clojure.reflect/reflect
2.5 clojure.data/diff
2.6 clojure.core/every-pred and clojure.core/some-fn Combinators
2.7 clojure.core/realized?
2.8 clojure.core/with-redefs-fn & with-redefs
2.9 clojure.core/find-keyword
2.10 clojure.repl/pst
2.11 clojure.pprint/print-table
2.12 pprint respects *print-length*
2.13 compilation and deployment via Maven
2.14 internal keyword map uses weak refs
2.15 ^:const defs
2.16 Message Bearing Assert
2.17 Error Checking for defmulti Options
2.18 Removed Checked Exceptions
2.19 vector-of Takes Multiple Arguments
2.20 deref with timeout
2.21 Walk Support for sorted-by Collections
2.22 string.join Enhanced to Work with Sets
2.23 clojure.test-helper
2.24 Newline outputs platform-specific newline sequence
2.25 init-proxy and update-proxy return proxy
2.26 doc & find-doc moved to REPL
2.27 clojure.java.shell/sh accepts as input anything that clojure.java.io/copy does
2.28 InterruptedHandler Promoted to clojure.repl
2.29 Add support for running -main namespaces from clojure.main
2.30 Set thread names on agent thread pools
2.31 Add docstring support to def
2.32 Comp function returns identity when called with zero arity
2.33 Type hints can be applied to arg vectors
2.34 Binding Conveyance
3 Performance Enhancements
4 Bug Fixes
5 Modular Contrib
(def *fred*)
=> Warning: *fred* not declared dynamic and thus is not dynamically rebindable, but its name suggests otherwise. Please either indicate ^:dynamic ** or change the name.
This allows ISeq implementers to be in the map or set equality partition.
Bit Operations map directly to primitive operations
The following namespaces are no longer loaded on startup: clojure.set, clojure.xml, clojure.zip
Use repeat instead.
Full details here:
Details here: Defrecord Improvements
Details here: Error Handling
Additionally:
Better error messages:
- When calling macros with arity
- For Invalid Map Literals
- For alias function if using unknown namespace
- In the REPL
- Add "starting at " to EOF while reading exceptions
- Better compilation error reporting
Full details here: Reflection API
Recursively compares a and b, returning a tuple of [things-only-in-a things-only-in-b things-in-both]
(diff {:a 1 :b 2} {:a 1 :b 22 :c 3})
=> ({:b 2} {:c 3, :b 22} {:a 1})
every-pred takes a set of predicates and returns a function f that returns true if all of its composing predicates return a logical true value against all of its arguments, else it returns false.
((every-pred even?) 2 4 6)
=> true
((every-pred even?) 2 4 5)
=>false
some-fn takes a set of predicates and returns a function f that returns the first logical true value returned by one of its composing predicates against any of its arguments, else it returns logical false.
((some-fn even?) 2 4 5)
=> true
((some-fn odd?) 2 4 6)
=> false
Returns true if a value has been produced for a promise, delay, future or lazy sequence.
(let [x (range 5)]
(println (realized? x))
(first x)
(println (realized? x)))
=> false
=> true
with-redefs-fn temporarily redefines Vars during a call to func. with-redefs temporarily redefines Vars while executing the body.
(with-redefs [nil? :temp] (println nil?))
=> :temp
Returns a Keyword with the given namespace and name if one already exists.
(find-keyword "def")
=> :def
(find-keyword "fred")
=> nil
Prints a stack trace of the exception
(pst (IllegalArgumentException.))
IllegalArgumentException
user/eval27 (NO_SOURCE_FILE:18)
clojure.lang.Compiler.eval (Compiler.java:6355)
clojure.lang.Compiler.eval (Compiler.java:6322)
clojure.core/eval (core.clj:2699)
clojure.main/repl/read-eval-print--5906 (main.clj:244)
clojure.main/repl/fn--5911 (main.clj:265)
clojure.main/repl (main.clj:265)
clojure.main/repl-opt (main.clj:331)
clojure.main/main (main.clj:427)
clojure.lang.Var.invoke (Var.java:397)
clojure.lang.Var.applyTo (Var.java:518)
clojure.main.main (main.java:37)
Prints a collection of maps in a textual table.
(print-table [:fred :barney]
[{:fred "ethel"}
{:fred "wilma" :barney "betty"}])
===============
:fred | :barney
===============
ethel |
wilma | betty
===============
Assigning *print-length* now affects output of pprint
See the following pages for more information:
^:const lets you name primitive values with speedier reference.
(def constants
{:pi 3.14
:e 2.71})
(def ^:const pi (:pi constants))
(def ^:const e (:e constants))
The overhead of looking up :e and :pi in the map happens at compile time, as (:pi constants) and (:e constants) are evaluated when their parent def forms are evaluated.
Assert can take a second argument which will be printed when the assert fails
(assert (= 1 2) "1 is not equal to 2")
=> AssertionError Assert failed: 1 is not equal to 2
defmulti will check to verify that its options are valid. For example, the following code will throw an exception:
(defmulti fred :ethel :lucy :ricky)
=> IllegalArgumentException
Clojure does not throw checked exceptions
vector-of takes multiple args used to populate the array
(vector-of :int 1 2 3)
=> [1 2 3]
deref now takes a timeout option - when given with a blocking reference, will return the timeout-val if the timeout (in milliseconds) is reached before value is available.
(deref (promise) 10 :ethel)
=> :ethel
Walk modified to work on sorted-by collections
let [x (sorted-set-by > 1 2 3)] (walk inc reverse x))
=> (2 3 4)
Just like join works on other collections
(join " and " #{:fred :ethel :lucy})
=> ":lucy and :fred and :ethel"
All test helpers moved into clojure.test-helper
Newline sequence is output as \r\n on Windows now.
Now you can chain calls on the proxy
Adds special form docs to the REPL
This adds InputStream, Reader, File, byte[] to the list of inputs for clojure.java.shell/sh
Promoting this library eliminates the need for a dependency on old contrib.
This patch allows clojure.main to accept an argument pointing to a namespace to look for a -main function in. This allows users to write -main functions that will work the same whether the code is AOT-compiled for use in an executable jar or just run from source.
It's a best practice to name the threads in an executor thread pool with a custom ThreadFactory so that the purpose of these threads is clear in thread dumps and other runtime operational tools.
Patch causes thread names like:
clojure-agent-send-pool-%d (should be fixed # of threads)
clojure-agent-send-off-pool-%d (will be added and removed over time)
A def can now have a docstring between name and value.
(def foo "a foo" :foo)
(= (comp) identity)
=> true
You can hint different arities separately:
(defn hinted
(^String [])
(^Integer [a])
(^java.util.List [a & args]))
This is preferred over hinting the function name. Hinting the function name is still allowed for backward compatibility, but will likely be deprecated in a future release.
Clojure APIs that pass work off to other threads (e.g. send, send-off, pmap, future) now convey the dynamic bindings of the calling thread:
(def ^:dynamic *num* 1)
(binding [*num* 2] (future (println *num*)))
;; prints "2", not "1"
- Code path for using vars is now much faster for the common case
- Improved startup time
- Fix performance on some numeric overloads See CLJ-380 for more information
- Promises are lock free
- Functions only get metadata support code when metadata explicitly supplied
- definterface/gen-interface accepts array type hints
- inline nil?
- inline bit-functions & math ops
- inline n-ary min & max
- PersistentQueue count is now O(1)
- Intrinsics: unchecked math operators now emit bytecodes directly where possible
Complete list of Tickets for 1.3 Release.
-
CLJ-8 detect and report cyclic load dependencies
- Patch restore detection of cyclic load dependencies
-
CLJ-31 compiler now correctly rejects attempts to recur across try (fn [x] (try (recur 1))) => CompilerException
-
CLJ-286 *out* being used as java.io.PrintWriter
- Patch fixes using Writer instead of PrintWriter
- fix clojure.main to not assume that err is a PrintWriter
-
CLJ-292 LazySeq.sval() nests RuntimeExceptions
- Patch causes only the original RuntimeException to be thrown
-
CLJ-390 sends from agent error-handlers should be allowed
- Patch allows agent error-handler to send successfully
-
CLJ-426 case should handle hash collision
- There were situations where a hash collision would occur with case and an exception would be thrown. See discussion for more details
-
CLJ-430 clojure.java.io URL Coercion throws java.lang.ClassCastException
- Patch correct exception to be thrown
-
CLJ-432 deftype does not work if containing ns contains dashes
- Patch munges namespaces with dashes properly
-
CLJ-433 munge should not munge $ (which isJavaIdentifierPart), should munge ' (which is not)
-
CLJ-435 stackoverflow exception in printing meta with :type
- Patch fixes exception being thrown on certain type metadata (with-meta {:value 2} {:type Object}) => No message. [Thrown class java.lang.StackOverflowError]
-
CLJ-437 Bugs in clojure.set/subset? and superset? for sets with false/nil elements
- Patch fixes failing on subset? and superset? for sets with false/nil elements
-
CLJ-439 Automatic type translation from Integer to Long
- Patch fixes increase coercion from Integer to Long
-
CLJ-444 Infinite recursion in Keyword.intern leads to stack overflow
- No more infinite recursion with patch
-
CLJ-673 use system class loader when base loader is null
- facilitates placing Clojure on bootclasspath
-
CLJ-678 into-array should work with all primitive types
-
CLJ-680 printing promises should not block
- Patch allows printing of promises without blocking
-
CLJ-682 cl-format: ~w throws an exception when not wrapped in a pretty-writer
- Patch fixes the following bug in cl-format with ~w:
-
CLJ-693 VerifyError with symbol metadata, macros, and defrecord
-
CLJ-702 case gives NPE when used with nil
- Patch allows nil to be used with case
-
CLJ-734 starting scope of let bindings seems incorrect from jdi perspective
- Patch fixes local variables table to have the correct code index for let bindings.
-
CLJ-739 version.properties file is not closed
- Patch properly closes version.properties file
-
CLJ-751 cl-format: ~( throws an exception with an empty string
- Patch fixes the following bug in cl-format when format is nil
(cl-format nil "~:(
a)" "") => NullPointerException
- Patch fixes the following bug in cl-format when format is nil
(cl-format nil "~:(
-
CLJ-780 race condition in reference cache on Java 5
- Map.Entry instances can have null values prior to Java 6. This patch provides a workaround.
-
floats were being boxed as Doubles, now they are boxed as Floats
-
several "holding onto head" fixes
- Stop top-level defs from hanging onto the head of an expression that uses a lazy seq
- Stop multimethods from holding onto heads of their arguments
In 1.3, the monolithic clojure-contrib.jar has been replaced by a modular system of contrib libraries, so that production systems can include only the code they actually need. This also allows individual contribs to have their own release cycles. Many contribs have moved forward by several point versions already. Documentation for updating applications to use the new contrib libraries is at http://dev.clojure.org/display/design/Where+Did+Clojure.Contrib+Go
Important Note: Many of the new modular contribs are compatible with both 1.2 and 1.3. This offers an incremental migration path: First, upgrade your contrib libraries while holding Clojure at 1.2, Then, in a separate step, upgrade to Clojure 1.3.