nextflow.config

plugins {
  id 'nf-schema@2.3.0'
}

validation {
  help {
    enabled             = true
    shortParameter      = false
    fullParameter       = 'help'
    showHidden          = true
    afterText           = 'If you encounter any issues with fold2go, please report them at https://gitlab.rlp.net/imbforge/fold2go/-/issues'
  }
}

// include the pipeline config defaults
includeConfig 'workflows/fold2go/nextflow.config'

// include pipeline profiles
// these should at least configure executor, container engine and 'gpu' process label
profiles {
  standard {
    includeConfig 'configs/singularity.config'
    includeConfig 'configs/imb.config'
  }
  docker {
    includeConfig 'configs/docker.config'
  }
  singularity {
    includeConfig 'configs/singularity.config'
  }
}

// generate a timestamp to add to reports
def timestamp = new java.util.Date().format( 'yyyy-MM-dd_HH-mm')

report {
  enabled   = true
  overwrite = true
  file      = "${params.OUT}/report_${timestamp}.html"
}

timeline {
  enabled   = true
  overwrite = true
  file      = "${params.OUT}/timeline_${timestamp}.html"
}

trace {
  enabled   = false
  overwrite = true
  file      = "${params.OUT}/trace_${timestamp}.txt"
}

dag {
  enabled   = false
  overwrite = true
  file      = "${params.OUT}/graph_${timestamp}.mmd"
}

manifest {
  name = 'imbforge/fold2go'
  homePage = 'https://gitlab.rlp.net/imbforge/fold2go'
  description = 'fold2go is a nextflow pipeline for in silico prediction of protein structures and interactions through various machine learning models'
  author = 'Patrick Hüther (huether@imb-mainz.de)'
  mainScript = 'main.nf'
  defaultBranch = 'main'
  nextflowVersion = '!>=24.04.0'
}

// when a run is terminated via GUI, the jupyter-server is not stopped, which leads to a 500 error
// workaround this by manually stopping the jupyter-server, which will shut the proxy down as well
// FIXME: once https://github.com/jupyterhub/jupyter-server-proxy/pull/395 is merged, this can be handled programmatically
if ( System.getenv('JUPYTERHUB_SERVICE_URL') ) {
  workflow.onComplete = { "jupyter-server stop ${new URL(System.getenv('JUPYTERHUB_SERVICE_URL')).getPort()}".execute() }
}