-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathbluelib.inc
1549 lines (1511 loc) · 43.5 KB
/
bluelib.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; bluelib.inc - GG/SMS project boilerplate and standard library.
; Latest revision: Spring 2017 for project astroswab.
; *****************************************************************************
; BASE LIBRARY
; *****************************************************************************
.equ ROMSIZE 256 ; Make a 128k or 256k rom.
.equ INCLUDE_VDP_INTERRUPT_HANDLER ; Comment out to exclude it.
.equ INCLUDE_PAUSE_BUTTON_HANDLER ; Comment out to exclude it.
; -----------------------------------------------------------------------------
; HARDWARE DEFINITIONS
; -----------------------------------------------------------------------------
; Video memory and initialization:
.equ NAME_TABLE_START $3800
.equ VISIBLE_NAME_TABLE_SIZE 2*32*24
.equ FULL_NAME_TABLE_SIZE 2*32*28
.equ SPRITE_BANK_START $2000
.equ BACKGROUND_BANK_START $0000
.equ SPRITE_PALETTE_START 16
.equ BACKGROUND_PALETTE_START 0
.equ SAT_Y_START $3f00
.equ SAT_XC_START SAT_Y_START+64+64
.equ SPRITE_TERMINATOR $d0
.equ NTSC 0
.equ PAL 1
.equ FIRST_LINE_OF_VBLANK 192
;
.equ REGISTER_0 0
.equ REGISTER_1 1
.equ REGISTER_2 2
.equ REGISTER_3 3
.equ REGISTER_4 4
.equ REGISTER_5 5
.equ REGISTER_6 6
.equ REGISTER_7 7
.equ REGISTER_8 8
.equ REGISTER_9 9
.equ REGISTER_10 10
.equ REGISTER_11 11
;
; Memory map and initialization:
.equ RAM_START $c000
.equ STACK_INIT_ADDRESS $dff0
; Port communication and control:
.equ SYSTEM_CONTROL_PORT $00 ; GG: start, region, ntsc/pal.
.equ START_BUTTON_BIT %10000000 ; 0 = Switch is on!
.equ INPUT_PORT_1 $dc
.equ INPUT_PORT_2 $dd
.equ PSG_PORT $7f
.equ V_COUNTER_PORT $7e
.equ CONTROL_PORT $BF
.equ DATA_PORT $BE
.equ VRAM_WRITE_COMMAND %01000000
.equ VRAM_READ_COMMAND %00000000
.equ REGISTER_WRITE_COMMAND %10000000
.equ CRAM_WRITE_COMMAND %11000000
; --- NB! Developed for GG -------------------
; Register 0 settings:
.equ SCROLL_0_LINE_0_SPRITES_0 %00000110
; Register 1 settings:
.equ DISPLAY_1_FRAME_1_SIZE_0 %11100000
.equ DISPLAY_0_FRAME_1_SIZE_0 %10100000
.equ DISPLAY_0_FRAME_0_SIZE_0 %10000000
.equ DISPLAY_1_FRAME_1_SIZE_0_ZOOM %11100001
; ---------------------------------------------
.equ SCROLL_0__LCB_1_LINE_0_SPRITES_0 %00100110
.equ SCROLL_0__LCB_0_LINE_0_SPRITES_0 %00000110
;
.equ HORIZONTAL_SCROLL_REGISTER 8
.equ VERTICAL_SCROLL_REGISTER 9
.equ RASTER_INTERRUPT_REGISTER 10
; Banks / ROM / External RAM control:
.equ SET_EXTRAM_BIT %00001000
.equ RESET_EXTRAM_BIT %11110111
.equ EXTRAM_START $8000
.equ EXTRAM_SIZE $4000
.equ SLOT_2_CONTROL $ffff
.equ BANK_CONTROL $fffc
; CRT screen values:
.equ CRT_LEFT_BORDER 0
.equ CRT_RIGHT_BORDER 255
.equ CRT_TOP_BORDER 0
.equ CRT_BOTTOM_BORDER 191
; LCD screen values:
.equ LCD_RIGHT_BORDER (6*8)+(20*8)
.equ LCD_LEFT_BORDER 6*8
.equ LCD_TOP_BORDER 3*8
.equ LCD_BOTTOM_BORDER (3*8)+(18*8)
.equ LCD_WIDTH 20*8
.equ LCD_HEIGHT 18*8
; Invisible area:
.equ INVISIBLE_AREA_TOP_BORDER 192
.equ INVISIBLE_AREA_BOTTOM_BORDER 224
; -----------------------------------------------------------------------------
; SOFTWARE DEFINITIONS
; -----------------------------------------------------------------------------
.equ TRUE $ff
.equ FALSE 0
.equ ENABLED $ff
.equ DISABLED 0
.equ FLAG_SET $ff
.equ FLAG_RESET $00
.equ PAUSE_FLAG_RESET $00
.equ PAUSE_FLAG_SET $ff
.equ UNUSED_BYTE $0
.equ UNUSED_WORD $0000
.equ PERCENT_CHANCE_50 128
.equ PERCENT_CHANCE_100 255
;
.equ BYTES_PER_TILE 32
.equ ONE_TILEMAP_ROW 32*2
.equ END_OF_TABLE $ff
; Font / printing support.
.equ CHARS_IN_ASCII_SET 91
.equ STRING_TERMINATOR 3 ; Terminate strings with #
.equ ASCII_ZERO 16 ; Where in the tilebank is the ASCII zero?
.equ ASCII_ONE 17
.equ ASCII_NINE ASCII_ZERO+9
.equ ASCII_SPACE 0
.equ ASCII_EXCLAMATION 1
.equ ASCII_TABLE_START 0
.asciitable
map " " to "z" = ASCII_TABLE_START
.enda
; =============================================================================
; M A C R O S
; =============================================================================
; -----------------------------------------------------------------------------
.macro SELECT_EXTRAM
; -----------------------------------------------------------------------------
; Select external RAM: Now memory addresses from $8000 - $c000 (slot 2)
; are mapped to the battery-backed RAM, and thus its contents are saved
; between sessions.
push af
ld a,(BANK_CONTROL)
or SET_EXTRAM_BIT
ld (BANK_CONTROL),a
pop af
.endm
; -----------------------------------------------------------------------------
.macro SELECT_ROM
; -----------------------------------------------------------------------------
; Select ROM: Used to switch mapping in slot 2 ($8000 - $c000) back to ROM
; if external RAM was selected.
push af
ld a,(BANK_CONTROL)
and RESET_EXTRAM_BIT
ld (BANK_CONTROL),a
pop af
.endm
; -----------------------------------------------------------------------------
.macro SELECT_BANK
; -----------------------------------------------------------------------------
; Select a bank for slot 2, i.e. SELECT_BANK 4.
push af
ld a,\1
ld (SLOT_2_CONTROL),a
pop af
.endm
; -----------------------------------------------------------------------------
.macro SELECT_BANK_IN_REGISTER_A
; -----------------------------------------------------------------------------
; Select a bank for slot 2, - put value in register A.
ld (SLOT_2_CONTROL),a
.endm
; -----------------------------------------------------------------------------
.macro SAVE_REGISTERS
; -----------------------------------------------------------------------------
; Save all registers, except IX and IY
push af
push bc
push de
push hl
push ix
push iy
.endm
; -----------------------------------------------------------------------------
.macro RESTORE_REGISTERS
; -----------------------------------------------------------------------------
; Restore all registers, except IX and IY
pop iy
pop ix
pop hl
pop de
pop bc
pop af
.endm
; -----------------------------------------------------------------------------
.memorymap
; -----------------------------------------------------------------------------
defaultslot 0
slotsize $4000
slot 0 $0000
slot 1 $4000
slot 2 $8000
slotsize $2000
slot 3 RAM_START
.endme
.if ROMSIZE == 128
.rombankmap ; 128K rom
bankstotal 8
banksize $4000
banks 8
.endro
.endif
.if ROMSIZE == 256
.rombankmap ; 256K rom
bankstotal 16
banksize $4000
banks 16
.endro
.endif
; -----------------------------------------------------------------------------
.ramsection "bluelib global variables" slot 3
; -----------------------------------------------------------------------------
VDPStatus db
pause_flag db
input_ports dw
tv_type db
;
.ends
.org 0
.bank 0 slot 0
; -----------------------------------------------------------------------------
.section "Boot" force
; -----------------------------------------------------------------------------
boot:
di
im 1
ld sp,STACK_INIT_ADDRESS
; Initialize the standard Sega mapper.
ld de,$fffc
ld hl,_MapperInitData
ld bc,$0004
ldir
call ClearRam ; Except the top (stack, slot/bank registers, etc.)
call ClearVRam
call detect_tv_type ; Beware! Messes with interrupts and vdp-registers.
ld (tv_type),a
call InitializeVDPRegisters
jp init
_MapperInitData:
.db $00,$00,$01,$02
.ends
.ifdef INCLUDE_VDP_INTERRUPT_HANDLER
.org $0038
; ---------------------------------------------------------------------------
.section "!VDP interrupt" force
; ---------------------------------------------------------------------------
push af
in a,CONTROL_PORT
ld (VDPStatus),a
pop af
ei
reti
.ends
.endif
.ifdef INCLUDE_PAUSE_BUTTON_HANDLER
.org $0066
; ---------------------------------------------------------------------------
.section "!Pause interrupt" force
; ---------------------------------------------------------------------------
push af
ld a,(pause_flag)
cpl
ld (pause_flag),a
pop af
retn
.ends
.endif
; =============================================================================
; H E L P E R F U N C T I O N S (sorted alphabetically)
; =============================================================================
; -----------------------------------------------------------------------------
.section "await_frame_interrupt" free
; -----------------------------------------------------------------------------
; Await frame interrupt.
; Repeatedly test bit 7 of VDPStatus until it is set (by the VDP interrupt
; handler). Then reset this bit and return.
; Entry: None
; Exit: Bit 7 of variable VDPStatus is cleared.
; Uses: VDPStatus (1 byte)
await_frame_interrupt:
push af
-:
ld a,(VDPStatus)
bit 7,a
jp z,-
in a,(V_COUNTER_PORT)
; Check this post: http://www.smspower.org/forums/8113-WaitForVBlankSlowerOnNTSCThanPALSystematicProblemWithWaitForVBlankNoInt
cp FIRST_LINE_OF_VBLANK+1
jp nz,-
res 7,a
ld (VDPStatus),a
pop af
ret
.ends
;
; -----------------------------------------------------------------------------
.section "hl_ (call hl)" free
; -----------------------------------------------------------------------------
hl_: ; "call _hl"
; Jump to where HL is pointing to. Assume it is a handler that ends in
; ret.
jp (hl)
.ends
;
; -----------------------------------------------------------------------------
.section "clear_extram" free
; -----------------------------------------------------------------------------
; Clear external ram by writing zeroes to all bytes.
; Uses AF, BC, HL
clear_extram:
SELECT_EXTRAM
ld bc,EXTRAM_SIZE ; Every byte in external ram.
ld hl,EXTRAM_START ; Begin from the first byte.
-:
xor a ; Write zeroes over all external ram bytes.
ld (hl),a
inc hl
dec bc
ld a,b
or c
jp nz,-
SELECT_ROM
ret
.ends
;
; -----------------------------------------------------------------------------
.section "ClearRam" free
; -----------------------------------------------------------------------------
; Overwrite ram with zeroes from RAM_START to STACK_INIT_ADDRESS - 16
; Uses AF, BC, DE, HL
ClearRam:
ld hl,RAM_START
ld bc,STACK_INIT_ADDRESS-16-RAM_START
ld a,0
call _FillMemory
ret
_FillMemory:
ld (hl),a
ld d,h
ld e,l
inc de
dec bc
ld a,b
or c
ret z
ldir
ret
.ends
;
; -----------------------------------------------------------------------------
.section "ClearVRam" free
; -----------------------------------------------------------------------------
; Write 00 to all vram positions. Assumes disabled display.
; Uses AF, BC
ClearVRam:
xor a
out (CONTROL_PORT),a
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
ld bc,$4000 ; 16K
-:
xor a
out (DATA_PORT),a
dec bc
ld a,b
or c
jp nz,-
ret
.ends
;
; -----------------------------------------------------------------------------
.section "convert_byte" free
; -----------------------------------------------------------------------------
convert_byte:
; Convert a byte passed in A to a value from a specified conversion table.
; Entry: A = Byte-sized value to convert.
; B = Values in conversion table (failsafe).
; HL = Ptr to conversion table (value, converted value, value etc..)
; Exit: A = result of conversion (if matching value found in table).
; Carry flag set if no matching value found in table.
; Uses: AF, BC, HL
-:
ld c,(hl)
cp c
inc hl
jp nz,+
ld a,(hl)
ret
+:
inc hl
djnz -
scf
ret
.ends
;
; -----------------------------------------------------------------------------
.section "cp_word" free
; -----------------------------------------------------------------------------
cp_word:
; Compare a word-sized variable at HL to a word-sized value in DE.
; Entry: HL = Pointer to variable.
; BC = Value to compare.
; Exit: Zero flag is set/reset.
;
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
sbc hl,bc
ret
.ends
; -----------------------------------------------------------------------------
.section "detect_tv_type" free
; -----------------------------------------------------------------------------
detect_tv_type:
; Returns a=0 for NTSC, a=1 for PAL
; Uses: a, hl, de
; From SMS-Power!
di ; disable interrupts
ld a,%01100000 ; set VDP such that the screen is on
out ($bf),a ; with VBlank interrupts enabled
ld a,$81
out ($bf),a
ld hl,$0000 ; init counter
-: in a,($bf) ; get VDP status
or a ; inspect
jp p,- ; loop until frame interrupt flag is set
-: in a,($bf) ; do the same again, in case we were unlucky and came in just
or a ; before the start of the VBlank with the flag already set
jp p,-
; the VDP must now be at the start of the VBlank
-: inc hl ; (6 cycles) increment counter until interrupt flag comes on again
in a,($bf) ; (11 cycles)
or a ; (4 cycles)
jp p,- ; (10 cycles)
xor a ; reset carry flag, also set a=0
ld de,2048 ; see if hl is more or less than 2048
sbc hl,de
ret c ; if less, return a=0
ld a,1
ret ; if more or equal, return a=1
.ends
;
; -----------------------------------------------------------------------------
.section "fast_put_char" free
; -----------------------------------------------------------------------------
; Put one character on the nametable with minimum overhead.
; Entry: HL = Pointer to 4-byte table with char data, in this format:
; Address (word), char (byte), flags (byte)
; Exit: None
; Uses: AF, HL
.equ FAST_PUT_CHAR_OFFSET 2 ; Used to alter just the char being put.
fast_put_char:
ld a,(hl)
out (CONTROL_PORT),a
inc hl
ld a,(hl)
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
inc hl
ld a,(hl)
out (DATA_PORT),a
inc hl
ld a,(hl)
out (DATA_PORT),a ; Write 2nd byte to name table.
ret
.ends
;
; -----------------------------------------------------------------------------
.section "get_absolute_value" free
; -----------------------------------------------------------------------------
;
get_absolute_value:
;
bit 7,a
ret z
neg
ret
.ends
;
; -----------------------------------------------------------------------------
.section "get_byte_from_table" free
; -----------------------------------------------------------------------------
get_byte_from_table:
; Retrieve a byte item from a table of bytes.
; Entry: A = Index.
; HL = Base address of byte table (256 bytes).
; Exit: A = Byte item.
; Uses: None.
push hl
push de
;add a,a
ld d,0
ld e,a
add hl,de
ld a,(hl)
;inc hl
;ld h,(hl)
;ld l,a
pop de
pop hl
ret
;
.ends
;
; -----------------------------------------------------------------------------
.section "get_input_ports" free
; -----------------------------------------------------------------------------
; Set input_ports (word) to mirror current state of ports $dc and $dd.
; Uses: AF
get_input_ports:
in a,(INPUT_PORT_1)
ld (input_ports),a
in a,(INPUT_PORT_2)
ld (input_ports+1),a
ret
.ends
;
; -----------------------------------------------------------------------------
.section "get_word_from_table" free
; -----------------------------------------------------------------------------
get_word_from_table:
; Retrieve a word item from a table of words.
; Entry: A = Index.
; HL = Base address of word table. (128 words in table)
; Exit: HL = Word.
; Uses: AF, DE, HL.
add a,a
ld d,0
ld e,a
add hl,de
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
ret
;
.ends
; -----------------------------------------------------------------------------
.section "InitializeVDPRegisters" free
; -----------------------------------------------------------------------------
; Initialize the 11 VDP registers with the preset data block.
; Uses: AF, B, HL
_VDPRegisterInitData:
.db SCROLL_0_LINE_0_SPRITES_0
.db DISPLAY_0_FRAME_0_SIZE_0
.db $ff,$ff,$ff,$ff,$ff,$00,$00,$00,$ff
InitializeVDPRegisters:
ld hl,_VDPRegisterInitData
xor b
-:
ld a,(hl)
out (CONTROL_PORT),a
inc hl
ld a,b
or REGISTER_WRITE_COMMAND
out (CONTROL_PORT),a
cp REGISTER_WRITE_COMMAND|10
ret z
inc b
jr -
.ends
;
; -----------------------------------------------------------------------------
.section "is_dpad_pressed" free
; -----------------------------------------------------------------------------
is_dpad_pressed:
ld a,(input_ports)
and %00001111 ; Isolate the dpad bits.
cpl ; Invert bits; now 1 = keypress!
and %00001111 ; Get rid of garbage from cpl in last four bits.
cp 0 ; Now, is any dpad key preseed?
ret z ; No, then return with carry flag reset (by the AND).
scf ; Yes, then set carry flag and...
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_button_1_pressed" free
; -----------------------------------------------------------------------------
is_button_1_pressed:
ld a,(input_ports)
and %00010000
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_player_2_button_1_pressed" free
; -----------------------------------------------------------------------------
is_player_2_button_1_pressed:
ld a,(input_ports+1)
and %00000100
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_button_2_pressed" free
; -----------------------------------------------------------------------------
is_button_2_pressed:
ld a,(input_ports)
and %00100000
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_player_2_button_2_pressed" free
; -----------------------------------------------------------------------------
is_player_2_button_2_pressed:
ld a,(input_ports+1)
and %00001000
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_down_pressed" free
; -----------------------------------------------------------------------------
is_down_pressed:
ld a,(input_ports)
and %00000010
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_left_pressed" free
; -----------------------------------------------------------------------------
is_left_pressed:
ld a,(input_ports)
and %00000100
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_reset_pressed" free
; -----------------------------------------------------------------------------
is_reset_pressed:
ld a,(input_ports+1)
and %00010000
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_right_pressed" free
; -----------------------------------------------------------------------------
is_right_pressed:
ld a,(input_ports)
and %00001000
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_up_pressed" free
; -----------------------------------------------------------------------------
is_up_pressed:
ld a,(input_ports)
and %00000001
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "is_start_pressed" free
; -----------------------------------------------------------------------------
is_start_pressed:
in a,(SYSTEM_CONTROL_PORT)
and START_BUTTON_BIT
ret nz ; Return with carry flag reset
scf
ret ; Return with carry flag set.
.ends
;
; -----------------------------------------------------------------------------
.section "kill_psg" free
; -----------------------------------------------------------------------------
; Manually silence all sound.
; Entry: None.
; Saves registers used.
kill_psg:
push af
ld a,$9f
out (PSG_PORT),a
ld a,$bf
out (PSG_PORT),a
ld a,$df
out (PSG_PORT),a
pop af
ret
.ends
;
; -----------------------------------------------------------------------------
.section "load_cram" free
; -----------------------------------------------------------------------------
; Load a number of colors into color ram (SMS).
; Entry: A = Palette index (0-31)
; B = Number of colors to load
; HL = Base address of source data (color bytes, SMS)
; Uses: AF, BC, HL
; Assumes blanked display and interrupts off.
load_cram:
out (CONTROL_PORT),a
ld a,CRAM_WRITE_COMMAND
out (CONTROL_PORT),a
-:
ld a,(hl)
out (DATA_PORT),a
inc hl
djnz -
ret
.ends
;
; -----------------------------------------------------------------------------
.section "load_cram_gg" free
; -----------------------------------------------------------------------------
; Load a number of colors into color ram (GG).
; Entry: A = Palette index (0-31)
; B = Number of colors to load
; HL = Base address of source data (color words, GG)
; Uses: AF, BC, HL
; Assumes blanked display and interrupts off.
load_cram_gg:
sla a
out (CONTROL_PORT),a
ld a,CRAM_WRITE_COMMAND
out (CONTROL_PORT),a
-:
ld a,(hl)
out (DATA_PORT),a
inc hl
ld a,(hl)
out (DATA_PORT),a
inc hl
djnz -
ret
.ends
;
; -----------------------------------------------------------------------------
.section "load_vdp_registers" free
; -----------------------------------------------------------------------------
load_vdp_registers:
; Load all 11 vdp registers with preset values.
; Entry: HL pointing to init data block (11 bytes).
xor b
-:
ld a,(hl)
out (CONTROL_PORT),a
inc hl
ld a,b
or REGISTER_WRITE_COMMAND
out (CONTROL_PORT),a
cp REGISTER_WRITE_COMMAND|10
ret z
inc b
jr -
ret
.ends
;
; -----------------------------------------------------------------------------
.section "load_vram" free
; -----------------------------------------------------------------------------
; Load a number of bytes from a source address into vram.
; Entry: BC = Number of bytes to load
; DE = Destination address in vram
; HL = Source address
; Exit: DE = Next free byte in vram.
; Uses: AF, BC, DE, HL,
load_vram:
ld a,e
out (CONTROL_PORT),a
ld a,d
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
-:
ld a,(hl)
out (DATA_PORT),a
inc hl
dec bc
ld a,c
or b
jp nz,-
ret
.ends
;
; -----------------------------------------------------------------------------
.section "load_vram_from_table" free
; -----------------------------------------------------------------------------
; Load a number of bytes from a source address into vram.
; Entry: HL = Pointer to table, w. data in the following format:
; Destination address in vram (word).
; Amount of bytes (word).
; Source address (word).
; Exit: HL = Next item in table.
; Uses: AF, BC, DE, HL,
load_vram_from_table:
push hl
ld a,(hl)
out (CONTROL_PORT),a
inc hl
ld a,(hl)
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
inc hl
ld c,(hl)
inc hl
ld b,(hl)
inc hl
ld a,(hl)
inc hl
ld h,(hl)
ld l,a
-:
ld a,(hl)
out (DATA_PORT),a
inc hl
dec bc
ld a,c
or b
jp nz,-
ld de,6
pop hl
add hl,de
ret
.ends
;
; -----------------------------------------------------------------------------
.section "put_string" free
; -----------------------------------------------------------------------------
; Put a string of multiple characters on the nametable with minimum overhead.
; Entry: B = Number og characters in string.
; HL = Pointer to string: Nametable address (word), then pairs of
; bytes [char], [flags]
; Exit: None
; Uses: AF, B, HL
put_string:
ld a,(hl)
out (CONTROL_PORT),a
inc hl
ld a,(hl)
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
-:
inc hl
ld a,(hl)
out (DATA_PORT),a
inc hl
ld a,(hl)
out (DATA_PORT),a ; Write 2nd byte to name table.
djnz -
ret
.ends
;
; -----------------------------------------------------------------------------
.section "ReadVRam" free
; -----------------------------------------------------------------------------
; Read a number of bytes from vram into a buffer.
; Entry: BC = Number of bytes to read
; DE = Destination address in ram (buffer)
; HL = Source address in vram
; Uses: AF, BC, DE, HL,
ReadVRam:
ld a,l
out (CONTROL_PORT),a
ld a,h
or VRAM_READ_COMMAND
out (CONTROL_PORT),a
-:
in a,(DATA_PORT)
ld (de),a
inc de
dec bc
ld a,c
or b
jp nz,-
ret
.ends
;
; -----------------------------------------------------------------------------
.section "Set register (vdp)" free
; -----------------------------------------------------------------------------
; Write to target register.
; Entry: A = byte to be loaded into vdp register.
; B = target register 0-10.
; Uses: AF, B
set_register:
out (CONTROL_PORT),a
ld a,REGISTER_WRITE_COMMAND
or b
out (CONTROL_PORT),a
ret
.ends
;
; -----------------------------------------------------------------------------
.section "set_vram_address" free
; -----------------------------------------------------------------------------
; Set vram address.
; Entry: HL = Address.
; Exit:
; Uses:
set_vram_address:
ld a,l
out (CONTROL_PORT),a
ld a,h
or VRAM_WRITE_COMMAND
out (CONTROL_PORT),a
ret
.ends
; -----------------------------------------------------------------------------
.section "Wait for scanline" free
; -----------------------------------------------------------------------------
; Wait for a specific scanline passed in A.
; Entry: A = Scanline to wait for.
; Uses: AF, B
wait_for_scanline:
ld b,a
-:
in a,(V_COUNTER_PORT)
cp b
jp nz,-
ret
.ends
;
; *****************************************************************************
; B L U E L I B S P R I T E R O U T I N E S
; *****************************************************************************
;
.equ PLAYER_SIZE 4 ; Number of tiles not part of asc/desc flicker.
.equ ASCENDING 0
.equ DESCENDING $ff
;
.ramsection "Spritelib Variables" slot 3
SpriteBufferY dsb 64
SpriteBufferXC dsb 128
NextFreeSprite db
SATLoadMode db ; Ascending or descending - for flickering.
.ends
;
; -----------------------------------------------------------------------------
.section "add_sprite" free
; -----------------------------------------------------------------------------
; Add a sprite of size = 1 character to the SAT.
; Entry: A = Character code (character in bank 2).
; B = vertical position, C = horizontal position.
; Exit:
; Uses: None - all registers saved
add_sprite:
; Test for sprite overflow (more than 64 hardware sprites at once).
SAVE_REGISTERS
ld d,a ; Save the tile in unused register.
ld a,(NextFreeSprite)
inc a
cp 65
jp nc,exit_add_sprite
ld a,d ; Restore tile in A.
;
push af
push bc
; Point DE to SpriteBufferY[NextFreeSprite].
ld a,(NextFreeSprite)