Added my 4 most useful functions to the libary.

Author: green-coder

.gitignore

@@ -0,0 +1,11 @@
+.cljs_node_repl/
+.cpcache/
+.idea/
+.nrepl-port
+*.iml
+node_modules
+out/
+*.jar
+pom.xml
+
+package-lock.json

bin/kaocha

@@ -0,0 +1,2 @@
+#!/usr/bin/env bash
+clojure -M:test -m kaocha.runner "$@"

deps.edn

@@ -0,0 +1,27 @@
+{:paths   ["src"]
+ :deps    {} ;; This part intentionally left blank
+ :aliases {:dev      {:extra-deps {org.clojure/clojure       {:mvn/version "1.10.3"}
+                                   org.clojure/clojurescript {:mvn/version "1.11.4"}}}
+           :test     {:extra-paths ["test"]
+                      :extra-deps  {lambdaisland/kaocha           {:mvn/version "1.63.998"}
+                                    lambdaisland/kaocha-cljs      {:mvn/version "1.0.107"}
+                                    lambdaisland/kaocha-junit-xml {:mvn/version "0.0.76"}
+                                    org.clojure/test.check        {:mvn/version "1.1.1"}}}
+
+           ; clojure -M:outdated --upgrade
+           :outdated {:extra-deps {com.github.liquidz/antq {:mvn/version "1.5.1"}}
+                      :main-opts  ["-m" "antq.core"]}
+
+           :depstar  {:replace-deps {com.github.seancorfield/depstar {:mvn/version "2.1.303"}}
+                      :exec-fn      hf.depstar/jar
+                      :exec-args    {:sync-pom    true
+                                     :group-id    "taipei.404"
+                                     :artifact-id "mate"
+                                     :version     "0.0.1"
+                                     :jar         "mate.jar"}}}}
+;; Memo for deploying a new release:
+;; - Change the version above, then build the jar:
+;;     clojure -X:depstar
+;; - add a tag "v0.x.y" to the latest commit and push to repo
+;; - deploy:
+;;     mvn deploy:deploy-file -Dfile=mate.jar -DpomFile=pom.xml -DrepositoryId=clojars -Durl=https://clojars.org/repo/

package.json

@@ -0,0 +1,6 @@
+{
+  "devDependencies": {
+    "isomorphic-ws": "^4.0.1",
+    "ws": "^7.0.1"
+  }
+}

src/mate/core.cljc

@@ -0,0 +1,46 @@
+(ns mate.core
+  #?(:cljs (:require-macros mate.core))
+  (:refer-clojure :exclude [group-by])
+  (:require [clojure.core :as cc]))
+
+(defn seq-indexed
+  "Returns an indexed sequence from the collection `coll`."
+  [coll]
+  (map-indexed vector coll))
+
+(defmacro comp->
+  "Same as `comp` but with the arguments in reverse order."
+  [& args]
+  `(comp ~@(reverse args)))
+
+(defn group-by
+  "Same as clojure.core/group-by, but with some handy new arities which apply
+   custom map & reduce operations to the elements grouped together under the same key."
+  ([kf coll]
+   ;(group-by kf identity conj [] coll)
+   (cc/group-by kf coll))
+  ([kf vf coll]
+   (group-by kf vf conj [] coll))
+  ([kf vf rf coll]
+   (group-by kf vf rf (rf) coll))
+  ([kf vf rf init coll]
+   (->> coll
+        (reduce (fn [ret x]
+                  (let [k (kf x)
+                        v (vf x)]
+                    (assoc! ret k (rf (get ret k init) v))))
+                (transient {}))
+        persistent!)))
+
+(defn index-by
+  "Returns a hashmap made of `[key value]` pairs from items in the collection `coll`
+   where the keys are `(kf item)` and the values are `(vf item)`.
+   `vf` defaults to the identify function."
+  ([kf coll]
+   (index-by kf identity coll))
+  ([kf vf coll]
+   (->> coll
+        (reduce (fn [ret x]
+                  (assoc! ret (kf x) (vf x)))
+                (transient {}))
+        persistent!)))

test/mate/core_test.cljc

@@ -0,0 +1,38 @@
+(ns mate.core-test
+  (:require [clojure.test :refer [deftest testing is are]]
+            [mate.core :as m]))
+
+(deftest seq-index-test
+  (is (= (m/seq-indexed [:a :a :b :a :b])
+         '([0 :a] [1 :a] [2 :b] [3 :a] [4 :b]))))
+
+(deftest comp->-test
+  (is (= ((m/comp-> inc str) 2) "3")))
+
+(deftest group-by-test
+  (let [coll [[:a 1] [:a 2] [:b 3] [:a 4] [:b 5]]]
+    (is (= (m/group-by first coll)
+           {:a [[:a 1] [:a 2] [:a 4]]
+            :b [[:b 3] [:b 5]]}))
+
+    (is (= (m/group-by first second coll)
+           {:a [1 2 4]
+            :b [3 5]}))
+
+    (is (= (m/group-by first second + coll)
+           {:a 7
+            :b 8}))
+
+    (is (= (m/group-by first second + 10 coll)
+           {:a 17
+            :b 18}))))
+
+(deftest index-by-test
+  (let [coll [[:a 1] [:a 2] [:b 3] [:a 4] [:b 5]]]
+    (is (= (m/index-by first coll)
+           {:a [:a 4]
+            :b [:b 5]}))
+
+    (is (= (m/index-by first second coll)
+           {:a 4
+            :b 5}))))

tests.edn

@@ -0,0 +1,5 @@
+#kaocha/v1
+{:tests [{:id   :unit
+          :type :kaocha.type/clojure.test}
+         {:id   :unit-cljs
+          :type :kaocha.type/cljs}]}