assignment operators (:=) with .esdl / REPL

[adehadd-aimgroup]

Hi there,

Was using the edgedb UI and was interested in the assignment operator (:=) used to capture the result and re-use the output for a subsequent operation.

We can see that in the example below where insert4 is reused in insert3

Schema

    type SensorType {
        required property name -> str;
        optional link brand -> SensorBrand;
    }

    type SensorBrand {
        required property name -> str;
    }

edgedb UI

insert4 :=
insert default::SensorBrand {
  name := <std::str>"Cool Sensor"
}
insert3 :=
insert default::SensorType {
  name := <std::str>"Data Logger",
  brand := insert4
}

But if I copy past this example into the REPL it doesn't let me assign the output to a variable.

Is there a possibility to use this method when writing queries?

[tailhook]

I'm not sure what magic UI does to make the above work. Here is how you should write the complete query instead:

WITH
  insert4 := insert default::SensorBrand {
    name := <std::str>"Cool Sensor"
  }

insert default::SensorType {
  name := <std::str>"Data Logger",
  brand := insert4
}

I.e you should use WITH to declare variables (views) before the query, and after the with block some query should happen. In my example it's the last insert, but you could use SELECT (insert4, insert3) instead.

[adehadd-aimgroup]

Awesome, thanks for this.

With your suggestion I was able to extend this to allow for more complex cases, by simply wrapping each insert statement itself in (), which better would allow me to copy the suggestion from the ui verbatim. (although for whatever reason I can't actually select the text in the UI, but I can work around that)

WITH insert4 := (insert default::SensorBrand {
    name := <std::str>"Cool Sensor4"
  }),
  insert5 := (insert default::SensorBrand {
    name := <std::str>"Cool Sensor5"
  }),

  insert6 := (insert default::SensorType {
    name := <std::str>"Data Logger2",
    brand := insert4
  }),
  insert7 := (insert default::SensorType {
    name := <std::str>"Data Logger3",
    brand := insert5
  })
select (insert4, insert5, insert6, insert7)